A bemutató az Excel ISERROR függvény gyakorlati felhasználását vizsgálja, és bemutatja, hogyan tesztelhetjük a különböző képleteket hibák szempontjából.

Ha olyan képletet ír, amelyet az Excel nem ért, vagy nem tud kiszámítani, akkor hibaüzenettel hívja fel a figyelmet a problémára. Az ISERROR függvény segíthet a hibák észlelésében, és hiba esetén alternatívát kínál.

ISERROR funkció az Excelben

Az Excel ISERROR függvénye mindenféle hibát kiszűr, beleértve a #CALC!, #DIV/0!, #N/A, #NAME?, #NUM!, #NULL!, #REF!, #VALUE! és #SPILL! hibákat. Az eredmény egy Boolean érték: TRUE, ha hibát észlelt, egyébként FALSE.

A funkció az Excel 2000-től 2021-ig és az Excel 365 összes verziójában elérhető.

Az ISERROR függvény szintaxisa ilyen egyszerű:

Hol érték a hiba szempontjából ellenőrizendő cellaérték vagy képlet.

Excel ISERROR formula

Az ISERROR képlet létrehozásához a legegyszerűbb formában adjon meg egy hivatkozást arra a cellára, amelyet hibára szeretne tesztelni. Például:

=ISERROR(A2)

Ha hibát talál, TRUE-t kap, ha pedig nincs hiba a vizsgált cellában, FALSE-t kap:

IF ISERROR formula Excelben

Egyéni üzenet visszaküldéséhez vagy más számítás elvégzéséhez hiba esetén használja az ISERROR-t az IF függvénnyel együtt. Az általános képlet a következőképpen néz ki:

Emberi nyelvre lefordítva azt mondja: ha a fő képlet hibát eredményez, jelenítse meg a megadott szöveget vagy futtasson egy másik számítást, egyébként adja vissza a képlet normál eredményét.

Az alábbi képen a végösszegnek a mennyiséggel való elosztása néhány hibát generál a Ár oszlop:

A különböző hibakódok egyéni szöveggel való helyettesítéséhez a következő IF ISERROR képletet használhatja:

=IF(ISERROR(A2/B2), "Ismeretlen", A2/B2)

Az Excel 2007 és újabb verziókban ugyanez az eredmény a beépített IFERROR funkció segítségével érhető el:

=IFERROR(A2/B2, "Ismeretlen")

Meg kell jegyezni, hogy az IFERROR formula egy kicsit gyorsabban fut, mert az A2/B2 számítást csak egyszer végzi el. Míg az IF ISERROR kétszer számítja ki - először, hogy megnézze, hibát generál-e, majd újra, ha a teszt FALSE.

IF ISERROR VLOOKUP formula

Az ISERROR használata a VLOOKUP funkcióval valójában a fentebb tárgyalt IF ISERROR formula egy speciális esete. Ha a VLOOKUP függvény nem találja a keresési értéket, vagy bármilyen más okból nem sikerül, akkor ezzel a szintaxissal egy egyéni szöveges üzenetet jeleníthet meg:

Ebben a példában a keresési táblázatból (D3:E10) a fő táblázatba (A3:B15) húzzuk az időket. Ha a keresési érték (a résztvevő neve) nem létezik a keresési táblázatban, akkor a "Nem minősített" választ adjuk vissza.

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$10, 2, FALSE)), "Nem minősített", VLOOKUP(A3, $D$3:$E$10, 2, FALSE)))

Tipp. Ha csak akkor szeretne megjeleníteni egy egyéni szöveget, ha egy keresési érték nem található (#N/A hiba) figyelmen kívül hagyva más hibákat, akkor használja az IFNA VLOOKUP képletet az Excel 2013 és újabb verziókban vagy az IF ISNA VLOOKUP képletet a régebbi verziókban.

IF ISERROR INDEX MATCH formula

Amikor az INDEX MATCH kombináció (vagy az INDEX XMATCH képlet az Excel 365-ben) segítségével keresést végez, ugyanezzel a technikával csapdába ejtheti és kezelheti az esetleges hibákat - az ISERROR függvény ellenőrzi a hibákat, és IF hiba esetén megjeleníti a megadott szöveget.

Tegyük fel, hogy a keresőtábla az első oszlopban időpontokat tartalmaz. Mivel a VLOOKUP nem képes balra nézni, az INDEX MATCH képletet használjuk a D oszlopból való időpontok kinyerésére:

=INDEX($D$3:$D$10, MATCH(A3, $E$3:$E$10, 0))

Ezután pedig a fent említett általános képletbe ágyazza be, hogy a hibákat bármilyen szöveggel helyettesítse:

=IF(ISERROR(INDEX($D$3:$D$10, MATCH(A3, $E$3:$E$10, 0))), "Not qualified", INDEX($D$3:$D$10, MATCH(A3, $E$3:$E$10, 0))))

Megjegyzés: Az IF ISERROR VLOOKUP képlethez hasonlóan célszerűbb csak az #N/A hibákat csapdába ejteni, és nem leplezni az esetleges problémákat magával a képlettel. Ehhez az INDEX MATH képletet az Excel 2013 és újabb verziókban IFNA, vagy korábbi verziókban IF ISNA formában csomagolja be.

IF ISERROR Igen/Nem formula

Az előző példák mindegyikében az IF ISERROR a fő formula eredményét adta vissza, ha az nem hiba. Azonban másképp is működhet - valamit visszaad, ha hiba, és valami mást, ha nincs hiba.

Tegyük fel, hogy a mintaadatkészletünkben nem érdekelnek a pontos időpontok, csak azt szeretnénk tudni, hogy az A csoportból mely résztvevők minősítettek és melyek nem. Ehhez használjuk a MATCH függvényt, hogy összehasonlítsuk az A oszlopban lévő nevet a D oszlopban lévő minősített résztvevők listájával, majd az eredményeket az ISERROR-nak adjuk meg. Ha a név nem elérhető a D oszlopban (a MATCH hibát ad vissza), akkor kapjuk meg a következőtaz IF függvény a "Nem" vagy "Nem minősített" kijelzéshez. Ha a név megjelenik a D oszlopban (nincs hiba), akkor az "Igen" vagy "Minősített" választ adja vissza.

=IF(ISERROR(MATCH(A3, $D$3:$D$10, 0)), "Nem", "Igen" )

Hogyan számoljuk a hibák számát

Ha egy adott oszlopban lévő hibák számát szeretné megtudni, akkor egy tartományt kell ellenőriznie, nem csak egy cellát. Ehhez "táplálja" a céltartományt az ISERROR-ba, és a visszaadott bólés értékeket a kettős egyértékű operátor (--) segítségével 1-es és 0-s értékekre kényszeríti. A SUM vagy SUMPRODUCT függvény összeadhatja a számokat, és kiadhatja a végeredményt.

Például:

=SUM(--ISERROR(C2:C10))

Felhívjuk figyelmét, hogy ez csak az Excel 365 és Excel 2021 programokban működik normál képletként, amelyek támogatják a dinamikus tömböket. Az Excel 2019 és korábbi programokban a Ctrl + Shift + Enter billentyűkombinációt kell megnyomnia a tömbképlet létrehozásához (ne írja be a görbe zárójeleket kézzel, az nem fog működni!):

{=SUM(--ISERROR(C2:C10))}

Alternatívaként használhatja a SUMPRODUCT függvényt, amely natívan kezeli a tömböket, így a képletet minden változatban a szokásos Enter billentyűvel fejezheti be:

=SUMPRODUCT(--ISERROR(C2:C10))

Az ISERROR és az IFERROR közötti különbség az Excelben

Mind az ISERROR, mind az IFERROR függvények az Excelben a hibák csapdázására és kezelésére szolgálnak. A különbség a következő:

• Tiszta formájában az ISERROR csak azt vizsgálja, hogy az érték hibás-e. Minden Excel-verzióban elérhető.
• Az IFERROR függvény a hibák elnyomására vagy elrejtésére szolgál - hiba esetén egy másik, Ön által megadott értéket ad vissza. Az Excel 2007 és újabb verziókban érhető el.

Első pillantásra az IFERROR az IF ISERROR formula rövidített alternatívájának tűnik. Közelebbről megvizsgálva azonban észrevehető a különbség:

• Az IFERROR lehetővé teszi, hogy csak value_if_error Ha nincs hiba, mindig a vizsgált érték/képlet eredményét adja vissza.
• Az IF ISERROR nagyobb rugalmasságot biztosít, és lehetővé teszi mindkét helyzet kezelését - mi történjen, ha hiba történik, és mi, ha nincs hiba.

Hogy jobban szemléltessük a lényeget, tekintsük meg ezeket a képleteket:

=IFERROR(A1, "Számítási hiba")

=IF(ISERROR(A1), "Számítási hiba", A1)

Ez a két képlet egyenértékű - mindkettő ellenőrzi az A1-ben lévő képletvezérelt értéket, és "Számítási hiba" választ ad vissza, ha hiba, egyébként pedig - visszaadja az értéket.

De mi van akkor, ha valamilyen számítást szeretnénk elvégezni, ha az A1-ben lévő érték nem hiba? Az IFERROR függvény erre nem képes. Az IF ISERROR esetében csak írjuk be a kívánt számítást az utolsó argumentumba. Például:

=IF(ISERROR(A1), "Számítási hiba", A1*2)

Mint látod, az IFERROR képletnek ez a hosszabb változata, amelyet gyakran elavultnak tartanak, még mindig hasznos lehet :)

Elérhető letöltések

ISERROR formula példák (.xlsx fájl)