Vodič pokazuje kako napisati naredbu IF OR u Excelu da provjerite različite uvjete "ovo ILI ono".

IF je jedna od najpopularnijih Excel funkcija i vrlo korisna samostalno. U kombinaciji s logičkim funkcijama kao što su AND, OR i NOT, funkcija IF ima još veću vrijednost jer omogućava testiranje više uvjeta u željenim kombinacijama. U ovom vodiču ćemo se fokusirati na korištenje formule IF-i-OR u Excel-u.

IF OR izraz u Excelu

Za procjenu dva ili više uslova i vraćanje jednog rezultat ako je bilo koji od uvjeta TRUE, a drugi rezultat ako su svi uvjeti FALSE, ugradite funkciju OR u logički test IF:

Na jednostavnom engleskom, logika formule može se formulirati na sljedeći način: Ako je ćelija "ovo" ILI "ono", poduzmite jednu akciju, ako ne, onda uradite nešto drugo .

Evo primjera formule IF OR u najjednostavnijem obliku:

=IF(OR(B2="delivered", B2="paid"), "Closed", "Open")

Ono što formula kaže je sljedeće: Ako ćelija B2 sadrži "isporučeno" ili " plaćeno", označite narudžbu kao "Zatvoreno", u suprotnom "Otvoreno".

U slučaju da ne želite ne vratiti ništa ako je logično test procjenjuje na FALSE , uključite prazan niz ("") u zadnji argument:

=IF(OR(B2="delivered", B2="paid"), "Closed", "")

Ista formula se također može napisati u kompaktnijem obliku koristeći konstantu niza :

=IF(OR(B2={"delivered","paid"}), "Closed", "")

U slučaju zadnjegargument je izostavljen, formula će prikazati FALSE kada nijedan od uslova nije ispunjen.

Napomena. Obratite pažnju da formula IF OR u Excelu ne pravi razliku između malih i velikih znakova jer je funkcija OR mala i mala slova . U našem slučaju, "isporučeno", "isporučeno" i "ISPORUČENO" se smatraju istom riječju. Ako želite razlikovati velika i mala slova teksta, umotajte svaki argument funkcije OR u EXACT kao što je prikazano u ovom primjeru.

Primjeri formule IF ILI

U nastavku ćete pronaći još nekoliko primjera zajedničkog korištenja Excelovih funkcija IF i OR koje će vam dati više ideja o tome kakve logičke testove možete pokrenuti.

Formula 1. IF s više uvjeta ILI

Ne postoji određeno ograničenje za broj uslova ILI ugrađenih u formulu IF sve dok je u skladu s općim ograničenjima Excela:

• U Excelu 2007 i novijim, dozvoljeno je do 255 argumenata, ukupne dužine ne prelazi 8.192 karaktera.
• U Excel 2003 i starijim verzijama možete koristiti do 30 argumenata, a ukupna dužina ne smije biti veća od 1.024 karaktera.

Kao primjer, provjerimo kolone A, B i C za prazne ćelije i vratite "Nepotpuno" ako je barem jedna od 3 ćelije prazna. Zadatak se može izvršiti sa sljedećom funkcijom IF OR:

=IF(OR(A2="",B2="",),"Incomplete","")

I rezultat će izgledati slično kaoovo:

Formula 2. Ako je ćelija ovo ILI ono, onda izračunajte

Tražeći formulu koja može učiniti nešto složenije od vraćanja unaprijed definiranog tekst? Samo ugnijezdite drugu funkciju ili aritmetičku jednadžbu u argumente value_if_true i/ili value_if_false argumenta IF.

Recimo, izračunate ukupan iznos za narudžbu ( Količina pomnoženo sa Jedinična cijena ) i želite primijeniti popust od 10% ako je ispunjen bilo koji od ovih uslova:

• u B2 je veći ili jednak 10, ili
• Jedinična cijena u C2 je veća ili jednaka $5.

Dakle, koristite funkciju ILI da provjerite oba uslova i ako rezultat je TRUE, smanjite ukupan iznos za 10% (B2*C2*0,9), inače vratite punu cijenu (B2*C2):

=IF(OR(B2>=10, C2>=5), B2*C2*0.9, B2*C2)

Dodatno, možete koristiti formule ispod da eksplicitno naznačite snižene narudžbe:

=IF(OR(B2>=10, C2>=5),"Yes", "No")

Snimak ekrana ispod prikazuje obje formule u akciji:

Formula 3. Slučaj -sensitive IF OR formula

Kao što je već spomenuto, Excel OR funkcija je po prirodi neosjetljiva na velika i mala slova. Međutim, vaši podaci mogu biti osjetljivi na velika i mala slova i zato biste željeli pokrenuti testove ILI osjetljivih na velika i mala slova . U ovom slučaju, izvršite svaki pojedinačni logički test unutar funkcije EXACT i ugniježdite te funkcije u naredbu OR.

U ovom primjeru, pronađimo i označimo ID-ove naloga "AA-1" i "BB-1":

=IF(OR(EXACT(A2, "AA-1"), EXACT(A2, "BB-1")), "x", "")

Kao rezultat, samo dva ID-a naloga gdje sva velika slova su označena sa "x"; slični ID-ovi kao što su "aa-1" ili "Bb-1" nisu označeni:

Formula 4. Ugniježđene IF OR izjave u Excel

U situacijama kada želite da testirate nekoliko skupova kriterijuma ILI i vratite različite vrednosti u zavisnosti od rezultata tih testova, napišite pojedinačnu formulu IF za svaki skup kriterijuma „ovo ILI ono“ i ugnezdite te IF jedan u drugi.

Da demonstriramo koncept, provjerimo nazive stavki u koloni A i vratimo "Voće" za Jabuka ili Narandža i "Povrće" za Paradižnik ili Krastavac :

=IF(OR(A2="apple", A2="orange"), "Fruit", IF(OR(A2="tomato", A2="cucumber"), "Vegetable", ""))

Za više informacija, pogledajte Ugniježđeno IF sa OR/AND uslovima.

Formula 5. Naredba IF AND OR

Da biste procijenili različite kombinacije različitih uslova, možete napraviti I kao i OR logičke testove unutar jedne formule.

Kao primjer, idemo označiti redove u kojima je stavka u stupcu A ili Jabuka ili Narandža i količina u stupcu B je veća od 10:

=IF(AND(OR(A2="apple",A2="orange"), B2>10), "x", "")

Za više informacija n, pogledajte Excel IF sa više uslova I/ILI.

Tako koristite funkcije IF i OR zajedno. Da biste bolje pogledali formule o kojima se raspravlja u ovom kratkom vodiču, dobrodošli stepreuzmite naš primjer radne knjige Excel IF OR. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeće sedmice!