В урока е обяснена функцията MAX с много примери за формули, които показват как да намерите най-голямата стойност в Excel и да подчертаете най-голямото число в работния лист.

MAX е една от най-простите и лесни за използване функции на Excel. Въпреки това тя има няколко трика, чието познаване ще ви даде голямо предимство. Да речем, как да използвате функцията MAX с условия? Или как да извлечете абсолютната най-голяма стойност? Този урок предлага повече от едно решение за тези и други свързани задачи.

Функция MAX на Excel

Функцията MAX в Excel връща най-високата стойност в зададен от вас набор от данни.

Синтаксисът е следният:

Къде: номер може да бъде представен от числова стойност, масив, именуван диапазон, препратка към клетка или диапазон, съдържащ числа.

Номер1 е необходимо, номер2 и следващите аргументи не са задължителни.

Функцията MAX е налична във всички версии на Excel за Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 и по-ниски.

Как да създадете формула MAX в Excel

За да създадете най-простата формула MAX, можете да въведете числа директно в списъка с аргументи, както е показано по-долу:

=MAX(1, 2, 3)

На практика е доста рядко срещан случай, когато числата са "твърдо кодирани". В по-голямата си част ще се занимавате с диапазони и клетки.

Най-бързият начин за създаване на формула Max, която намира най-високата стойност в даден диапазон, е следният:

1. В клетка въведете =MAX(
2. Изберете диапазон от числа, като използвате мишката.
3. Въведете затварящата скоба.
4. Натиснете клавиша Enter, за да завършите формулата си.

Например, за да се определи най-голямата стойност в диапазона A1:A6, формулата ще бъде следната:

=MAX(A1:A6)

Ако числата ви са в съседни ред или колона (както в този пример), можете да накарате Excel да създаде автоматично формулата Max вместо вас. Ето как:

1. Изберете клетките с вашите числа.
2. На Начало в раздела Формати група, щракнете върху AutoSum и изберете Макс от падащия списък. (Или щракнете върху AutoSum > Макс на Формули в раздела Функционална група Библиотека. )

Това ще вмъкне готова за използване формула в клетка под избрания диапазон, така че се уверете, че има поне една празна клетка под списъка с числа, който сте избрали:

5 неща, които трябва да знаете за функцията MAX

За да използвате успешно формулите Max в работните си листове, запомнете тези прости факти:

1. В настоящите версии на Excel формулата MAX може да приема до 255 аргумента.
2. Ако аргументите не съдържат едно число, функцията MAX връща нула.
3. Ако аргументите съдържат една или повече стойности за грешка, се връща съобщение за грешка.
4. Празните клетки се игнорират.
5. Обработват се логически стойности и текстови представяния на числата, предоставени директно в списъка с аргументи (TRUE се оценява като 1, FALSE се оценява като 0). В препратките логическите и текстовите стойности се игнорират.

Как да използвате функцията MAX в Excel - примери за формули

По-долу ще намерите няколко типични употреби на функцията MAX на Excel. В много случаи има няколко различни решения за една и съща задача, затова ви препоръчвам да тествате всички формули, за да изберете най-подходящата за вашия тип данни.

Как да намерите максималната стойност в група

За да извлечете най-голямото число в група числа, подайте тази група на функцията MAX като референтен диапазон. Диапазонът може да съдържа толкова редове и колони, колкото желаете. Например, за да получите най-голямата стойност в диапазона C2:E7, използвайте тази проста формула:

=MAX(C2:E7)

Намиране на най-високата стойност в несъседни клетки или диапазони

За да направите MAX формула за несвързани клетки и диапазони, трябва да включите препратка към всяка отделна клетка и/или диапазон. Следващите стъпки ще ви помогнат да направите това бързо и безупречно:

1. Започнете да въвеждате формула Max в клетка.
2. След като въведете отварящата скоба, задръжте натиснат клавиша Ctrl и изберете клетките и диапазоните в листа.
3. След като изберете последния елемент, освободете клавиша Ctrl и въведете затварящата скоба.
4. Натиснете Enter.

Excel автоматично ще използва подходящ синтаксис и ще получите формула, подобна на тази:

=MAX(C5:E5, C9:E9)

Както е показано на екранната снимка по-долу, формулата връща максималната стойност на междинната сума от редове 5 и 9:

Как да получите максимална (последна) дата в Excel

Във вътрешната система на Excel датите не са нищо друго освен серийни номера, така че функцията MAX ги обработва без проблем.

Например, за да намерите последната дата на доставка в C2:C7, направете обичайната формула Max, която използвате за числа:

=MAX(C2:C7)

Функция MAX в Excel с условия

Когато желаете да получите максималната стойност въз основа на условия, има няколко формули, от които можете да избирате. За да се уверим, че всички формули връщат идентичен резултат, ще ги тестваме върху един и същ набор от данни.

Задачата : С помощта на артикулите, изброени в B2:B15, и данните за продажбите в C2:C15 се стремим да намерим най-високата продажба за конкретен артикул, въведена в F1 (моля, вижте снимката в края на този раздел).

Excel MAX IF формула

Ако търсите формула, която да работи във всички версии на Excel от 2000 до 2019 г., използвайте функцията IF, за да проверите условието, и след това предайте получения масив на функцията MAX:

=MAX(IF(B2:B15=F1, C2:C15))

За да работи формулата, трябва да натиснете едновременно Ctrl + Shift + Enter, за да я въведете като формула за масив. Ако всичко е направено правилно, Excel ще загради формулата ви в {къдрави скоби}, което е визуална индикация за формула за масив.

Възможно е също така да се оценят няколко условия в една формула и в следващия урок е показано как: MAX IF с няколко условия.

Формула MAX IF, която не е масив

Ако не обичате да използвате формули за масиви в работните си листове, комбинирайте MAX с функцията SUMPRODUCT, която обработва масиви по естествен начин:

=SUMPRODUCT(MAX((B2:B15=F1)*(C2:C15))

За повече информация вижте MAX IF без масив.

Функция MAXIFS

В Excel 2019 и Excel за Office 365 има специална функция, наречена MAXIFS, която е предназначена за намиране на най-високата стойност с до 126 критерия.

В нашия случай има само едно условие, така че формулата е проста:

=MAXIFS(C2:C15, B2:B15, F1)

За подробно обяснение на синтаксиса вижте Excel MAXIFS с примери за формули.

На снимката по-долу са показани всички 3 формули в действие:

Получаване на максимална стойност с игнориране на нулите

Всъщност това е вариант на условния MAX, разгледан в предишния пример. За да изключите нулите, използвайте логическия оператор "не е равно на" и поставете израза "0" в критериите на MAXIFS или в логическия тест на MAX IF.

Както разбирате, тестването на това условие има смисъл само в случай на отрицателни числа . При положителните числа тази проверка е излишна, защото всяко положително число е по-голямо от нула.

За да опитаме, нека намерим най-малката отстъпка в диапазона C2:C7. Тъй като всички отстъпки са представени с отрицателни числа, най-малката отстъпка всъщност е най-голямата стойност.

MAX IF

Не забравяйте да натиснете Ctrl + Shift + Enter, за да изпълните правилно тази формула за масиви:

=MAX(IF(C2:C70, C2:C7))

MAXIFS

Това е обикновена формула и е достатъчно да натиснете обичайния клавиш Enter.

=MAXIFS(C2:C7,C2:C7,"0")

Намиране на най-високата стойност, като се игнорират грешките

Когато работите с голямо количество данни, управлявани от различни формули, има вероятност някои от формулите ви да доведат до грешки, което ще накара формулата MAX също да върне грешка.

Като заобиколен вариант можете да използвате MAX IF заедно с ISERROR. Като се има предвид, че търсите в диапазона A1:B5, формулата придобива следния вид:

=MAX(IF(ISERROR(A1:B5)), "", A1:B5))

За да опростите формулата, използвайте функцията IFERROR вместо комбинацията IF ISERROR. Това също така ще направи логиката малко по-очевидна - ако има грешка в A1:B5, заместете я с празен низ ('') и след това получете максималната стойност в диапазона:

=MAX(IFERROR(A1:B5, ""))

Проблемът е, че не трябва да забравяте да натискате Ctrl + Shift + Enter, тъй като това работи само като формула за масив.

В Excel 2019 и Excel for Office 356 функцията MAXIFS може да бъде решение, при условие че наборът ви от данни съдържа поне едно положително число или нулева стойност:

=MAXIFS(A1:B5,A1:B5,">=0")

Тъй като формулата търси най-голямата стойност с условие "по-голямо или равно на 0", тя няма да работи за набор от данни, състоящ се само от отрицателни числа.

Всички тези ограничения не са добри и очевидно се нуждаем от по-добро решение. Функцията AGGREGATE, която може да извършва редица операции и да пренебрегва стойностите на грешките, се вписва идеално:

=AGGREGATE(4, 6, A1:B5)

Числото 4 в първия аргумент указва функцията MAX, числото 6 във втория аргумент е опцията "игнориране на грешки", а A1:B5 е целевият диапазон.

При перфектни обстоятелства и трите формули ще дадат един и същ резултат:

Как да намерите абсолютната максимална стойност в Excel

Когато работите с диапазон от положителни и отрицателни числа, понякога може да искате да намерите най-голямата абсолютна стойност, независимо от знака.

Първата идея, която ми хрумва, е да получим абсолютните стойности на всички числа в диапазона, като използваме функцията ABS, и да ги подадем на MAX:

Това е формула за масиви, затова не забравяйте да я потвърдите с бързата клавишна комбинация Ctrl + Shift + Enter. Друго предупреждение е, че тя работи само с числа и води до грешка в случай на нецифрови данни.

Не сте доволни от тази формула? Тогава нека създадем нещо по-жизнеспособно :)

Какво ще стане, ако намерим минималната стойност, обърнем или игнорираме знака ѝ и след това я оценим заедно с всички останали числа? Да, това ще работи перфектно като нормална формула. Като допълнителен бонус, тя се справя отлично с текстови записи и грешки:

При номера на източника в A1:B5 формулите са следните.

Масив (завършва се с Ctrl + Shift + Enter):

=MAX(ABS(A1:B5))

Редовно формула (завършва се с Enter):

=MAX(MAX(A1:B5), -MIN(A1:B5))

или

=MAX(MAX(A1:B5), ABS(MIN(A1:B5))

Резултатите са показани на снимката по-долу:

Връщане на максималната абсолютна стойност, запазваща знака

В някои ситуации може да се наложи да намерите най-голямата абсолютна стойност, но да върнете числото с първоначалния му знак, а не с абсолютната стойност.

Ако приемем, че числата се намират в клетките A1:B5, ето формулата, която трябва да използвате:

=IF(ABS(MAX(A1:B5))>ABS(MIN(A1:B5)), MAX(A1:B5), MIN(A1:B5))

Сложна на пръв поглед, логиката е доста лесна за следване. Първо се намират най-голямото и най-малкото число в диапазона и се сравняват абсолютните им стойности. Ако абсолютната максимална стойност е по-голяма от абсолютната минимална стойност, се връща максималното число, а в противен случай - минималното. Тъй като формулата връща първоначалната, а не абсолютната стойност, тя запазва информацията за знака:

Как да подчертаете максималната стойност в Excel

В случаите, когато искате да определите най-голямото число в първоначалния набор от данни, най-бързият начин е да го подчертаете с условно форматиране на Excel. Примерите по-долу ще ви преведат през два различни сценария.

Подчертаване на най-голямото число в даден диапазон

Microsoft Excel разполага с предварително дефинирано правило за форматиране на най-високо класираните стойности, което напълно отговаря на нашите нужди. Ето стъпките за прилагането му:

1. Изберете диапазона от числа (C2:C7 в нашия случай).
2. На Начало в раздела Стилове група, щракнете върху Условно форматиране> Ново правило .
3. В Ново правило за форматиране диалогов прозорец, изберете Форматиране само на най-високо или най-ниско класираните стойности .
4. В долния прозорец изберете Топ от падащия списък и въведете 1 в полето до него (което означава, че искате да маркирате само една клетка, съдържаща най-голямата стойност).
5. Щракнете върху Формат и изберете желания формат.
6. Щракнете два пъти върху OK, за да затворите двата прозореца.

Готово! Най-високата стойност в избрания диапазон се подчертава автоматично. Ако има повече от една максимална стойност (дубликати), Excel ще ги подчертае всичките:

Подчертаване на максималната стойност във всеки ред

Тъй като няма вградено правило, което да прави така, че най-високата стойност да се откроява от всеки ред, ще трябва да конфигурирате свое собствено правило въз основа на формула MAX. Ето как:

1. Изберете всички редове, в които искате да подчертаете максималните стойности (C2:C7 в този пример).
2. На Начало в раздела Стилове група, щракнете върху Ново правило > Използвайте формула, за да определите кои клетки да форматирате .
3. В Форматиране на стойности, при които тази формула е вярна въведете тази формула:

   =C2=MAX($C2:$E2)

   Където C2 е най-лявата клетка, а $C2:$E2 е обхватът на първия ред. За да работи правилото, не забравяйте да заключите координатите на колоните в обхвата със знака $.

4. Щракнете върху Формат и изберете желания формат.
5. Щракнете два пъти върху OK.

Съвет. По подобен начин можете да маркирате най-висока стойност в всяка колона . Стъпките са абсолютно същите, с изключение на това, че записвате формула за първия диапазон на колоната и заключвате координатите на реда: =C2=MAX(C$2:C$7)

За повече информация вижте Как да създадем правило за условно форматиране, базирано на формула.

Функцията MAX на Excel не работи

MAX е една от най-простите за използване функции на Excel. Ако противно на всички очаквания тя не работи правилно, най-вероятно става въпрос за един от следните проблеми.

Формулата MAX връща нула

Ако нормална формула MAX връща 0, въпреки че в зададения диапазон има по-големи числа, има вероятност тези числа да са форматирани като текст. Това е особено характерно, когато изпълнявате функцията MAX върху данни, получени от други формули. Можете да проверите това, като използвате например функцията ISNUMBER:

=ISNUMBER(A1)

Ако горната формула върне FALSE, стойността в A1 не е числова. Това означава, че трябва да отстраните проблема с оригиналните данни, а не с формулата MAX.

Формулата MAX връща #N/A, #VALUE или друга грешка

Моля, проверете внимателно препратените клетки. Ако някоя от препратените клетки съдържа грешка, формулата MAX ще доведе до същата грешка. За да заобиколите това, вижте как да получите максималната стойност, като игнорирате всички грешки.

Това е начинът за намиране на максималната стойност в Excel. Благодаря ви, че прочетохте, и се надявам скоро да се видим в нашия блог!

Налични изтегляния:

Примерна работна книга на Excel MAX