Tässä opetusohjelmassa on yksinkertainen selitys Excelin DATEDIF-funktiosta ja muutama kaavaesimerkki, jotka osoittavat, miten päivämääriä verrataan ja miten päivien, viikkojen, kuukausien tai vuosien ero lasketaan.

Viime viikkojen aikana olemme tutkineet lähes kaikkia päivämäärien ja kellonaikojen kanssa työskentelyyn liittyviä näkökohtia Excelissä. Jos olet seurannut blogisarjaamme, tiedät jo, miten lisätä ja muotoilla päivämääriä laskentataulukoissa, miten laskea arkipäiviä, viikkoja, kuukausia ja vuosia sekä lisätä ja vähentää päivämääriä.

Tässä opetusohjelmassa keskitymme päivämäärien välisen eron laskemiseen Excelissä ja opit eri tapoja laskea päivien, viikkojen, kuukausien ja vuosien määrä kahden päivämäärän välillä.

Löydä helposti kahden päivämäärän välinen ero Excelissä

Saat tuloksen valmiina kaavana vuosina, kuukausina, viikkoina tai päivinä.

Päivämäärien lisääminen ja vähentäminen parilla napsautuksella

Delegoi päivämäärä & aika kaavojen rakentaminen asiantuntijalle

Laske ikä Excelissä lennossa

Ja saat räätälöidyn kaavan

Excel DATEDIF -funktio - saat päivämäärän eron

Nimensä mukaisesti DATEDIF-funktio on tarkoitettu kahden päivämäärän välisen erotuksen laskemiseen.

DATEDIF on yksi harvoista Excelin dokumentoimattomista funktioista, ja koska se on "piilotettu", et löydä sitä Excelin työkalusta. Kaava välilehdellä, etkä saa mitään vihjeitä siitä, mitä argumentteja pitää syöttää, kun alat kirjoittaa funktion nimeä kaavariville. Siksi on tärkeää tuntea Excelin DATEDIF:n täydellinen syntaksi, jotta voit käyttää sitä kaavoissa.

Excel DATEDIF-funktio - syntaksi

Excelin DATEDIF-funktion syntaksi on seuraava:

Kaikki kolme argumenttia tarvitaan:

Start_date - laskettavan jakson alkupäivä.

End_date - jakson päättymispäivä.

Yksikkö - aikayksikkö, jota käytetään laskettaessa kahden päivämäärän välistä eroa. Kun annat eri yksiköitä, voit saada DATEDIF-funktion palauttamaan päivämäärän erotuksen päivinä, kuukausina tai vuosina. Käytettävissä on yhteensä kuusi yksikköä, jotka on kuvattu seuraavassa taulukossa.

Excel DATEDIF-kaava

Kahden päivämäärän välisen erotuksen saamiseksi Excelissä tärkein tehtäväsi on toimittaa alku- ja loppupäivämäärät DATEDIF-funktiolle. Tämä voidaan tehdä monella eri tavalla edellyttäen, että Excel ymmärtää ja tulkitsee toimitetut päivämäärät oikein.

Soluviittaukset

Helpoin tapa tehdä DATEDIF-kaava Excelissä on syöttää kaksi voimassa olevaa päivämäärää erillisiin soluihin ja viitata näihin soluihin. Esimerkiksi seuraava kaava laskee soluissa A1 ja B1 olevien päivämäärien väliin jäävien päivien määrän:

=DATEDIF(A1, B1, "d")

Tekstijonot

Excel ymmärtää päivämääriä monissa tekstimuodoissa, kuten "1.1.2023", "1/1/2023", "1.1.2023" jne. Päivämäärät voidaan kirjoittaa suoraan kaavan argumentteihin lainausmerkkien ympäröiminä tekstijonoina. Esimerkiksi näin voit laskea määritettyjen päivämäärien väliin jäävien kuukausien määrän:

=DATEDIF("1/1/2023", "12/31/2025", "m")

Sarjanumerot

Koska Microsoft Excel tallentaa jokaisen päivämäärän juoksevana numerona alkaen 1. tammikuuta 1900, käytät päivämääriä vastaavia numeroita. Vaikka tämä menetelmä on tuettu, se ei ole luotettava, koska päivämäärien numerointi vaihtelee eri tietokonejärjestelmissä. 1900-päivämääräjärjestelmässä voit käyttää alla olevaa kaavaa löytääksesi kahden päivämäärän, 1.1.2023 ja 31.12.2025, väliin jäävien vuosien määrän:

=DATEDIF(44927, 46022, "y")

Muiden toimintojen tulokset

Jos haluat selvittää, kuinka monta päivää on tämän päivän ja 20. toukokuuta 2025 välissä, voit käyttää seuraavaa kaavaa.

=DATEDIF(TODAY(), "5/20/2025", "d")

Huomautus: Kaavoissa loppupäivämäärän on aina oltava suurempi kuin alkupäivämäärä, muuten Excelin DATEDIF-funktio palauttaa #NUM! -virheen.

Toivottavasti edellä esitetyt tiedot ovat auttaneet ymmärtämään perusasioita. Katsotaan nyt, miten voit käyttää Excelin DATEDIF-funktiota vertaillaksesi päivämääriä laskentataulukoissa ja palauttaa erotuksen.

Kuinka saada kahden päivämäärän välisten päivien lukumäärä Excelissä?

Jos olet tarkkaillut DATEDIF:n argumentteja tarkkaan, olet huomannut, että päivämäärien välisten päivien laskemiseen on olemassa kolme eri yksikköä. Se, mitä niistä käytät, riippuu tarpeistasi.

Esimerkki 1. Excelin DATEDIF-kaava päivämäärien välisen eron laskemiseksi päivinä.

Oletetaan, että sinulla on alkupäivämäärä solussa A2 ja loppupäivämäärä solussa B2 ja haluat, että Excel palauttaa päivämäärien välisen erotuksen päivinä. Yksinkertainen DATEDIF-kaava toimii hyvin:

=DATEDIF(A2, B2, "d")

Edellyttäen, että alkupäivämäärä-argumentin arvo on pienempi kuin loppupäivämäärä-argumentin arvo. Jos alkupäivämäärä on suurempi kuin loppupäivämäärä, Excelin DATEDIF-funktio palauttaa #NUM-virheen, kuten rivillä 5:

Jos etsit kaavaa, joka palauttaa päivämäärän erotuksen päivinä joko positiivisena tai negatiivisena lukuna, vähennä yksinkertaisesti toinen päivämäärä suoraan toisesta:

=B2-A2

Katso lisätietoja ja lisää kaavaesimerkkejä kohdasta Päivämäärien vähentäminen Excelissä.

Esimerkki 2. Päivien laskeminen Excelissä vuosia huomioimatta

Oletetaan, että sinulla on kaksi luetteloa päivämääristä, jotka kuuluvat eri vuosiin, ja haluat laskea päivämäärien välisten päivien määrän ikään kuin ne olisivat saman vuoden päivämääriä. Käytä tähän DATEDIF-kaavaa, jonka yksikkö on "YD":

=DATEDIF(A2, B2, "yd")

Jos haluat, että Excelin DATEDIF-funktio ei huomioi vuosilukujen lisäksi myös kuukausia, käytä yksikköä "md". Tällöin kaava laskee kahden päivämäärän väliset päivät ikään kuin ne olisivat samassa kuussa ja samassa vuodessa:

=DATEDIF(A2, B2, "md")

Alla oleva kuvakaappaus havainnollistaa tuloksia, ja sen vertaaminen yllä olevaan kuvakaappaukseen auttaa ymmärtämään eron paremmin.

Vinkki. Jos haluat saada lukumäärän työpäivinä kahden päivämäärän välillä, käytä NETWORKDAYS- tai NETWORKDAYS.INTL-funktiota.

Kuinka laskea päivämäärän ero viikoissa

Kuten luultavasti huomasit, Excelin DATEDIF-funktiossa ei ole erityistä yksikköä päivämäärän eron laskemiseksi viikoissa. Asiaa on kuitenkin helppo kiertää.

Jos haluat selvittää, kuinka monta viikkoa kahden päivämäärän välillä on, voit käyttää DATEDIF-funktiota, jossa on yksikkö "D", palauttaa päivien erotuksen ja jakaa tuloksen 7:llä.

Saadaksesi lukumäärän täydet viikot päivämäärien välissä, kääri DATEDIF-kaavasi ROUNDDOWN-funktioon, joka pyöristää luvun aina nollaan:

=ROUNDDOWN((DATEDIF(A2, B2, "d") / 7), 0)

Jossa A2 on laskettavan ajanjakson alkamispäivä ja B2 loppupäivä.

Kuinka laskea kahden päivämäärän välisten kuukausien määrä Excelissä?

Päivien laskemisen tapaan Excelin DATEDIF-funktio voi laskea kahden määritetyn päivämäärän väliin jäävien kuukausien lukumäärän. Kaava tuottaa erilaisia tuloksia antamastasi yksiköstä riippuen.

Esimerkki 1. Kahden päivämäärän välisten kokonaisten kuukausien laskeminen (DATEDIF).

Voit laskea päivämäärien välisten kokonaisten kuukausien määrän käyttämällä DATEDIF-funktiota, jossa on yksikkö "M". Esimerkiksi seuraava kaava vertaa päivämääriä kohdissa A2 (aloituspäivämäärä) ja B2 (loppupäivä) ja palauttaa erotuksen kuukausina:

=DATEDIF(A2, B2, "m")

Huomautus: Jotta DATEDIF-kaava laskee kuukaudet oikein, loppupäivämäärän on aina oltava suurempi kuin alkupäivämäärä; muutoin kaava palauttaa #NUM-virheen.

Tällaisten virheiden välttämiseksi voit pakottaa Excelin pitämään aina vanhempaa päivämäärää alkupäivämääränä ja uudempaa päivämäärää loppupäivämääränä. Voit tehdä tämän lisäämällä yksinkertaisen loogisen testin:

=IF(B2>A2, DATEDIF(A2,B2, "m"), DATEDIF(B2,A2, "m"))

Esimerkki 2. Kahden päivämäärän väliin jäävien kuukausien lukumäärän saaminen vuosia huomioimatta (DATEDIF).

Jos haluat laskea päivämäärien väliin jäävien kuukausien määrän ikään kuin ne olisivat saman vuoden aikana, kirjoita yksikköargumenttiin "YM":

=DATEDIF(A2, B2, "ym")

Kuten näet, tämä kaava palauttaa virheen myös rivillä 6, jossa loppupäivämäärä on pienempi kuin alkupäivämäärä. Jos tietokokonaisuutesi saattaa sisältää tällaisia päivämääriä, löydät ratkaisun seuraavista esimerkeistä.

Esimerkki 3. Kahden päivämäärän välisten kuukausien laskeminen (MONTH-toiminto)

Vaihtoehtoinen tapa laskea kahden päivämäärän välisten kuukausien lukumäärä Excelissä on käyttää KUUKAUSI-funktiota tai tarkemmin sanottuna KUUKAUSI- ja VUOSI-funktioiden yhdistelmää:

=(VUOSI(B2) - VUOSI(A2))*12 + KUUKAUSI(B2) - KUUKAUSI(A2)

Tämä kaava ei tietenkään ole yhtä läpinäkyvä kuin DATEDIF, ja logiikan ymmärtäminen vie aikaa. Toisin kuin DATEDIF-funktio, se voi kuitenkin verrata mitä tahansa kahta päivämäärää ja palauttaa kuukausien välisen erotuksen joko positiivisena tai negatiivisena arvona:

Huomaa, että YEAR/MONTH-kaavalla ei ole ongelmia laskea rivin 6 kuukausia, joiden alkupäivämäärä on viimeisempi kuin loppupäivämäärä, jolloin analoginen DATEDIF-kaava epäonnistuu.

Huomautus: DATEDIF- ja YEAR/MONTH-kaavojen palauttamat tulokset eivät aina ole samanlaisia, koska ne toimivat eri periaatteilla. Excelin DATEDIF-funktio palauttaa seuraavien päivien määrän täydet kalenterikuukaudet päivämäärien välillä, kun taas YEAR/MONTH-kaava käyttää kuukausien numeroita.

Esimerkiksi yllä olevan kuvakaappauksen rivillä 7 DATEDIF-kaava palauttaa arvon 0, koska päivämäärien välillä ei ole vielä kulunut kokonaista kalenterikuukautta, kun taas YEAR/MONTH palauttaa arvon 1, koska päivämäärät kuuluvat eri kuukausiin.

Esimerkki 4. Kuukausien laskeminen 2 päivämäärän välillä vuosia huomioimatta (MONTH-funktio)

Jos kaikki päivämäärät ovat samalta vuodelta tai jos haluat laskea päivämäärien väliset kuukaudet ottamatta huomioon vuosia, voit hakea kuukauden jokaisesta päivämäärästä MONTH-funktiolla ja vähentää kuukauden toisesta:

=KUUKAUSI(B2) - KUUKAUSI(A2)

Tämä kaava toimii samalla tavalla kuin Excelin DATEDIF ja "YM"-yksikkö, kuten seuraavassa kuvakaappauksessa näytetään:

Kahden kaavan palauttamat tulokset eroavat kuitenkin toisistaan muutaman rivin verran:

• Rivi 4: Loppupäivä on pienempi kuin alkupäivä, joten DATEDIF palauttaa virheen, kun taas MONTH-MONTH antaa negatiivisen arvon.
• Rivi 6: päivämäärät ovat eri kuukausia, mutta varsinainen päivämäärän ero on vain yksi päivä. DATEDIF palauttaa arvon 0, koska se laskee kahden päivämäärän välille kokonaisia kuukausia. MONTH-MONTH palauttaa arvon 1, koska se vähentää kuukausien numerot toisistaan ottamatta huomioon päiviä ja vuosia.

Kuinka laskea kahden päivämäärän väliset vuodet Excelissä

Jos olet seurannut edellisiä esimerkkejä, joissa laskimme kuukausia ja päiviä kahden päivämäärän välillä, voit helposti johtaa kaavan vuosien laskemiseksi Excelissä. Seuraavat esimerkit voivat auttaa sinua tarkistamaan, että kaava on oikein :)

Esimerkki 1. Kahden päivämäärän välisten kokonaisten vuosien laskeminen (DATEDIF-funktio).

Jos haluat selvittää kahden päivämäärän väliin jäävien kokonaisten kalenterivuosien määrän, käytä vanhaa hyvää DATEDIF-menetelmää, jossa on yksikkö "Y":

=DATEDIF(A2,B2, "y")

Huomaa, että DATEDIF-kaava palauttaa rivillä 6 arvon 0, vaikka päivämäärät ovat eri vuosilta. Tämä johtuu siitä, että alku- ja loppupäivämäärien väliin jäävien täysien kalenterivuosien määrä on nolla. Uskon, ettet ole yllättynyt nähdessäsi #NUM! -virheen rivillä 7, jossa aloituspäivämäärä on viimeisempi kuin loppupäivämäärä.

Esimerkki 2. Kahden päivämäärän välisten vuosien laskeminen (YEAR-funktio)

Vaihtoehtoinen tapa laskea vuodet Excelissä on käyttää YEAR-toimintoa. MONTH-kaavan tavoin poimit jokaisesta päivämäärästä vuoden ja vähennät sitten vuodet toisistaan:

=VUOSI(B2) - VUOSI(A2)

Seuraavassa kuvakaappauksessa voit verrata DATEDIF- ja YEAR-funktioiden palauttamia tuloksia:

Useimmissa tapauksissa tulokset ovat identtiset, paitsi että:

• DATEDIF-funktio laskee kokonaisia kalenterivuosia, kun taas YEAR-kaava vain vähentää yhden vuoden toisesta. Rivillä 6 havainnollistetaan ero.
• DATEDIF-kaava palauttaa virheen, jos alkupäivämäärä on suurempi kuin loppupäivämäärä, kun taas YEAR-funktio palauttaa negatiivisen arvon, kuten rivillä 7.

Miten saada päivämäärän ero päivinä, kuukausina ja vuosina?

Jos haluat laskea kahden päivämäärän väliin jäävien kokonaisten vuosien, kuukausien ja päivien määrän yhdessä kaavassa, voit yksinkertaisesti yhdistää kolme DATEDIF-funktiota:

=DATEDIF(A2, B2, "y") &" vuotta, "&DATEDIF(A2, B2, "ym") &" kuukautta, " &DATEDIF(A2, B2, "md") &" päivää"

Jos et halua näyttää nolla-arvoja, voit kietoa jokaisen DATEDIF-arvon IF-funktioon seuraavasti:

=IF(DATEDIF(A2,B2, "y")=0, "", DATEDIF(A2,B2, "y") & " vuotta ") & IF(DATEDIF(A2,B2, "ym")=0,"", DATEDIF(A2,B2, "ym") & " kuukautta ") & IF(DATEDIF(A2, B2, "md")=0, "", DATEDIF(A2, B2, "md") & " päivää"

Kaava näyttää vain nollasta poikkeavat elementit, kuten seuraavasta kuvakaappauksesta käy ilmi:

Muita tapoja saada päivämäärän erotus päivinä on kohdassa Päivien laskeminen Excelissä päivämäärän jälkeen tai päivämäärään asti.

DATEDIF-kaavat iän laskemiseksi Excelissä

Itse asiassa jonkun iän laskeminen syntymäpäivän perusteella on erikoistapaus päivämäärien välisen eron laskemisesta Excelissä, jossa loppupäivämäärä on tämän päivän päivämäärä. Käytät siis tavallista DATEDIF-kaavaa, jossa on "Y"-yksikkö, joka palauttaa päivämäärien välisten vuosien määrän, ja annat end_date-argumentiksi TODAY()-funktion:

=DATEDIF(A2, TODAY(), "y")

A2 on syntymäaika.

Yllä oleva kaava laskee kokonaisten vuosien määrän. Jos haluat saada tarkan iän, joka sisältää vuodet, kuukaudet ja päivät, liitä kolme DATEDIF-funktiota toisiinsa, kuten edellisessä esimerkissä tehtiin:

=DATEDIF(B2,TODAY(), "y") & " Vuodet, " & DATEDIF(B2,TODAY(), "ym") & " Kuukaudet, " & DATEDIF(B2,TODAY(), "md") & " Päivät"

Saat seuraavan tuloksen:

Jos haluat oppia muita menetelmiä syntymäajan muuntamiseksi iäksi, katso Miten ikä lasketaan syntymäajasta.

Date & Time Wizard - helppo tapa rakentaa päivämäärän erotuskaavoja Excelissä

Kuten tämän ohjeen ensimmäisessä osassa osoitettiin, Excelin DATEDIF on varsin monipuolinen funktio, joka soveltuu moniin eri käyttötarkoituksiin. Sillä on kuitenkin yksi merkittävä haittapuoli - Microsoft ei ole dokumentoinut sitä, eli et löydä DATEDIF-funktiota funktioluettelosta etkä näe argumenttityökaluja, kun alat kirjoittaa kaavaa soluun. Jotta voit käyttää DATEDIF-funktiota seuraavissa funktioissatyöarkkisi, sinun on muistettava sen syntaksi ja syötettävä kaikki argumentit manuaalisesti, mikä saattaa olla aikaa vievä ja virhealtis tapa erityisesti aloittelijoille.

Ultimate Suite for Excel muuttaa tämän radikaalisti, sillä se tarjoaa nyt seuraavat ominaisuudet Date & Time Wizard joka voi tehdä melkein mistä tahansa päivämääräeron kaavasta hetkessä. Näin se onnistuu:

1. Valitse solu, johon haluat lisätä kaavan.
2. Mene osoitteeseen Ablebits-työkalut tab> Päivämäärä & Aika ryhmää ja napsauta Date & Time Wizard nappi:

• Napsauta Päivämäärä 1 laatikko (tai napsauta Sulje dialogi painiketta laatikon oikealla puolella) ja valitse solu, joka sisältää ensimmäisen päivämäärän.
• Klikkaa Päivämäärä 2 ruutuun ja valitse solu, jossa on toinen päivämäärä.
• Valitse haluamasi yksikkö tai yksikköyhdistelmä valikosta Ero Ohjattu toiminto antaa sinulle mahdollisuuden esikatsella laatikossa olevaa tulosta ja solussa olevaa kaavaa.
• Jos olet tyytyväinen esikatseluun, napsauta painiketta Lisää kaava painiketta, muuten kokeile eri yksiköitä.

Esimerkiksi näin saat esimerkiksi seuraavanlaisen päivien lukumäärä kahden päivämäärän välillä Excelissä:

Kun kaava on lisätty valittuun soluun, voit kopioida sen muihin soluihin tavalliseen tapaan kaksoisnapsauttamalla tai vetämällä täyttökahvaa. Tulos näyttää samankaltaiselta kuin tämä:

Jotta tulokset voidaan esittää sopivimmalla tavalla, käytettävissä on vielä muutama lisävaihtoehto:

• Vuodet pois lukien ja/tai sulje pois kuukausia laskelmista.
• Näytä tai älä näytä Tekstimerkinnät kuten päivät , kuukaudet , viikot ja vuotta .
• Näytä tai älä näytä nolla yksikköä .
• Palauta tulokset negatiivisina arvoina jos päivämäärä 1 (alkupäivä) on suurempi kuin päivämäärä 2 (loppupäivä).

Esimerkkinä saadaan kahden päivämäärän välinen erotus vuosina, kuukausina, viikkoina ja päivinä ilman nollayksiköitä:

Date & Time Formula Wizardin käytön edut

Nopeuden ja yksinkertaisuuden lisäksi Date & Time Wizard tarjoaa muutamia muita etuja:

• Toisin kuin tavallinen DATEDIF-kaava, ohjatun toiminnon luoma kehittynyt kaava ei välitä siitä, kumpi päivämääristä on pienempi ja kumpi suurempi. Ero lasketaan aina täydellisesti, vaikka päivämäärä 1 (alkupäivä) olisi suurempi kuin päivämäärä 2 (loppupäivä).
• Ohjattu toiminto tukee kaikkia mahdollisia yksiköitä (päivät, viikot, kuukaudet ja vuodet), ja voit valita 11 eri yksikön yhdistelmää.
• Ohjatun ohjelman luomat kaavat ovat tavallisia Excel-kaavoja, joten voit muokata, kopioida tai siirtää niitä tavalliseen tapaan. Voit myös jakaa laskentataulukot muiden ihmisten kanssa, ja kaikki kaavat pysyvät paikoillaan, vaikka toisella ei olisikaan Ultimate Suitea Excelissä.

Näin lasket kahden päivämäärän erotuksen eri aikaväleillä. Toivottavasti DATEDIF-funktio ja muut tänään oppimasi kaavat osoittautuvat hyödyllisiksi työssäsi.

Saatavilla olevat lataukset

Ultimate Suite 14 päivän täysin toimiva versio (.exe-tiedosto)