Tutorial ini melihat penggunaan praktis dari fungsi Excel ISERROR dan menunjukkan cara menguji berbagai rumus untuk kesalahan.

Saat Anda menulis rumus yang tidak dipahami atau tidak dapat dihitung oleh Excel, itu menarik perhatian Anda pada masalah dengan menampilkan pesan kesalahan. Fungsi ISERROR dapat membantu Anda menangkap kesalahan dan memberikan alternatif saat kesalahan ditemukan.

Fungsi ISERROR di Excel

Fungsi Excel ISERROR menangkap semua jenis kesalahan, termasuk #CALC!, #DIV / 0!, #N / A, #NAME?, #NUM!, #NULL!, #REF!, #VALUE!, dan #SPILL! Hasilnya adalah nilai Boolean: TRUE jika kesalahan terdeteksi, FALSE sebaliknya.

Fungsi ini tersedia di semua versi Excel 2000 hingga 2021 dan Excel 365.

Sintaks fungsi ISERROR sesederhana ini:

Di mana nilai adalah nilai sel atau formula yang akan diperiksa kesalahannya.

Rumus ISERROR Excel

Untuk membuat rumus ISERROR dalam bentuknya yang paling sederhana, berikan referensi ke sel yang ingin Anda uji kesalahannya. Misalnya:

=ISERROR(A2)

Jika ada kesalahan yang ditemukan, Anda akan mendapatkan TRUE. Jika tidak ada kesalahan dalam sel yang diuji, Anda akan mendapatkan FALSE:

JIKA ISERROR rumus di Excel

Untuk mengembalikan pesan khusus atau melakukan kalkulasi yang berbeda ketika terjadi error, gunakan ISERROR bersama dengan fungsi IF. Rumus generiknya terlihat sebagai berikut:

Diterjemahkan ke dalam bahasa manusia, dikatakan: jika rumus utama menghasilkan kesalahan, tampilkan teks yang ditentukan atau jalankan kalkulasi lain, jika tidak, kembalikan hasil normal dari rumus tersebut.

Pada gambar di bawah ini, membagi total dengan kuantitas menghasilkan beberapa kesalahan pada Harga kolom:

Untuk mengganti semua kode kesalahan yang berbeda dengan teks khusus, Anda dapat menggunakan rumus IF ISERROR berikut:

=IF(ISERROR(A2/B2), "Tidak diketahui", A2/B2)

Di Excel 2007 dan versi yang lebih baru, hasil yang sama dapat dicapai dengan bantuan fungsi IFERROR bawaan:

=IFERROR(A2/B2, "Tidak diketahui")

Perlu dicatat bahwa rumus IFERROR berjalan sedikit lebih cepat karena melakukan perhitungan A2/B2 hanya sekali saja. Sedangkan IF ISERROR menghitungnya dua kali - pertama untuk melihat apakah menghasilkan error dan kemudian lagi jika hasil tesnya SALAH.

JIKA ISERROR VLOOKUP rumus

Menggunakan ISERROR dengan VLOOKUP sebenarnya adalah kasus khusus dari rumus IF ISERROR yang dibahas di atas. Ketika fungsi VLOOKUP tidak dapat menemukan nilai pencarian atau gagal karena alasan lain, Anda menampilkan pesan teks khusus dengan menggunakan sintaks ini:

Untuk contoh ini, mari kita tarik waktu dari tabel pencarian (D3:E10) ke tabel utama (A3:B15). Jika nilai pencarian (nama peserta) tidak ada dalam tabel pencarian, kita akan mengembalikan "Tidak memenuhi syarat".

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$10, 2, FALSE)), "Tidak memenuhi syarat", VLOOKUP(A3, $D$3:$E$10, 2, FALSE))

Tip. Jika Anda ingin menampilkan teks khusus hanya apabila nilai pencarian tidak ditemukan (kesalahan # N / A) mengabaikan kesalahan lainnya, lalu gunakan rumus IFNA VLOOKUP di Excel 2013 dan yang lebih baru atau IF ISNA VLOOKUP di versi yang lebih lama.

JIKA ISERROR INDEX MATCH rumus

Saat melakukan pencarian dengan bantuan kombinasi INDEX MATCH (atau rumus INDEX XMATCH di Excel 365), Anda dapat menjebak dan menangani kemungkinan kesalahan dengan menggunakan teknik yang sama - fungsi ISERROR memeriksa kesalahan dan IF menampilkan teks yang ditentukan saat terjadi kesalahan.

Misalkan tabel pencarian memiliki waktu di kolom pertama. Karena VLOOKUP tidak dapat melihat ke kiri, kita menggunakan rumus INDEX MATCH untuk menarik waktu dari kolom D:

=INDEX($D$3:$D$10, MATCH(A3, $E$3:$E$10, 0))

Dan kemudian, Anda menyarangkannya dalam rumus umum yang disebutkan di atas untuk mengganti kesalahan yang tertangkap dengan teks apa pun yang Anda inginkan:

=IF(ISERROR(INDEX($D$3:$D$10, MATCH(A3, $E$3:$E$10, 0))), "Not qualified", INDEX($D$3:$D$10, MATCH(A3, $E$3:$E$10, 0))))

Catatan. Seperti rumus IF ISERROR VLOOKUP, akan lebih masuk akal jika kamu hanya menjebak error #N/A saja dan tidak menyamarkan potensi masalah pada rumusnya sendiri. Untuk itu, bungkus rumus INDEX MATHmu dengan IFNA di Excel 2013 ke atas atau IF ISNA di versi sebelumnya.

JIKA ISERROR Rumus Ya/Tidak

Pada semua contoh sebelumnya, IF ISERROR mengembalikan hasil dari rumus utamanya jika tidak error. Namun, ia juga bisa bekerja dengan cara yang berbeda - mengembalikan sesuatu jika error dan sesuatu yang lain jika tidak ada error.

Dalam contoh dataset kita, misalkan Anda tidak tertarik pada waktu yang tepat, Anda hanya ingin mengetahui peserta mana dari grup A yang memenuhi syarat dan mana yang tidak. Untuk melakukan ini, gunakan fungsi MATCH untuk membandingkan nama di kolom A dengan daftar peserta yang memenuhi syarat di kolom D, lalu sajikan hasilnya ke ISERROR. Jika nama tidak tersedia di kolom D (MATCH mengembalikan kesalahan), dapatkanJika nama muncul di kolom D (tidak ada kesalahan), kembalikan "Ya" atau "Memenuhi syarat".

=IF(ISERROR(MATCH(A3, $D$3:$D$10, 0)), "No", "Yes" )

Cara menghitung jumlah kesalahan

Untuk mendapatkan jumlah kesalahan dalam kolom tertentu, Anda perlu memeriksa rentang, bukan hanya satu sel. Untuk ini, "beri makan" rentang target ke ISERROR dan paksa nilai Boolean yang dikembalikan ke dalam 1 dan 0 menggunakan operator unary ganda (--). Fungsi SUM atau SUMPRODUCT dapat menjumlahkan angka dan memberikan hasil akhir.

Contohnya:

=SUM(--ISERROR(C2:C10))

Harap dicatat, ini berfungsi sebagai rumus biasa hanya di Excel 365 dan Excel 2021, yang mendukung array dinamis. Di Excel 2019 dan sebelumnya, Anda perlu menekan Ctrl + Shift + Enter untuk membuat rumus array (jangan ketik tanda kurung kurawal secara manual, itu tidak akan berfungsi!):

{=SUM(--ISERROR(C2:C10))}

Sebagai alternatif, Anda dapat menggunakan fungsi SUMPRODUCT yang menangani array secara native, sehingga rumus dapat diselesaikan dengan tombol Enter biasa di semua versi:

=SUMPRODUCT(--ISERROR(C2:C10))

Perbedaan antara ISERROR dan IFERROR di Excel

Baik fungsi ISERROR dan IFERROR digunakan untuk menjebak dan menangani kesalahan di Excel. Perbedaannya adalah sebagai berikut:

• Dalam bentuknya yang murni, ISERROR hanya menguji apakah nilainya adalah kesalahan atau tidak. Ini tersedia di semua versi Excel.
• Fungsi IFERROR dirancang untuk menekan atau menyamarkan kesalahan - ketika kesalahan ditemukan, ia mengembalikan nilai lain yang Anda tentukan. Ini tersedia di Excel 2007 dan lebih tinggi.

Sekilas, IFERROR terlihat seperti alternatif singkatan dari rumus IF ISERROR. Namun, jika dilihat lebih dekat, kamu bisa melihat perbedaannya:

• IFERROR memungkinkan Anda untuk menentukan hanya value_if_error Jika tidak ada kesalahan, ia selalu mengembalikan hasil dari nilai/rumus yang diuji.
• IF ISERROR memberikan fleksibilitas yang lebih besar dan memungkinkan Anda menangani kedua situasi tersebut - apa yang harus terjadi jika terjadi error dan apa yang harus terjadi jika tidak ada error.

Untuk mengilustrasikan poinnya dengan lebih baik, pertimbangkan rumus-rumus ini:

=IFERROR(A1, "Kesalahan perhitungan")

=IF(ISERROR(A1), "Kesalahan perhitungan", A1)

Kedua rumus ini setara - keduanya memeriksa nilai yang digerakkan oleh rumus di A1 dan mengembalikan "Kesalahan penghitungan" jika itu adalah kesalahan, jika tidak - kembalikan nilainya.

Tetapi bagaimana jika Anda ingin melakukan beberapa kalkulasi jika nilai di A1 bukan error? Fungsi IFERROR tidak dapat melakukan itu. Dalam kasus IF ISERROR, cukup ketik kalkulasi yang diinginkan di argumen terakhir. Sebagai contoh:

=IF(ISERROR(A1), "Kesalahan perhitungan", A1*2)

Seperti yang Anda lihat, variasi yang lebih panjang dari rumus IFERROR ini, yang sering dianggap ketinggalan zaman, masih bisa berguna :)

Unduhan yang tersedia

Contoh rumus ISERROR (file .xlsx)