Udžbenik pokazuje kako napisati izjavu IF OR u Excelu za provjeru različitih uvjeta "ovo ILI ono".

IF je jedna od najpopularnijih Excel funkcija i vrlo korisna samostalno. U kombinaciji s logičkim funkcijama kao što su I, ILI i NE, funkcija IF ima još veću vrijednost jer omogućuje testiranje više uvjeta u željenim kombinacijama. U ovom ćemo se vodiču usredotočiti na korištenje formule IF-and-OR u Excelu.

Izjava IF OR u Excelu

Za procjenu dva ili više uvjeta i vraćanje jednog rezultat ako je bilo koji od uvjeta TRUE, i drugi rezultat ako su svi uvjeti FALSE, ugradite funkciju OR u logički test IF:

Na jednostavnom engleskom, logika formule može se formulirati na sljedeći način: Ako je ćelija "ovo" ILI "ono", poduzmite jednu radnju, ako nije, učinite nešto drugo .

Ovo je primjer formule IF OR u najjednostavnijem obliku:

=IF(OR(B2="delivered", B2="paid"), "Closed", "Open")

Ono što formula kaže je sljedeće: ako ćelija B2 sadrži "isporučeno" ili " plaćen", označite narudžbu kao "Zatvoreno", inače "Otvoreno".

U slučaju da ne želite ništa vratiti ako je logično test daje vrijednost FALSE , uključite prazan niz ("") u zadnji argument:

=IF(OR(B2="delivered", B2="paid"), "Closed", "")

Ista formula može se napisati i u kompaktnijem obliku koristeći konstantu polja :

=IF(OR(B2={"delivered","paid"}), "Closed", "")

U slučaju posljednjegargument izostavljen, formula će prikazati FALSE kada niti jedan od uvjeta nije ispunjen.

Napomena. Obratite pozornost da formula IF OR u Excelu ne razlikuje mala i velika slova jer funkcija OR ne razlikuje velika i mala slova . U našem slučaju, "isporučeno", "isporučeno" i "ISPORUČENO", sve se smatraju istom riječi. Ako želite razlikovati velika i mala slova u tekstu, zamotajte svaki argument funkcije OR u EXACT kao što je prikazano u ovom primjeru.

Primjeri formula IF OR u programu Excel

U nastavku ćete pronaći još nekoliko primjera zajedničkog korištenja Excelovih funkcija IF i OR koje će vam dati više ideja o tome kakve biste logičke testove mogli pokrenuti.

Formula 1. IF s višestrukim uvjetima ILI

Ne postoji određeno ograničenje za broj uvjeta ILI ugrađenih u formulu IF sve dok je u skladu s općim ograničenjima programa Excel:

• U programu Excel 2007 i novijim verzijama dopušteno je do 255 argumenata ukupne duljine ne prelazi 8192 znaka.
• U programu Excel 2003 i starijim verzijama možete koristiti do 30 argumenata, a ukupna duljina ne smije premašiti 1024 znaka.

Kao primjer, provjerimo stupci A, B i C za prazne ćelije i vraćaju "Nepotpuno" ako je barem jedna od 3 ćelije prazna. Zadatak se može izvršiti sljedećom funkcijom IF OR:

=IF(OR(A2="",B2="",),"Incomplete","")

I rezultat će izgledati sličnoovo:

Formula 2. Ako je ćelija ovo ILI ono, tada izračunajte

Tražite formulu koja može učiniti nešto složenije od vraćanja unaprijed definiranog tekst? Samo ugniježdite drugu funkciju ili aritmetičku jednadžbu u value_if_true i/ili value_if_false argumente IF.

Recimo, izračunali ste ukupni iznos za narudžbu ( Kol. pomnoženo s Jediničnom cijenom ) i želite primijeniti popust od 10% ako je ispunjen bilo koji od ovih uvjeta:

• u B2 je veće ili jednako 10, ili
• Jedinična cijena u C2 je veća ili jednaka 5 USD.

Dakle, koristite funkciju OR da provjerite oba uvjeta, i ako rezultat je TRUE, smanjite ukupni iznos za 10% (B2*C2*0.9), inače vratite punu cijenu (B2*C2):

=IF(OR(B2>=10, C2>=5), B2*C2*0.9, B2*C2)

Dodatno, možete koristiti donju formulu za eksplicitno označavanje narudžbi s popustom:

=IF(OR(B2>=10, C2>=5),"Yes", "No")

Snimak zaslona u nastavku prikazuje obje formule u djelu:

Formula 3. Slučaj -osjetljiva formula IF OR

Kao što je već spomenuto, funkcija Excel OR po prirodi ne razlikuje velika i mala slova. Međutim, vaši podaci mogu biti osjetljivi na velika i mala slova pa biste željeli pokrenuti testove ILI koji razlikuju velika i mala slova . U tom slučaju izvedite svaki pojedinačni logički test unutar funkcije EXACT i ugniježdite te funkcije u naredbu OR.

U ovom primjeru, pronađimo i označimo ID-ove naloga "AA-1" i "BB-1":

=IF(OR(EXACT(A2, "AA-1"), EXACT(A2, "BB-1")), "x", "")

Kao rezultat, samo dva ID-a naloga gdje sva slova su velika i označena su sa "x"; slični ID-ovi kao što su "aa-1" ili "Bb-1" nisu označeni:

Formula 4. Ugniježđene IF OR izjave u Excelu

U situacijama kada želite testirati nekoliko skupova kriterija ILI i vratiti različite vrijednosti ovisno o rezultatima tih testova, napišite pojedinačnu formulu IF za svaki skup kriterija "ovo ILI ono" i ugniježdite te IF-ove jedan u drugi.

Da demonstriramo koncept, provjerimo nazive stavki u stupcu A i vratimo "Voće" za Jabuku ili Naranču i "Povrće" za Rajčicu ili Krastavac :

=IF(OR(A2="apple", A2="orange"), "Fruit", IF(OR(A2="tomato", A2="cucumber"), "Vegetable", ""))

Za više informacija pogledajte Ugniježđeni IF s OR/AND uvjetima.

Formula 5. Izjava AKO I ILI

Da biste procijenili razne kombinacije različitih uvjeta, možete napraviti I kao i ILI logičke testove unutar jedne formule.

Na primjer, idemo za označavanje redaka gdje je stavka u stupcu A ili Jabuka ili Naranča , a količina u stupcu B je veća od 10:

=IF(AND(OR(A2="apple",A2="orange"), B2>10), "x", "")

Za više informacija n, pogledajte Excel IF s više uvjeta I/ILI.

Tako koristite funkcije IF i OR zajedno. Kako biste pobliže pogledali formule o kojima se govori u ovom kratkom vodiču, dobrodošli stepreuzmite našu oglednu radnu knjigu programa Excel IF OR. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeći tjedan!