L'esercitazione mostra come scrivere un'istruzione IF OR in Excel per verificare varie condizioni "questo OR quello".

La funzione IF è una delle funzioni più popolari di Excel ed è molto utile da sola. Combinata con le funzioni logiche come AND, OR e NOT, la funzione IF ha ancora più valore perché permette di verificare più condizioni nelle combinazioni desiderate. In questa esercitazione ci concentreremo sull'uso della formula IF e OR in Excel.

Istruzione IF OR in Excel

Per valutare due o più condizioni e restituire un risultato se una qualsiasi delle condizioni è VERA e un altro risultato se tutte le condizioni sono FALSE, è necessario incorporare la funzione OR nel test logico di IF:

In parole povere, la logica della formula può essere formulata come segue: se una cella è "questo" OPPURE "quello", eseguire un'azione, altrimenti fare qualcos'altro.

Ecco un esempio della formula IF OR nella sua forma più semplice:

=IF(OR(B2="consegnato", B2="pagato"), "Chiuso", "Aperto")

La formula dice: se la cella B2 contiene "consegnato" o "pagato", contrassegnare l'ordine come "chiuso", altrimenti "aperto".

Nel caso in cui si voglia non restituire nulla se il il test logico valuta FALSO includere una stringa vuota ("") nell'ultimo argomento:

=IF(OR(B2="consegnato", B2="pagato"), "Chiuso", "")

La stessa formula può essere scritta in forma più compatta utilizzando una costante di array:

=IF(OR(B2={"consegnato", "pagato"}), "Chiuso", "")

Se l'ultimo argomento viene omesso, la formula visualizzerà FALSO quando nessuna delle condizioni è soddisfatta.

Nota: si prega di prestare attenzione al fatto che una formula IF OR in Excel non distingue tra caratteri minuscoli e maiuscoli poiché la funzione OR è senza distinzione tra maiuscole e minuscole Nel nostro caso, "consegnato", "Consegnato" e "CONSEGNATO" sono tutti considerati la stessa parola. Se si desidera distinguere il caso del testo, avvolgere ogni argomento della funzione OR in EXACT come mostrato in questo esempio.

Esempi di formula IF OR di Excel

Di seguito troverete alcuni altri esempi di utilizzo delle funzioni IF e OR di Excel, che vi daranno ulteriori idee sul tipo di test logici che potreste eseguire.

Formula 1. IF con condizioni OR multiple

Non esiste un limite specifico al numero di condizioni OR inserite in una formula IF, purché sia conforme alle limitazioni generali di Excel:

• In Excel 2007 e versioni successive, sono consentiti fino a 255 argomenti, con una lunghezza totale non superiore a 8.192 caratteri.
• In Excel 2003 e versioni successive, è possibile utilizzare fino a 30 argomenti e la lunghezza totale non deve superare i 1.024 caratteri.

Ad esempio, controlliamo le colonne A, B e C per verificare la presenza di celle vuote e restituiamo "Incompleto" se almeno una delle tre celle è vuota. Il compito può essere svolto con la seguente funzione IF OR:

=IF(OR(A2="",B2="",),"Incomplete","")

Il risultato sarà simile a questo:

Formula 2. Se una cella è questa OPPURE quella, calcolare

Se si cerca una formula che possa fare qualcosa di più complesso che restituire un testo predefinito, basta annidare un'altra funzione o un'equazione aritmetica nell'elemento valore_se_vero e/o valore_se_falso argomenti di IF.

Supponiamo di calcolare l'importo totale di un ordine ( Qtà. moltiplicato per Prezzo unitario ) e si vuole applicare lo sconto del 10% se una di queste condizioni è soddisfatta:

• in B2 è maggiore o uguale a 10, oppure
• Prezzo unitario in C2 è maggiore o uguale a 5 dollari.

Quindi, si utilizza la funzione OR per verificare entrambe le condizioni e, se il risultato è VERO, si diminuisce l'importo totale del 10% (B2*C2*0,9), altrimenti si restituisce il prezzo pieno (B2*C2):

=IF(OR(B2>=10, C2>=5), B2*C2*0,9, B2*C2)

Inoltre, è possibile utilizzare la formula seguente per indicare esplicitamente gli ordini scontati:

=IF(OR(B2>=10, C2>=5), "Sì", "No")

L'immagine seguente mostra entrambe le formule in azione:

Formula 3. Formula IF OR sensibile alle maiuscole e minuscole

Come già detto, la funzione OR di Excel è per sua natura insensibile alle maiuscole e alle minuscole. Tuttavia, i vostri dati potrebbero essere sensibili alle maiuscole e alle minuscole e quindi dovreste eseguire test OR sensibili alle maiuscole e alle minuscole In questo caso, eseguire ogni singolo test logico all'interno della funzione EXACT e annidare queste funzioni nell'istruzione OR.

In questo esempio, individuiamo e contrassegniamo gli ID degli ordini "AA-1" e "BB-1":

=IF(OR(EXACT(A2, "AA-1"), EXACT(A2, "BB-1")), "x", "")

Di conseguenza, solo due ID di ordini in cui le lettere sono tutte maiuscole sono contrassegnati da una "x"; ID simili come "aa-1" o "Bb-1" non vengono segnalati:

Formula 4. Istruzioni IF OR annidate in Excel

Nelle situazioni in cui si desidera testare alcune serie di criteri OR e restituire valori diversi a seconda dei risultati di tali test, scrivere una formula IF individuale per ogni serie di criteri "questo OR quello" e annidare tali IF l'uno nell'altro.

Per dimostrare il concetto, controlliamo i nomi degli elementi nella colonna A e restituiamo "Frutta" per Mela o Arancione e "Vegetale" per Pomodoro o Cetriolo :

=IF(OR(A2="mela", A2="arancia"), "Frutta", IF(OR(A2="pomodoro", A2="cetriolo"), "Verdura", ""))

Per ulteriori informazioni, vedere IF annidato con condizioni OR/AND.

Formula 5. Istruzione IF AND OR

Per valutare varie combinazioni di condizioni diverse, è possibile eseguire test logici AND e OR all'interno di una singola formula.

A titolo di esempio, si segnalano le righe in cui l'elemento della colonna A è o Mela o Arancione e la quantità nella colonna B è superiore a 10:

=IF(AND(OR(A2="mela",A2="arancia"), B2>10), "x", "")

Per ulteriori informazioni, consultare Excel IF con condizioni multiple AND/OR.

Ecco come si usano le funzioni IF e OR insieme. Per dare un'occhiata più da vicino alle formule discusse in questo breve tutorial, potete scaricare la nostra cartella di lavoro di Excel IF OR di esempio. Vi ringrazio per la lettura e spero di vedervi sul nostro blog la prossima settimana!