Taula de continguts
El tutorial mostra com escriure una instrucció SI O a Excel per comprovar si hi ha diverses condicions "això O allò".
SI és una de les funcions d'Excel més populars i molt útil. per si mateix. Combinada amb les funcions lògiques com AND, OR i NOT, la funció SI té encara més valor perquè permet provar múltiples condicions en les combinacions desitjades. En aquest tutorial, ens centrarem a utilitzar la fórmula IF i OR a Excel.
Declaració SI OR a Excel
Per avaluar dues o més condicions i retornar una resultat si alguna de les condicions és VERTADERA i un altre resultat si totes les condicions són FALSES, incrusteu la funció OR a la prova lògica de SI:
IF(OR( condició1, condició2,...), value_if_true, value_if_false)En anglès senzill, la lògica de la fórmula es pot formular de la següent manera: Si una cel·la és "això" O "això", feu una acció, si no, feu una altra cosa. .
Aquí teniu un exemple de la fórmula SI O en la forma més simple:
=IF(OR(B2="delivered", B2="paid"), "Closed", "Open")
El que diu la fórmula és això: si la cel·la B2 conté "entregat" o " pagat", marqueu la comanda com a "Tancada", en cas contrari "Oberta".
En cas que no vulgueu retornar res si el lògic La prova s'avalua com a FALSE , inclou una cadena buida ("") a l'últim argument:
=IF(OR(B2="delivered", B2="paid"), "Closed", "")
La mateixa fórmula també es pot escriure en una forma més compacta utilitzant una constant de matriu :
=IF(OR(B2={"delivered","paid"}), "Closed", "")
En cas que sigui l'últims'omet l'argument, la fórmula mostrarà FALSE quan no es compleixi cap de les condicions.
Nota. Si us plau, tingueu en compte que una fórmula SI O a Excel no distingeix entre caràcters en minúscules i majúscules perquè la funció O és insensible a majúscules . En el nostre cas, "entregat", "entregat" i "ENTREGAT", es consideren tots la mateixa paraula. Si voleu distingir entre majúscules i minúscules de text, emboliqueu cada argument de la funció OR a EXACTE com es mostra en aquest exemple.
Excels d'Excel IF OR de fórmules
A continuació trobareu alguns exemples més. d'utilitzar conjuntament les funcions SI i OR d'Excel que us donaran més idees sobre quin tipus de proves lògiques podeu executar.
Fórmula 1. SI amb múltiples condicions OR
No hi ha cap límit específic per a el nombre de condicions OR incrustades en una fórmula IF sempre que compleixi amb les limitacions generals d'Excel:
- A Excel 2007 i superior, es permeten fins a 255 arguments, amb una longitud total que no superi els 8.192 caràcters.
- A Excel 2003 i versions anteriors, podeu utilitzar fins a 30 arguments i la longitud total no ha de superar els 1.024 caràcters.
Com a exemple, comprovem columnes A, B i C per a cel·les en blanc i retorna "Incomplet" si almenys una de les 3 cel·les està en blanc. La tasca es pot realitzar amb la següent funció SI O:
=IF(OR(A2="",B2="",),"Incomplete","")
I el resultat serà semblant aaixò:
Fórmula 2. Si una cel·la és això O allò, calculeu
Buscant una fórmula que pugui fer alguna cosa més complexa que retornar un valor predefinit. text? Simplement anideu una altra funció o equació aritmètica als arguments value_if_true i/o value_if_false de SI.
Diguem, calculeu l'import total d'una comanda ( Qty. multiplicat per Preu unitari ) i voleu aplicar el descompte del 10% si es compleix alguna d'aquestes condicions:
- a B2 és superior o igual a 10, o
- Preu unitari a C2 és superior o igual a 5 $.
Per tant, feu servir la funció OR per comprovar ambdues condicions, i si el resultat és CERT, reduïu l'import total un 10% (B2*C2*0,9), en cas contrari retorneu el preu complet (B2*C2):
=IF(OR(B2>=10, C2>=5), B2*C2*0.9, B2*C2)
A més, podeu utilitzar el fórmula següent per indicar explícitament les comandes amb descompte:
=IF(OR(B2>=10, C2>=5),"Yes", "No")
La captura de pantalla següent mostra les dues fórmules en acció:
Fórmula 3. Cas -fórmula SI OR sensible
Com ja s'ha esmentat, la funció OR d'Excel no distingeix entre majúscules i minúscules per naturalesa. Tanmateix, és possible que les vostres dades distingeixin entre majúscules i minúscules i, per tant, voldreu executar proves OR que distingeixen entre majúscules i minúscules . En aquest cas, realitzeu cada prova lògica individual dins de la funció EXACT i anideu aquestes funcions a la instrucció OR.
IF(OR(EXACT( cel·la," condició1"), EXACTE( cel·la," condició2"), valor_si_true,value_if_false)En aquest exemple, busquem i marquem els identificadors de comanda "AA-1" i "BB-1":
=IF(OR(EXACT(A2, "AA-1"), EXACT(A2, "BB-1")), "x", "")
Com a resultat, només dos identificadors d'ordres on les lletres són totes majúscules estan marcades amb "x"; ID similars com ara "aa-1" o "Bb-1" no estan marcats:
Fórmula 4. Sentències IF OR niades a Excel
En situacions en què vulgueu provar uns quants conjunts de criteris OR i retornar valors diferents segons els resultats d'aquestes proves, escriviu una fórmula IF individual per a cada conjunt de criteris "aquest OR allò" i niu aquests IF entre ells.
Per demostrar el concepte, comprovem els noms dels elements a la columna A i tornem "Fruita" per a Poma o Taronja i "Verdura" per a Tomàquet o Cogombre :
=IF(OR(A2="apple", A2="orange"), "Fruit", IF(OR(A2="tomato", A2="cucumber"), "Vegetable", ""))
Per obtenir més informació, vegeu IF nidat amb condicions OR/AND.
Fórmula 5. Declaració IF AND OR
Per avaluar diverses combinacions de condicions diferents, podeu fer proves lògiques AND així com OR dins d'una sola fórmula.
Com a exemple, anem per marcar files on l'article de la columna A és Poma o Taronja i la quantitat de la columna B és superior a 10:
=IF(AND(OR(A2="apple",A2="orange"), B2>10), "x", "")
Per a més informació n, consulteu l'Excel SI amb múltiples condicions AND/OR.
Així és com s'utilitzen les funcions SI i OR juntes. Per veure més de prop les fórmules que es discuteixen en aquest breu tutorial, us convidemdescarregueu la nostra mostra d'Excel IF OR. Us agraeixo la lectura i esperem veure-us al nostre blog la setmana vinent!
