Tutorial ningali kana kagunaan praktis tina pungsi Excel ISERROR sareng nunjukkeun cara nguji rumus anu béda pikeun kasalahan.

Lamun anjeun nulis rumus nu Excel teu ngarti atawa teu bisa ngitung, eta metot perhatian Anjeun ka masalah ku mintonkeun talatah kasalahan. Fungsi ISERROR tiasa ngabantosan anjeun mendakan kasalahan sareng nyayogikeun alternatip nalika aya kasalahan.

Fungsi ISERROR dina Excel

Fungsi Excel ISERROR nangkep sagala jinis kasalahan, kaasup #CALC!, #DIV/0!, #N/A, #NAME?, #NUM!, #NULL!, #REF!, #VALUE!, jeung #SILL!. Hasilna mangrupa nilai Boolean: BENER lamun kasalahan dideteksi, FALSE lamun heunteu.

Pungsi ieu sadia dina sadaya vérsi Excel 2000 nepi ka 2021 jeung Excel 365.

Sintaksis ISERROR fungsina sagampil kieu:

Dimana value nyaeta nilai sél atawa rumus anu bakal dipariksa pikeun kasalahan.

Rumus Excel ISERROR

Pikeun nyieun rumus ISERROR dina bentuk pangbasajanna, nyadiakeun rujukan ka sél nu Anjeun hoyong nguji pikeun kasalahan. Contona:

=ISERROR(A2)

Upami aya kasalahan, anjeun bakal nampi BENER. Upami teu aya kasalahan dina sél anu diuji, anjeun bakal nampi FALSE:

IF ISERROR formula dina Excel

Pikeun mulangkeun pesen khusus atanapi ngalakukeun itungan béda nalika kasalahan lumangsung, make ISERROR bareng jeung fungsi IF. Rumus umumna sapertos kieu:

Ditarjamahkeun kana basa manusa, nyebutkeun: lamun rumus utama hasil dina kasalahan, tampilkeun téks nu tangtu atawa ngajalankeun itungan sejen, disebutkeun balikkeun hasil normal tina rumus.

Dina gambar di handap, ngabagi total ku kuantitas ngahasilkeun sababaraha kasalahan dina Harga kolom:

Pikeun ngagentos sadaya kodeu kasalahan anu béda sareng téks khusus, anjeun tiasa nganggo rumus IF ISERROR ieu:

=IF(ISERROR(A2/B2), "Unknown", A2/B2)

Dina Excel 2007 sareng vérsi engké, hasil anu sami tiasa dihontal kalayan bantosan fungsi IFERROR inbuilt:

=IFERROR(A2/B2, "Unknown")

Kuduna Catet yén rumus IFERROR jalanna rada gancang sabab ngalakukeun itungan A2/B2 ngan sakali. Sedengkeun IF ISERROR ngitung dua kali - mimiti ningali naha éta ngahasilkeun kasalahan teras deui upami tés PALSU.

Rumus IF ISERROR VLOOKUP

Nganggo ISERROR sareng VLOOKUP, kanyataanna, kasus khusus tina IF IS Rumus ERROR dibahas di luhur. Lamun fungsi VLOOKUP teu bisa manggihan nilai lookup atawa gagal pikeun alesan sejen, Anjeun mintonkeun pesen téks custom ku ngagunakeun sintaksis ieu:

Pikeun conto ieu, hayu urang tarik waktu tina tabel lookup (D3:E10) kana tabel utama (A3:B15). Lamun nilai lookup (ngaran pamilon urang) teu aya dinatabél lookup, urang bakal balik "Teu mumpuni".

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$10, 2, FALSE)), "Not qualified", VLOOKUP(A3, $D$3:$E$10, 2, FALSE))

Tip. Upami anjeun hoyong ningalikeun téks khusus ngan ukur nalika nilai pilarian teu kapendak (#N/A error) teu malire kasalahan anu sanés, teras paké rumus IFNA VLOOKUP dina Excel 2013 sareng engké atanapi IF ISNA VLOOKUP langkung lami. versi.

IF ISERROR INDEX MATCH rumus

Nalika ngalakukeun pamariksaan kalayan bantuan kombinasi INDEX MATCH (atanapi rumus INDEX XMATCH dina Excel 365), anjeun tiasa bubu sareng nanganan sagala kasalahan anu mungkin ku ngagunakeun téknik anu sami - fungsi ISERROR mariksa kasalahan jeung IF mintonkeun téks nu tangtu lamun aya kasalahan.

Anggap tabel lookup boga kali dina kolom kahiji. Kusabab VLOOKUP henteu tiasa neuteup ka kénca, kami nganggo rumus INDEX MATCH pikeun narik waktos tina kolom D:

=INDEX($D$3:$D$10, MATCH(A3, $E$3:$E$10, 0))

Terus, anjeun nyarang dina rumus umum anu disebatkeun di luhur. pikeun ngagentos kasalahan anu katangkep ku téks anu anjeun pikahoyong:

=IF(ISERROR(INDEX($D$3:$D$10, MATCH(A3, $E$3:$E$10, 0))), "Not qualified", INDEX($D$3:$D$10, MATCH(A3, $E$3:$E$10, 0)))

Catetan. Salaku kalawan rumus IF ISERROR VLOOKUP, ngajadikeun leuwih akal pikiran ngan bubu #N / ​​A kasalahan sarta ulah nyamur masalah poténsi kalayan rumus sorangan. Jang ngalampahkeun ieu, bungkus rumus INDEX MATH anjeun dina IFNA dina Excel 2013 sareng anu langkung luhur atanapi IF ISNA dina versi sateuacana.

LamunRumus ISERROR Leres/Henteu

Dina sadaya conto saacanna, IF ISERROR ngabalikeun hasil tina rumus utama upami éta sanés kasalahan. Tapi, éta ogé tiasa dianggo ku cara anu béda - mulangkeun hiji hal upami aya kasalahan sareng anu sanés upami henteu aya kasalahan.

Dina set data sampel urang, anggap anjeun teu kabetot dina waktu pasti, anjeun ngan hayang nyaho mana pamilon ti grup A mumpuni sarta mana anu henteu. Jang ngalampahkeun ieu, make fungsi cocog pikeun ngabandingkeun ngaran dina kolom A ngalawan daptar pamilon mumpuni dina kolom D, lajeng ngalayanan hasil ka ISERROR. Upami nami henteu sayogi dina kolom D (MATCH mulihkeun kasalahan), kéngingkeun fungsi IF pikeun nunjukkeun "Henteu" atanapi "Teu mumpuni". Upami nami muncul dina kolom D (teu aya kasalahan), balikkeun "Sumuhun" atanapi "Kualifikasi".

=IF(ISERROR(MATCH(A3, $D$3:$D$10, 0)), "No", "Yes" )

Kumaha carana ngitung jumlah kasalahan.

Pikeun meunangkeun jumlah kasalahan dina kolom nu tangtu, anjeun kudu mariksa rentang, lain ngan hiji sél. Jang ngalampahkeun ieu, "eupan" rentang target ka ISERROR sarta maksakeun nilai Boolean balik kana 1 sarta 0 ngagunakeun operator unary ganda (--). Pungsi SUM atanapi SUMPRODUCT tiasa nambihan angka sareng nganteurkeun hasil ahir.

Contona:

=SUM(--ISERROR(C2:C10))

Perhatikeun, ieu tiasa dianggo salaku rumus biasa ngan dina Excel. 365 sareng Excel 2021, anu ngadukung susunan dinamis. Dina Excel 2019 sareng sateuacana, anjeunkudu mencet Ctrl + Shift + Enter pikeun nyieun rumus array (ulah ngetik kurung keriting sacara manual, éta moal jalan!):

{=SUM(--ISERROR(C2:C10))}

Alternatipna, Anjeun bisa make SUMPRODUCT fungsi nu nanganan arrays natively, jadi rumusna bisa direngsekeun ku tombol Enter biasa dina sakabéh versi:

=SUMPRODUCT(--ISERROR(C2:C10))

Béda antara ISERROR jeung IFERROR dina Excel

Kadua fungsi ISERROR sareng IFERROR dianggo pikeun ngajebak sareng nanganan kasalahan dina Excel. Bédana nyaéta kieu:

• Dina wangun murnina, ISERROR ngan ukur nguji naha nilaina kasalahan atawa henteu. Éta sayogi dina sadaya vérsi Excel.
• Pungsi IFERROR dirarancang pikeun nyegah atanapi nyamur kasalahan - nalika aya kasalahan, éta bakal ngabalikeun nilai sanés anu anjeun tangtoskeun. Éta sayogi dina Excel 2007 sareng anu langkung luhur.

Saheulaanan, IFERROR siga alternatif singgetan pikeun rumus IF ISERROR. Sanajan kitu, lamun nempo leuwih deukeut, Anjeun bisa nempo bédana:

• IFERROR ngidinan Anjeun pikeun nangtukeun ngan value_if_error . Upami teu aya kasalahan, éta salawasna ngabalikeun hasil tina nilai/rumus anu diuji.
• LAMUN ISERROR nyayogikeun langkung kalenturan sareng ngamungkinkeun anjeun pikeun nanganan duanana kaayaan - naon anu kedah kajantenan upami aya kasalahan sareng kumaha upami henteu aya kasalahan.

Pikeun ngagambarkeun anu hadé, pertimbangkeun rumus ieu:

=IFERROR(A1, "Calculation error")

=IF(ISERROR(A1), "Calculation error", A1)

Dua rumus ieu sarimbag - duanana pariksa nilai anu didorong ku rumus. dina A1 jeung mulang"Kasalahan itungan" lamun éta kasalahan, disebutkeun - balikkeun nilaina.

Tapi kumaha upami anjeun hoyong ngalakukeun sababaraha itungan upami nilai dina A1 sanes kasalahan? Fungsi IFERROR henteu tiasa ngalakukeun éta. Dina kasus IF ISERROR, ketik itungan anu dipikahoyong dina argumen anu terakhir. Contona:

=IF(ISERROR(A1), "Calculation error", A1*2)

Sakumaha nu katingali, variasi rumus IFERROR nu leuwih panjang ieu, nu mindeng dianggap katinggaleun jaman, masih bisa mangpaat :)

Sadia undeuran

Conto rumus ISERROR (file .xlsx)