Õpetuses vaadeldakse Exceli funktsiooni ISERROR praktilist kasutamist ja näidatakse, kuidas testida erinevaid valemeid vigade suhtes.

Kui kirjutate valemi, millest Excel ei saa aru või mida ei saa arvutada, juhib ta teie tähelepanu probleemile, näidates veateadet. Funktsioon ISERROR aitab teil vigu tabada ja pakub vea leidmisel alternatiivi.

Funktsioon ISERROR Excelis

Exceli funktsioon ISERROR püüab kõikvõimalikke vigu, sealhulgas #CALC!, #DIV/0!, #N/A, #NAME?, #NUM!, #NULL!, #REF!, #VALUE! ja #SPILL!. Tulemuseks on boolilik väärtus: TRUE, kui viga on tuvastatud, FALSE muidu.

Funktsioon on saadaval kõigis Excel 2000 kuni 2021 ja Excel 365 versioonides.

Funktsiooni ISERROR süntaks on nii lihtne:

Kus väärtus on lahtri väärtus või valem, mida kontrollitakse vigade suhtes.

Exceli ISERROR valem

Valemi ISERROR loomiseks selle lihtsaimal kujul esitage viide lahtrisse, mida soovite vigade suhtes testida. Näiteks:

=ISERROR(A2)

Kui leitakse mõni viga, saad tulemuseks TRUE. Kui testitud lahtris ei ole ühtegi viga, saad tulemuseks FALSE:

IF ISERROR valem Excelis

Kui soovite vea ilmnemisel tagastada kohandatud teate või teha teistsuguse arvutuse, kasutage ISERROR koos IF-funktsiooniga. Üldine valem näeb välja järgmiselt:

Inimkeelde tõlgituna ütleb see: kui põhivalem annab tulemuseks vea, kuvage määratud tekst või käivitage teine arvutus, vastasel juhul tagastage valemi tavaline tulemus.

Alljärgneval pildil tekitab kogusumma jagamine kogusega paar viga Hind veerus:

Kõigi erinevate veakoodide asendamiseks kohandatud tekstiga saate kasutada järgmist valemit IF ISERROR:

=IF(ISERROR(A2/B2), "Unknown", A2/B2)

Excel 2007 ja hilisemates versioonides saab sama tulemuse saavutada sisseehitatud IFERROR-funktsiooni abil:

=IFERROR(A2/B2, "Unknown")

Tuleb märkida, et valem IFERROR töötab veidi kiiremini, sest ta teeb A2/B2 arvutuse ainult üks kord. Samas kui IF ISERROR arvutab seda kaks korda - kõigepealt, et näha, kas see tekitab vea, ja seejärel uuesti, kui test on FALSE.

IF ISERROR VLOOKUP valemiga

ISERRORi kasutamine koos VLOOKUPiga on tegelikult eespool käsitletud IF ISERRORi valemi erijuhtum. Kui VLOOKUP-funktsioon ei leia otsinguväärtust või ebaõnnestub mingil muul põhjusel, kuvatakse selle süntaksi abil kohandatud tekstisõnum:

Selle näite puhul tõmbame ajad otsingutabeli (D3:E10) põhitabelisse (A3:B15). Kui otsinguväärtust (osaleja nimi) ei ole otsingutabelis olemas, siis tagastame "Not qualified".

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$10, 2, FALSE)), "Not qualified", VLOOKUP(A3, $D$3:$E$10, 2, FALSE))

Vihje. Kui soovite kuvada kohandatud teksti ainult siis, kui üks otsinguväärtust ei ole leitud (#N/A viga), ignoreerides muid vigu, siis kasutage valemit IFNA VLOOKUP Excel 2013 ja hilisemates versioonides või IF ISNA VLOOKUP vanemates versioonides.

IF ISERROR INDEX MATCH valemiga

Kui teete otsingut INDEX MATCH-kombinatsiooni (või INDEX XMATCH-valemi abil Excel 365-s), saate võimalikke vigu püüda ja käsitleda sama tehnikat kasutades - funktsioon ISERROR kontrollib vigade olemasolu ja IF kuvab määratud teksti, kui mõni viga esineb.

Oletame, et otsingutabeli esimeses veerus on ajad. Kuna VLOOKUP ei suuda vaadata vasakule, kasutame valemit INDEX MATCH, et tõmmata ajad veerust D:

=INDEX($D$3:$D$10, MATCH(A3, $E$3:$E$10, 0))

Ja siis pesitsete selle ülalnimetatud üldvalemisse, et asendada tabatud vead mis tahes tekstiga, mida soovite:

=IF(ISERROR(INDEX($D$3:$D$10, MATCH(A3, $E$3:$E$10, 0))), "Not qualified", INDEX($D$3:$D$10, MATCH(A3, $E$3:$E$10, 0)))

Märkus. Nagu ka IF ISERROR VLOOKUP valemi puhul, on mõistlikum püüda ainult #N/A vigu ja mitte varjata võimalikke probleeme valemiga endaga. Selleks mähkige oma INDEX MATH valemiga IFNA Excel 2013 ja uuemates versioonides või IF ISNA varasemates versioonides.

IF ISERROR Jah/ei valemiga

Kõikides eelnevates näidetes tagastas IF ISERROR põhivalemi tulemuse, kui see ei ole viga. See võib aga töötada ka teisiti - tagastada midagi, kui viga ja midagi muud, kui viga ei ole.

Oletame, et meie näidisandmestiku puhul ei huvita teid täpsed ajad, vaid soovite lihtsalt teada, millised osalejad grupist A on kvalifitseeritud ja millised mitte. Selleks kasutage funktsiooni MATCH, et võrrelda veerus A olevat nime veerus D oleva kvalifitseeritud osalejate nimekirjaga, ja serveerige tulemused ISERRORile. Kui nimi ei ole veerus D olemas (MATCH annab vea), saateIF-funktsioon, et kuvada "Ei" või "Ei kvalifitseeru". Kui nimi ilmub veerus D (viga ei esine), tagastab "Jah" või "Kvalifitseeru".

=IF(ISERROR(MATCH(A3, $D$3:$D$10, 0)), "No", "Yes" )

Kuidas lugeda vigade arvu

Selleks, et saada veamäär teatavas veerus, peate kontrollima vahemikku, mitte ainult ühte lahtrit. Selleks "sööda" sihtvahemikku ISERRORile ja sundida tagastatavad boolaarsed väärtused 1-ks ja 0-ks, kasutades kahekordset unaarilist operaatorit (--). Funktsioon SUM või SUMPRODUCT võib arvud kokku liita ja anda lõpptulemuse.

Näiteks:

=SUM(--ISERROR(C2:C10))

Pange tähele, et see toimib tavalise valemina ainult Excel 365 ja Excel 2021, mis toetavad dünaamilisi massiive. Excel 2019 ja varasemates programmides peate massiivi valemi loomiseks vajutama Ctrl + Shift + Enter (ärge kirjutage käsitsi kumerad sulgud, see ei tööta!):

{=SUM(--ISERROR(C2:C10))}

Alternatiivina saate kasutada funktsiooni SUMPRODUCT, mis käsitleb massiive algselt, nii et valemit saab kõigis versioonides täita tavalise Enter-klahviga:

=SUMPRODUCT(--ISERROR(C2:C10))

Erinevus ISERRORi ja IFERRORi vahel Excelis

Nii ISERROR kui ka IFERROR funktsioone kasutatakse Exceli vigade püüdmiseks ja käsitlemiseks. Erinevus on järgmine:

• Puhtal kujul testib ISERROR lihtsalt, kas väärtus on viga või mitte. See on saadaval kõigis Exceli versioonides.
• Funktsioon IFERROR on mõeldud vigade mahasurumiseks või varjamiseks - kui leitakse viga, tagastab see mõne teise, teie poolt määratud väärtuse. See on saadaval Excel 2007 ja uuemates versioonides.

Esmapilgul näib IFERROR olevat IF ISERROR valemi lühivariant. Lähemal vaatlusel märkate aga erinevust:

• IFERROR võimaldab määrata ainult value_if_error Kui viga ei esine, tagastab see alati testitud väärtuse/vormeli tulemuse.
• IF ISERROR pakub rohkem paindlikkust ja võimaldab käsitleda mõlemat olukorda - mis peaks juhtuma, kui viga ja mis siis, kui viga ei esine.

Selle punkti paremaks illustreerimiseks vaadake neid valemeid:

=IFERROR(A1, "Arvutusviga")

=IF(ISERROR(A1), "Arvutusviga", A1)

Need kaks valemit on samaväärsed - mõlemad kontrollivad valemiga määratud väärtust A1 ja tagastavad "Arvutusviga", kui tegemist on veaga, vastasel juhul - tagastavad väärtuse.

Aga mis siis, kui soovite teha mingi arvutuse, kui väärtus A1 ei ole viga? Funktsioon IFERROR ei suuda seda teha. IF ISERRORi puhul tuleb lihtsalt kirjutada viimasesse argumenti soovitud arvutus. Näiteks:

=IF(ISERROR(A1), "Arvutusviga", A1*2)

Nagu näete, võib see pikem variant IFERROR valemist, mida sageli peetakse aegunuks, olla siiski kasulik :)

Saadaolevad allalaadimised

ISERROR valemi näited (.xlsx fail)