Tha an oideachadh a’ toirt sùil air cleachdaidhean practaigeach na gnìomh Excel ISERROR agus a’ sealltainn mar a nì thu deuchainn air diofar fhoirmlean airson mhearachdan.

Nuair a sgrìobhas tu foirmle nach eil Excel a’ tuigsinn no nach urrainn obrachadh a-mach, bidh e a’ tarraing d’ aire chun duilgheadas le bhith a’ sealltainn teachdaireachd mearachd. 'S urrainn dhan ghnìomh ISERROR do chuideachadh le bhith a' glacadh mhearachdan agus roghainn eile a thoirt dhut nuair a lorgar mearachd.

Glacaidh an gnìomh Excel ISERROR a h-uile seòrsa mearachd, a’ toirt a-steach #CALC !, #DIV/0 !, #N/A, #NAME?, #NUM!, #NULL!, #REF!, #VALUE!, agus #SPILL !. Is e an toradh luach Boolean: TRUE ma lorgar mearachd, FALSE a chaochladh.

Tha an gnìomh ri fhaighinn anns a h-uile tionndadh de Excel 2000 tro 2021 agus Excel 365.

Co-chòrdadh an ISERROR tha an gnìomh cho sìmplidh ri seo:

Càite a bheil luach an luach cealla no am foirmle ri sgrùdadh airson mhearachdan.

Excel ISERROR (value)

Gus foirmle ISERROR a chruthachadh anns an fhoirm as sìmplidhe, thoir iomradh air a' chill a tha thu airson a dhearbhadh airson mhearachdan. Mar eisimpleir:

=ISERROR(A2)

Air eagal ‘s gun lorgar mearachd, gheibh thu TRUE. Mura h-eil mearachd sa chill a chaidh a dhearbhadh, gheibh thu FALSE:

IF ISERROR foirmle ann an Excel

Gus teachdaireachd àbhaisteach a thilleadh no teachdaireachd àbhaisteach a dhèanamh àireamhachadh eadar-dhealaichte nuair a thachras mearachd, cleachd ISERROR còmhla ris a’ ghnìomh IF. Tha am foirmle coitcheann a’ coimhead mar a leanas:

Air eadar-theangachadh gu cànan daonna, tha e ag ràdh: ma thig am prìomh fhoirmle gu buil ann am mearachd, seall an teacsa ainmichte no ruith àireamhachadh eile, no tillidh tu toradh àbhaisteach na foirmle.

San dealbh gu h-ìosal, le bhith a' roinneadh an àireamh gu lèir leis an àireamh bidh mearachd no dhà anns a' phrìs colbh:

Gus teacsa gnàthaichte a chur an àite a h-uile còd mearachd eadar-dhealaichte, faodaidh tu am foirmle IF ISERROR a leanas a chleachdadh:

=IF(ISERROR(A2/B2), "Unknown", A2/B2)

Ann an Excel 2007 agus tionndaidhean nas fhaide air adhart, faodar an aon toradh a choileanadh le cuideachadh bhon ghnìomh IFERROR a chaidh a thogail a-steach:

=IFERROR(A2/B2, "Unknown")

Bu chòir dha a bhith thug e fa-near gu bheil am foirmle IFERROR a' ruith beagan nas luaithe a chionn 's gu bheil e a' coileanadh àireamhachadh A2/B2 dìreach aon turas. Ged a tha IFERROR ga obrachadh a-mach dà uair - an toiseach feuch an cruthaich e mearachd agus an uairsin a-rithist ma tha an deuchainn FALSE.

IF ISERROR VLOOKUP foirmle

Tha cleachdadh ISERROR le VLOOKUP, gu dearbh, na chùis shònraichte den IF IS Foirmle ERROR air a dheasbad gu h-àrd. Nuair nach urrainn don ghnìomh VLOOKUP an luach sgrùdaidh a lorg no ma dh’ fhailicheas e air adhbhar sam bith eile, seallaidh tu teachdaireachd teacsa gnàthaichte le bhith a’ cleachdadh a’ cho-aontar seo:

Airson an eisimpleir seo, tarraing sinn na h-amannan bhon chlàr sgrùdaidh (D3: E10) chun phrìomh chlàr (A3: B15). Mura h-eil an luach lorg (ainm a’ chom-pàirtiche) ann am faidhlelorg clàr, tillidh sinn "Gun teisteanas".

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$10, 2, FALSE)), "Not qualified", VLOOKUP(A3, $D$3:$E$10, 2, FALSE))

Tip. Ma tha thu airson teacsa àbhaisteach a thaisbeanadh a-mhàin nuair nach lorgar luach lorg (mearachd # N/A) a’ seachnadh mhearachdan eile, cleachd am foirmle IFNA VLOOKUP ann an Excel 2013 agus nas fhaide air adhart no IF ISNA VLOOKUP ann an seann tionndaidhean.

IF ISERROR INDEX MATCH foirmle

Nuair a nì thu sgrùdadh le cuideachadh bhon mheasgachadh INDEX MATCH (no foirmle INDEX XMATCH ann an Excel 365), faodaidh tu mearachdan sam bith a ghlacadh agus a làimhseachadh le bhith a’ cleachdadh an aon dòigh - nì an gnìomh ISERROR sgrùdadh airson mhearachdan agus seallaidh IF an teacsa ainmichte nuair a thachras mearachd sam bith.

Can gu bheil amannan sa chiad cholbh sa chlàr sgrùdaidh. Leis nach urrainn do VLOOKUP coimhead air an taobh chlì aige, bidh sinn a’ cleachdadh an fhoirmle INDEX MATCH gus na h-amannan a tharraing bho cholbh D:

=INDEX($D$3:$D$10, MATCH(A3, $E$3:$E$10, 0))

Agus an uairsin, bidh thu ga neadachadh anns an fhoirmle choitcheann gu h-àrd. gus teacsa sam bith a tha thu ag iarraidh a chur an àite nam mearachdan a chaidh an glacadh:

=IF(ISERROR(INDEX($D$3:$D$10, MATCH(A3, $E$3:$E$10, 0))), "Not qualified", INDEX($D$3:$D$10, MATCH(A3, $E$3:$E$10, 0)))

Nota. Coltach ris an fhoirmle IF ISERROR VLOOKUP, tha e nas ciallaiche mearachdan #N/A a-mhàin a ghlacadh agus na cuir am falach duilgheadasan a dh’ fhaodadh a bhith ann leis an fhoirmle fhèin. Airson seo, paisg am foirmle INDEX MATH agad ann an IFNA ann an Excel 2013 agus nas àirde no IF ISNA ann an dreachan nas tràithe.

IFISERROR Tha/Chan eil foirmle

Anns a h-uile h-eisimpleir roimhe, IF ISERROR toradh a' phrìomh fhoirmle air ais mura h-e mearachd a th' ann. Ach, faodaidh e obrachadh ann an dòigh eile cuideachd - till rudeigin ma tha mearachd ann agus rudeigin eile mura h-eil mearachd ann.

Anns an t-seata-dàta sampall againn, is dòcha nach eil ùidh agad anns na dearbh amannan, tha thu dìreach airson faighinn a-mach dè na com-pàirtichean ann am buidheann A a tha barrantaichte agus cò aig nach eil. Gus seo a dhèanamh, cleachd an gnìomh MATCH gus coimeas a dhèanamh eadar an t-ainm ann an colbh A agus an liosta de chom-pàirtichean le teisteanas ann an colbh D, agus an uairsin cuir na toraidhean gu ISERROR. Mura h-eil an t-ainm ri fhaighinn ann an colbh D (tillidh MATCH mearachd), faigh an gnìomh IF gus “Chan eil” no “Gun teisteanas” a thaisbeanadh. Ma nochdas an t-ainm ann an colbh D (chan eil mearachd), till "Tha" no "Barrantaichte".

=IF(ISERROR(MATCH(A3, $D$3:$D$10, 0)), "No", "Yes" )

Mar a chunntas tu an àireamh mhearachdan

Gus an àireamh de mhearachdan ann an colbh sònraichte fhaighinn, feumaidh tu raon a sgrùdadh, chan e dìreach aon chealla. Airson seo, "feed" an raon targaid gu ISERROR agus co-èignich na luachan Boolean a chaidh a thilleadh gu 1's agus 0's a 'cleachdadh a' ghnìomhaiche dùbailte unary (--). Faodaidh an gnìomh SUM no SUMPRODUCT na h-àireamhan a chur suas agus an toradh deireannach a lìbhrigeadh.

Mar eisimpleir:

=SUM(--ISERROR(C2:C10))

Thoir an aire, tha seo ag obair mar fhoirmle àbhaisteach a-mhàin ann an Excel 365 agus Excel 2021, a bheir taic do arrays fiùghantach. Ann an Excel 2019 agus nas tràithe, tha thufeumaidh tu Ctrl + Shift + Enter a bhrùthadh gus foirmle rèite a chruthachadh (na cuir a-steach camagan lùbach le làimh, chan obraich sin!):

{=SUM(--ISERROR(C2:C10))}

Air neo, faodaidh tu an SUMPRODUCT a chleachdadh gnìomh a bhios a’ làimhseachadh arrays gu dùthchasach, agus mar sin faodar am foirmle a lìonadh leis an iuchair Enter àbhaisteach anns a h-uile tionndadh:

=SUMPRODUCT(--ISERROR(C2:C10))

Diofar eadar ISERROR agus IFERROR ann an Excel

Tha an dà chuid gnìomh ISERROR agus IFERROR gan cleachdadh gus mearachdan ann an Excel a ghlacadh agus a làimhseachadh. Tha an diofar mar a leanas:

• Anns a chruth fhìor-ghlan, tha ISERROR dìreach a' dèanamh deuchainn a bheil an luach na mhearachd no nach eil. Tha e ri fhaighinn anns a h-uile tionndadh de Excel.
• Tha an gnìomh IFERROR air a dhealbh gus mearachdan a chasg no a chur am falach - nuair a lorgar mearachd, tillidh e luach eile a shònraich thu. Tha e ri fhaighinn ann an Excel 2007 agus nas àirde.

Aig a' chiad sealladh, tha IFERROR a' coimhead coltach ri làmh-ghoirid eile seach foirmle IF ISERROR. Ma bheir thu sùil nas mionaidiche, ge-tà, mothaichidh tu an diofar:

17> Leigidh IFERROR leat dìreach value_if_error a shònrachadh. Mur eil mearachd ann, tillidh e toradh an luach/foirmle a chaidh a dhearbhadh an-còmhnaidh.
• IF ISERROR a' toirt barrachd sùbailteachd agus a' leigeil leat an dà shuidheachadh a làimhseachadh - dè bu chòir tachairt ma tha mearachd ann agus dè mura h-eil mearachd ann.<18

Gus am puing a shoilleireachadh nas fheàrr, smaoinich air na foirmlean seo:

=IFERROR(A1, "Calculation error")

=IF(ISERROR(A1), "Calculation error", A1)

Tha an dà fhoirmle seo co-ionann - bidh an dà chuid a’ sgrùdadh luach air a stiùireadh le foirmle ann an A1 agus till air ais"Mearachd àireamhachaidh" mas e mearachd a th' ann, air neo - till an luach.

Ach dè ma tha thu airson beagan àireamhachaidh a dhèanamh mur eil an luach ann an A1 na mhearachd? Chan urrainn dhan ghnìomh IFERROR sin a dhèanamh. Air eagal IF ISERROR, dìreach taip an àireamhachadh a tha thu ag iarraidh san argamaid mu dheireadh. Mar eisimpleir:

=IF(ISERROR(A1), "Calculation error", A1*2)

Mar a chì thu, faodaidh an atharrachadh nas fhaide seo air an fhoirmle IFERROR, a thathas gu tric a' meas seann-fhasanta, a bhith feumail fhathast :)

Luchdaich sìos ri fhaighinn<7

Eisempleirean foirmle ISERROR (faidhle .xlsx)