De handleiding legt de MAX-functie uit met vele formulevoorbeelden die laten zien hoe u de hoogste waarde in Excel kunt vinden en het grootste getal in uw werkblad kunt markeren.

MAX is een van de meest eenvoudige en gebruiksvriendelijke Excel-functies. Er zijn echter wel een paar trucjes die u met kennis van zaken een groot voordeel opleveren. Bijvoorbeeld, hoe gebruikt u de MAX-functie met voorwaarden? Of hoe haalt u de absoluut grootste waarde eruit? Deze zelfstudie biedt meer dan één oplossing voor deze en andere verwante taken.

Excel MAX-functie

De functie MAX in Excel geeft de hoogste waarde in een reeks gegevens die u opgeeft.

De syntaxis is als volgt:

Waar nummer kan worden voorgesteld door een numerieke waarde, een matrix, een genoemd bereik, een verwijzing naar een cel of bereik met getallen.

Nummer 1 is vereist, nummer2 en volgende argumenten zijn optioneel.

De MAX-functie is beschikbaar in alle versies van Excel voor Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 en lager.

Hoe maak je een MAX-formule in Excel?

Om een MAX-formule in zijn eenvoudigste vorm te maken, kunt u getallen rechtstreeks in de lijst van argumenten typen, zoals dit:

=MAX(1, 2, 3)

In de praktijk komt het zelden voor dat getallen "hardcoded" zijn. Meestal gaat het om bereiken en cellen.

De snelste manier om een Max-formule te bouwen die de hoogste waarde in een bereik vindt, is deze:

1. Typ in een cel =MAX(
2. Selecteer een reeks getallen met de muis.
3. Typ de afsluitende haakjes.
4. Druk op de Enter-toets om uw formule te voltooien.

Om bijvoorbeeld de grootste waarde in het bereik A1:A6 te berekenen, zou de formule als volgt gaan:

=MAX(A1:A6)

Als uw nummers in een aaneengesloten rij of kolom (zoals in dit voorbeeld), kunt u Excel automatisch een Max-formule voor u laten maken. Zo gaat u te werk:

1. Selecteer de cellen met uw getallen.
2. Op de Home tabblad, in de Formaten groep, klik AutoSum en kies Max uit de drop-down lijst. (Of klik op AutoSum > Max op de Formules tabblad in de Functie Bibliotheek groep. )

Hiermee wordt een kant-en-klare formule ingevoegd in een cel onder het geselecteerde bereik, dus zorg ervoor dat er ten minste één lege cel is onder de lijst met getallen die u hebt geselecteerd:

5 dingen die u moet weten over de MAX-functie

Om Max formules met succes te gebruiken in uw werkbladen, onthoudt u deze eenvoudige feiten:

1. In de huidige versies van Excel kan een MAX-formule maximaal 255 argumenten accepteren.
2. Indien de argumenten geen enkel getal bevatten, geeft de MAX-functie nul terug.
3. Indien de argumenten een of meer foutwaarden bevatten, wordt een fout geretourneerd.
4. Lege cellen worden genegeerd.
5. Logische waarden en tekstrepresentaties van getallen die rechtstreeks in de lijst met argumenten worden gegeven, worden verwerkt (TRUE evalueert als 1, FALSE evalueert als 0). In verwijzingen worden logische en tekstwaarden genegeerd.

Hoe de MAX-functie gebruiken in Excel - formulevoorbeelden

Hieronder vindt u een paar typische toepassingen van de Excel MAX-functie. In veel gevallen zijn er een paar verschillende oplossingen voor dezelfde taak, dus ik moedig u aan om alle formules te testen om degene te kiezen die het meest geschikt is voor uw gegevenstype.

Hoe de maximumwaarde in een groep te vinden

Om het grootste getal in een groep getallen te extraheren, geeft u die groep aan de functie MAX als een bereikreferentie. Een bereik kan zoveel rijen en kolommen bevatten als u wilt. Om bijvoorbeeld de hoogste waarde in het bereik C2:E7 te krijgen, gebruikt u deze eenvoudige formule:

=MAX(C2:E7)

Zoek de hoogste waarde in niet-aangrenzende cellen of bereiken

Om een MAX-formule te maken voor niet-aaneengesloten cellen en bereiken, moet u een verwijzing naar elke afzonderlijke cel en/of bereik opnemen. De volgende stappen helpen u dat snel en foutloos te doen:

1. Begin met het typen van een Max-formule in een cel.
2. Nadat u de openingshaakjes hebt getypt, houdt u de Ctrl-toets ingedrukt en selecteert u de cellen en bereiken in het blad.
3. Nadat u het laatste item hebt geselecteerd, laat u Ctrl los en typt u het laatste haakje.
4. Druk op Enter.

Excel zal automatisch een passende syntaxis gebruiken, en u krijgt een formule die hierop lijkt:

=MAX(C5:E5, C9:E9)

Zoals in de onderstaande schermafbeelding te zien is, geeft de formule het maximum subtotaal van rijen 5 en 9:

Hoe krijg ik de maximale (laatste) datum in Excel?

In het interne Excel-systeem zijn datums niets anders dan volgnummers, zodat de MAX-functie ze probleemloos verwerkt.

Om bijvoorbeeld de laatste leveringsdatum in C2:C7 te vinden, maakt u een gebruikelijke Max-formule die u voor getallen zou gebruiken:

=MAX(C2:C7)

MAX-functie in Excel met voorwaarden

Wanneer u de maximale waarde wilt verkrijgen op basis van voorwaarden, zijn er verschillende formules waaruit u kunt kiezen. Om er zeker van te zijn dat alle formules hetzelfde resultaat opleveren, zullen we ze testen op dezelfde set gegevens.

De taak Met de artikelen in B2:B15 en de verkoopcijfers in C2:C15 proberen wij de hoogste verkoop voor een specifiek artikel in F1 te vinden (zie de schermafbeelding aan het eind van dit deel).

Excel MAX IF-formule

Als u een formule zoekt die werkt in alle versies van Excel 2000 tot en met Excel 2019, gebruik dan de IF-functie om de voorwaarde te testen en geef de resulterende matrix door aan de MAX-functie:

=MAX(IF(B2:B15=F1, C2:C15))

Om de formule te laten werken, moet u tegelijkertijd op Ctrl + Shift + Enter drukken om deze in te voeren als een matrixformule. Als alles goed is gedaan, omsluit Excel uw formule in {curly braces}, wat een visuele indicatie is van een matrixformule.

Het is ook mogelijk om meerdere voorwaarden in een enkele formule te evalueren, en de volgende tutorial laat zien hoe: MAX IF met meerdere voorwaarden.

Niet-array MAX IF-formule

Als u niet graag matrixformules gebruikt in uw werkbladen, combineer MAX dan met de SUMPRODUCT-functie, die op natuurlijke wijze matrices verwerkt:

=SUMPRODUCT(MAX((B2:B15=F1)*(C2:C15)))

Voor meer informatie, zie MAX IF zonder array.

MAXIFS-functie

In Excel 2019 en Excel voor Office 365 is er een speciale functie met de naam MAXIFS, die is ontworpen om de hoogste waarde te vinden met maximaal 126 criteria.

In ons geval is er maar één voorwaarde, dus de formule is zo simpel als:

=MAXIFS(C2:C15, B2:B15, F1)

Voor een gedetailleerde uitleg van de syntaxis, zie Excel MAXIFS met formulevoorbeelden.

De onderstaande schermafbeelding toont alle 3 de formules in actie:

Maximale waarde krijgen waarbij nullen worden genegeerd

Dit is in feite een variant van de voorwaardelijke MAX die in het vorige voorbeeld werd besproken. Om nullen uit te sluiten, gebruikt u de logische operator "niet gelijk aan" en plaatst u de uitdrukking "0" in de criteria van MAXIFS of in de logische test van MAX IF.

Zoals u begrijpt, heeft het testen van deze voorwaarde alleen zin in geval van negatieve getallen Bij positieve getallen is deze controle overbodig omdat elk positief getal groter is dan nul.

Laten we, om het te proberen, de laagste korting vinden in het bereik C2:C7. Aangezien alle kortingen worden weergegeven door negatieve getallen, is de kleinste korting eigenlijk de grootste waarde.

MAX ALS

Druk op Ctrl + Shift + Enter om deze matrixformule correct in te vullen:

=MAX(IF(C2:C70, C2:C7))

MAXIFS

Het is een gewone formule, en een gewone Enter-toets is voldoende.

=MAXIFS(C2:C7,C2:C7,"0")

Zoek de hoogste waarde en negeer fouten

Wanneer u werkt met een grote hoeveelheid gegevens die door verschillende formules worden aangestuurd, is de kans groot dat sommige van uw formules fouten opleveren, waardoor een MAX-formule ook een fout oplevert.

Als workaround kunt u MAX IF gebruiken in combinatie met ISERROR. Aangezien u zoekt in het bereik A1:B5, krijgt de formule deze vorm:

=MAX(IF(ISERROR(A1:B5)), "", A1:B5))

Om de formule te vereenvoudigen, gebruikt u de functie IFERROR in plaats van de combinatie IF ISERROR. Dit maakt de logica ook wat duidelijker - als er een fout is in A1:B5, vervangt u deze door een lege tekenreeks (''), en krijgt u vervolgens de maximumwaarde in het bereik:

=MAX(IFERROR(A1:B5, ""))

Een vlieg in de zalf is dat je moet onthouden om op Ctrl + Shift + Enter te drukken, omdat dit alleen werkt als een matrixformule.

In Excel 2019 en Excel voor Office 356 kan de functie MAXIFS uitkomst bieden, mits uw gegevensverzameling ten minste één positief getal of nulwaarde bevat:

=MAXIFS(A1:B5,A1:B5,">=0")

Aangezien de formule zoekt naar de hoogste waarde met de voorwaarde "groter dan of gelijk aan 0", zal zij niet werken voor een gegevensverzameling die uitsluitend uit negatieve getallen bestaat.

Al deze beperkingen zijn niet goed, en we hebben duidelijk een betere oplossing nodig. De functie AGGREGATE, die een aantal bewerkingen kan uitvoeren en foutwaarden kan negeren, past perfect:

=AGGREGATE(4, 6, A1:B5)

Het getal 4 in het eerste argument geeft de MAX-functie aan, het getal 6 in het tweede argument is de optie "fouten negeren", en A1:B5 is uw doelbereik.

Onder perfecte omstandigheden zullen alle drie de formules hetzelfde resultaat opleveren:

Hoe de absolute maximumwaarde te vinden in Excel

Wanneer je werkt met een reeks positieve en negatieve getallen, wil je soms de grootste absolute waarde vinden, ongeacht het teken.

Het eerste idee dat in mij opkomt is om de absolute waarden van alle getallen in het bereik te verkrijgen door de ABS-functie te gebruiken en die in te voeren in MAX:

Dit is een matrixformule, dus vergeet niet te bevestigen met de sneltoets Ctrl + Shift + Enter. Een ander voorbehoud is dat het alleen werkt met getallen en een fout oplevert bij niet-numerieke gegevens.

Niet blij met deze formule? Laat ons dan iets bouwen dat meer levensvatbaar is :)

Wat als we de minimumwaarde vinden, het teken ervan omkeren of negeren, en dan samen met alle andere getallen evalueren? Ja, dat werkt perfect als een normale formule. Als extra bonus kan het prima omgaan met tekstinvoer en fouten:

Met de bronnummers in A1:B5 gaan de formules als volgt.

Array formule (aangevuld met Ctrl + Shift + Enter):

=MAX(ABS(A1:B5))

Regelmatig formule (aangevuld met Enter):

=MAX(MAX(A1:B5), -MIN(A1:B5))

of

=MAX(MAX(A1:B5), ABS(MIN(A1:B5))

Het onderstaande screenshot toont de resultaten:

Geeft de maximale absolute waarde met behoud van het teken

In sommige situaties kan het nodig zijn de grootste absolute waarde te vinden, maar het getal met het oorspronkelijke teken terug te geven, niet de absolute waarde.

Aangenomen dat de getallen in de cellen A1:B5 staan, is dit de te gebruiken formule:

=IF(ABS(MAX(A1:B5))>ABS(MIN(A1:B5)), MAX(A1:B5), MIN(A1:B5))

De logica is op het eerste gezicht complex, maar vrij eenvoudig te volgen. Eerst zoekt u de grootste en de kleinste getallen in het bereik en vergelijkt u hun absolute waarden. Als de absolute maximumwaarde groter is dan de absolute minimumwaarde, wordt het maximumgetal teruggegeven, anders - het minimumgetal. Omdat de formule de oorspronkelijke en niet de absolute waarde teruggeeft, blijft de tekeninformatie behouden:

Hoe max. waarde markeren in Excel

In situaties waarin u het grootste getal in de oorspronkelijke gegevensverzameling wilt identificeren, is de snelste manier om het te markeren met Excel voorwaardelijke opmaak. De onderstaande voorbeelden laten u twee verschillende scenario's zien.

Hoogste getal in een reeks markeren

Microsoft Excel heeft een voorgedefinieerde regel om topwaarden op te maken, die perfect past bij onze behoeften. Hier zijn de stappen om hem toe te passen:

1. Selecteer uw getallenbereik (C2:C7 in ons geval).
2. Op de Home tabblad, in de Styles groep, klik Voorwaardelijke opmaak> Nieuwe regel .
3. In de Nieuwe opmaakregel dialoogvenster, kies Alleen de hoogste of laagste waarden opmaken .
4. Kies in het onderste deelvenster Top uit de vervolgkeuzelijst en typ 1 in het vak ernaast (wat betekent dat u slechts één cel met de grootste waarde wilt markeren).
5. Klik op de Formaat toets en selecteer het gewenste formaat.
6. Klik tweemaal op OK om beide vensters te sluiten.

De hoogste waarde in het geselecteerde bereik wordt automatisch gemarkeerd. Indien er meer dan één maximumwaarde is (duplicaten), zal Excel ze allemaal markeren:

Markeer de maximumwaarde in elke rij

Aangezien er geen ingebouwde regel is om de hoogste waarde van elke rij eruit te laten springen, moet u uw eigen regel configureren op basis van een MAX-formule. Hier ziet u hoe:

1. Selecteer alle rijen waarin u de maximumwaarden wilt markeren (C2:C7 in dit voorbeeld).
2. Op de Home tabblad, in de Styles groep, klik Nieuwe regel > Gebruik een formule om te bepalen welke cellen moeten worden opgemaakt .
3. In de Formatteer waarden waar deze formule waar is vak, deze formule in:

   =C2=MAX($C2:$E2)

   Waarbij C2 de meest linkse cel is en $C2:$E2 het eerste rijbereik. Om de regel te laten werken, moet u de kolomcoördinaten in het bereik vergrendelen met het $-teken.

4. Klik op de Formaat en kies het gewenste formaat.
5. Klik tweemaal op OK.

Tip. Op soortgelijke wijze kunt u de hoogste waarde in elke kolom De stappen zijn precies hetzelfde, behalve dat u een formule schrijft voor het eerste kolombereik en de rijcoördinaten vergrendelt: =C2=MAX(C$2:C$7)

Voor meer informatie, zie Hoe maak je een op een formule gebaseerde regel voor voorwaardelijke opmaak.

Excel MAX functie werkt niet

MAX is een van de meest eenvoudige Excel-functies om te gebruiken. Als het tegen alle verwachtingen in niet goed werkt, is het waarschijnlijk een van de volgende problemen.

MAX-formule geeft nul terug

Als een normale MAX-formule 0 oplevert, ook al zijn er hogere getallen in het opgegeven bereik, is de kans groot dat die getallen als tekst zijn opgemaakt. Dit is vooral het geval wanneer u de MAX-functie uitvoert op gegevens die door andere formules worden aangestuurd. U kunt dit bijvoorbeeld controleren met de functie ISNUMBER:

=ISNUMBER(A1)

Indien de bovenstaande formule FALSE oplevert, is de waarde in A1 niet numeriek. Dit betekent dat u de oorspronkelijke gegevens moet onderzoeken, niet een MAX-formule.

MAX-formule geeft #N/A, #VALUE of een andere fout.

Controleer de cellen waarnaar wordt verwezen zorgvuldig. Als een van de cellen waarnaar wordt verwezen een fout bevat, zal een MAX-formule dezelfde fout opleveren. Om dit te omzeilen, zie hoe u de maximumwaarde krijgt waarbij alle fouten worden genegeerd.

Dat is hoe je de maximumwaarde vindt in Excel. Ik dank u voor het lezen en hoop u snel op onze blog te zien!

Beschikbare downloads:

Excel MAX-voorbeeldwerkmap