Ohjeessa näytetään, miten Excelissä kirjoitetaan IF OR -lause, jolla tarkistetaan erilaisia "tämä TAI tuo" -ehtoja.

IF on yksi suosituimmista Excelin funktioista ja erittäin hyödyllinen yksinään. Yhdistettynä loogisiin funktioihin, kuten AND, OR ja NOT, IF-funktiolla on vielä enemmän arvoa, koska sen avulla voidaan testata useita ehtoja halutuilla yhdistelmillä. Tässä opetusohjelmassa keskitymme IF- ja OR-kaavan käyttöön Excelissä.

IF OR -lauseke Excelissä

Jos haluat arvioida kahta tai useampaa ehtoa ja palauttaa yhden tuloksen, jos jokin ehdoista on TODELLINEN, ja toisen tuloksen, jos kaikki ehdot ovat VÄÄRÄT, sulauta OR-funktio IF:n loogiseen testiin:

Selkokielellä kaavan logiikka voidaan muotoilla seuraavasti: Jos solu on "tämä" TAI "tuo", tee yksi toimenpide, jos ei, tee jotain muuta.

Tässä on esimerkki IF OR -kaavasta yksinkertaisimmillaan:

=IF(OR(B2="toimitettu", B2="maksettu"), "Suljettu", "Avoin")

Kaava sanoo seuraavaa: Jos solu B2 sisältää "toimitettu" tai "maksettu", merkitse tilaus "Suljettu", muuten "Avoin".

Jos haluat ei palauta mitään jos looginen testi on FALSE , sisällytä tyhjä merkkijono ("") viimeiseen argumenttiin:

=IF(OR(B2="toimitettu", B2="maksettu"), "Suljettu", "")

Sama kaava voidaan kirjoittaa myös kompaktimmassa muodossa käyttämällä array-vakiota:

=IF(OR(B2={"toimitettu", "maksettu"}), "Suljettu", "")

Jos viimeinen argumentti jätetään pois, kaava näyttää FALSE, kun mikään ehdoista ei täyty.

Huomaa, että Excelin IF OR -kaava ei erota pieniä ja isoja kirjaimia, koska OR-funktio on case-insensitive Tapauksessamme "delivered", "Delivered" ja "DELIVERED" katsotaan kaikki samaksi sanaksi. Jos haluat erottaa tekstin tapaukset toisistaan, kiedo OR-funktion jokainen argumentti EXACT:iin, kuten tässä esimerkissä.

Excel IF OR -kaavan esimerkkejä

Alla on vielä muutamia esimerkkejä Excelin IF- ja OR-funktioiden käytöstä yhdessä, jotka antavat sinulle lisää ideoita siitä, millaisia loogisia testejä voit suorittaa.

Kaava 1. IF useilla OR-ehdoilla

IF-kaavaan upotettujen TAI-ehtojen lukumäärälle ei ole erityistä rajoitusta, kunhan se on Excelin yleisten rajoitusten mukainen:

• Excel 2007:ssä ja sitä uudemmissa ohjelmissa sallitaan enintään 255 argumenttia, joiden kokonaispituus saa olla enintään 8 192 merkkiä.
• Excel 2003:ssa ja sitä uudemmissa ohjelmissa voit käyttää enintään 30 argumenttia, ja kokonaispituus saa olla enintään 1024 merkkiä.

Tarkistetaan esimerkiksi sarakkeet A, B ja C tyhjien solujen varalta ja palautetaan "Epätäydellinen", jos vähintään yksi kolmesta solusta on tyhjä. Tehtävä voidaan suorittaa seuraavalla IF OR -funktiolla:

=IF(OR(A2="",B2="",),"Incomplete","")

Tulos näyttää samankaltaiselta kuin tämä:

Kaava 2. Jos solu on tämä TAI tuo, laske seuraavat luvut

Etsitkö kaavaa, joka voi tehdä jotain monimutkaisempaa kuin palauttaa ennalta määritetyn tekstin? Pane vain toinen funktio tai aritmeettinen yhtälö kohtaan value_if_true ja/tai value_if_false IF:n argumentit.

Oletetaan, että lasket tilauksen kokonaissumman ( Määrä. kerrottuna Yksikköhinta ) ja haluat soveltaa 10 prosentin alennusta, jos jompikumpi näistä ehdoista täyttyy:

• B2:ssa on vähintään 10, tai
• Yksikköhinta C2:ssa on vähintään 5 dollaria.

Käytä siis OR-funktiota molempien ehtojen tarkistamiseen, ja jos tulos on TRUE, vähennä kokonaissummaa 10 % (B2*C2*0,9), muuten palauta koko hinta (B2*C2):

=IF(OR(B2>=10, C2>=5), B2*C2*0.9, B2*C2)

Lisäksi voit käyttää alla olevaa kaavaa ilmaistaksesi selkeästi alennetut tilaukset:

=IF(OR(B2>=10, C2>=5), "Kyllä", "Ei")

Alla olevassa kuvakaappauksessa näkyy molemmat kaavat toiminnassa:

Kaava 3. Case-sensitive IF OR -kaava.

Kuten jo mainittiin, Excelin OR-funktio on luonnostaan isoja ja pieniä kirjaimia erittelemätön. Tietosi saattavat kuitenkin olla isoja ja pieniä kirjaimia eritteleviä, joten haluat suorittaa seuraavasti isojen ja pienten kirjainten väliset OR-testit Tässä tapauksessa suoritetaan jokainen yksittäinen looginen testi EXACT-funktion sisällä ja yhdistetään nämä funktiot OR-lauseeseen.

Tässä esimerkissä etsitään ja merkitään tilaustunnukset "AA-1" ja "BB-1":

=IF(OR(EXACT(A2, "AA-1"), EXACT(A2, "BB-1")), "x", "")

Tämän seurauksena vain kaksi tilauksen tunnusta, joissa kaikki kirjaimet ovat isoja, merkitään "x"-merkinnällä; samankaltaisia tunnuksia, kuten "aa-1" tai "Bb-1", ei merkitä:

Kaava 4. Sisäkkäiset IF OR -lausekkeet Excelissä

Tilanteissa, joissa haluat testata useita TAI-kriteerikokonaisuuksia ja palauttaa eri arvoja testien tuloksista riippuen, kirjoita yksittäinen IF-kaava jokaiselle "tämä TAI tuo" -kriteerikokonaisuudelle ja aseta nämä IF:t toisiinsa.

Konseptin havainnollistamiseksi tarkistetaan sarakkeessa A olevat nimikkeet ja palautetaan "Fruit", kun kyseessä on "Fruit". Apple tai Oranssi ja "Vegetable", kun kyseessä on Tomaatti tai Kurkku :

=IF(OR(A2="omena", A2="appelsiini"), "Hedelmä", IF(OR(A2="tomaatti", A2="kurkku"), "Vihannes", ""))

Lisätietoja on kohdassa Sisäkkäiset IF- ja OR/AND-ehdot.

Kaava 5. IF AND OR -lauseke

Voit arvioida eri ehtojen erilaisia yhdistelmiä tekemällä AND- ja OR-loogisia testejä yhden kaavan sisällä.

Merkitään esimerkiksi rivit, joissa sarakkeessa A oleva kohde on joko seuraava Apple tai Oranssi ja sarakkeessa B oleva määrä on suurempi kuin 10:

=IF(AND(OR(A2="omena",A2="appelsiini"), B2>10), "x", "")

Lisätietoja on kohdassa Excel IF useilla AND/OR-ehdoilla.

Näin käytät IF- ja OR-funktioita yhdessä. Jos haluat tutustua tarkemmin tässä lyhyessä opetusohjelmassa käsiteltyihin kaavoihin, voit ladata Excelin IF OR-työkirjan. Kiitos lukemisesta ja toivottavasti tapaamme blogissamme ensi viikolla!