Šodienas emuāra ieraksts ir par divu datumu starpības noteikšanu Google tabulās. Jūs redzēsiet daudz formulu DATEDIF, lai skaitītu dienas, mēnešus un gadus, un uzzināsiet, kā NETWORKDAYS tiek izmantots, lai skaitītu tikai darba dienas, pat ja jūsu brīvdienas ir balstītas uz pielāgotu grafiku.

Daudzi izklājlapu lietotāji uzskata, ka datumus apstrādāt ir mulsinoši vai pat ļoti sarežģīti. Taču, ticiet vai nē, šim nolūkam ir dažas ērtas un vienkāršas funkcijas. DATEDIF un NETWORKDAYS ir dažas no tām.

DATEDIF funkcija programmā Google Sheets

Kā tas notiek ar funkcijām, to nosaukumi norāda uz darbību. Tas pats attiecas uz DATEDIF. Tas jālasa kā datuma starpība , nevis datēts, ja , un tas apzīmē datumu starpība . Tādējādi DATEDIF Google tabulās aprēķina datumu starpību starp diviem datumiem.

Sadalīsim to pa daļām. Funkcijai ir nepieciešami trīs argumenti:

• start_date - datums, ko izmanto kā sākuma punktu. Tam jābūt vienam no šiem:
  • datums divās pēdiņās: "8/13/2020"
  • atsauce uz šūnu ar datumu: A2
  • formula, kas atgriež datumu: DATUMS(2020, 8, 13)
  • skaitlis, kas apzīmē konkrētu datumu un ko Google Sheets var interpretēt kā datumu, piemēram. 44056 ir augusts 13, 2020 .
• end_date - datums, ko izmanto kā galapunktu. Tam jābūt tādā pašā formātā kā datumam start_date .
• vienība - tiek izmantots, lai norādītu funkcijai, kāda starpība ir jāatgriež. Šeit ir pilns saraksts ar vienībām, kuras var izmantot:
  • "D" - (saīsinājums no dienas ) atgriež dienu skaitu starp diviem datumiem.
  • "M" - (mēneši) pilno mēnešu skaits starp diviem datumiem.
  • "Y" - (gadi) pilno gadu skaits.
  • "MD" - (dienas, neņemot vērā mēnešus) dienu skaits pēc veselu mēnešu atņemšanas.
  • "YD" - (dienas, neņemot vērā gadus) dienu skaits pēc veselu gadu atņemšanas.
  • "YM" - (mēneši, neņemot vērā gadus) pilno mēnešu skaits pēc pilno gadu atņemšanas.

Piezīme. Visas mērvienības formulās jāievada tādā pašā veidā, kā tās parādās iepriekš - ar dubultiekavītēm.

Tagad apvienosim visas šīs daļas un aplūkosim, kā DATEDIF formulas darbojas Google tabulās.

Dienu starp diviem datumiem aprēķināšana Google tabulās

Piemērs 1. Saskaitiet visas dienas

Man ir neliela tabula, lai izsekotu dažiem pasūtījumiem. Visi tie ir nosūtīti augusta pirmajā pusē - Nosūtīšanas datums - kas būs mans sākuma datums. Ir arī aptuvenais piegādes datums - Termiņš .

Es gatavojos aprēķināt dienas - "D" - starp nosūtīšanas un saņemšanas datumiem, lai redzētu, cik ilgā laikā preces tiek nogādātas. Šeit ir formula, kas man jāizmanto:

=DATEDIF(B2, C2, "D")

Es ievada DATEDIF formulu D2 un pēc tam kopēju to uz leju pa kolonnu, lai piemērotu citām rindām.

Padoms. Vienmēr varat aprēķināt visu kolonnu uzreiz ar vienu formulu, izmantojot ARRAYFORMULA:

=ArrayFormula(DATEDIF(B2:B13, C2:C13, "D"))

Piemērs 2. Skaitīt dienas, ignorējot mēnešus

Iedomājieties, ka starp diviem datumiem ir daži mēneši:

Kā skaitīt tikai dienas, it kā tās piederētu vienam un tam pašam mēnesim? Tieši tā: neņemot vērā aizritējušos pilnus mēnešus. DATEDIF to aprēķina automātiski, kad izmantojat vienumu "MD" vienība:

=DATEDIF(A2, B2, "MD")

Šī funkcija atņem pagājušos mēnešus un saskaita atlikušās dienas.

Piemērs 3. Dienu skaitīšana, ignorējot gadus

Cita vienība - "YD" - palīdzēs, ja starp datumiem ir vairāk nekā gads:

=DATEDIF(A2, B2, "YD")

Formula vispirms atņems gadus un pēc tam aprēķinās atlikušās dienas tā, it kā tās piederētu vienam gadam.

Darba dienu skaitīšana Google tabulās

Pastāv īpašs gadījums, kad Google tabulās ir jāskaita tikai darba dienas. DATEDIF formulas šeit īpaši nepalīdzēs. Un es ticu, ka jūs piekritīsiet, ka nedēļas nogales atņemšana manuāli nav pats elegantākais risinājums.

Par laimi, Google Sheets ir pāris ne tik maģiskas burvestības, lai to paveiktu :)

Piemērs 1. NETWORKDAYS funkcija

Pirmā no tām ir NETWORKDAYS. Šī funkcija aprēķina darba dienu skaitu starp diviem datumiem, izņemot nedēļas nogales (sestdienu un svētdienu) un pat brīvdienas, ja nepieciešams:

• start_date - datums, ko izmanto kā sākuma punktu. Vajadzīgs.

  Piezīme. Ja šis datums nav brīvdiena, tas tiek uzskatīts par darba dienu.

• end_date - datums, ko izmanto kā beigu punktu. Obligāti.

  Piezīme. Ja šis datums nav brīvdiena, tas tiek uzskatīts par darba dienu.

• brīvdienas - šī opcija nav obligāta, ja nepieciešams norādīt uz konkrētām brīvdienām. Tai jābūt datumu diapazonam vai skaitļiem, kas apzīmē datumus.

Lai ilustrētu, kā tas darbojas, pievienoju sarakstu ar brīvdienām, kas notiek starp nosūtīšanas un saņemšanas datumiem:

Tātad B slejā ir sākuma datums, C slejā - beigu datums. Datumi E slejā ir brīvdienas, kas jāņem vērā. Lūk, kā vajadzētu izskatīties formulai:

=NETWORKDAYS(B2, C2, $E$2:$E$4)

Padoms. Ja gatavojaties kopēt formulu uz citām šūnām, brīvdienās izmantojiet absolūtās šūnu atsauces, lai izvairītos no kļūdām vai nepareiziem rezultātiem. Vai arī apsveriet iespēju tā vietā izveidot masīva formulu.

Vai esat pamanījuši, kā samazinājās dienu skaits, salīdzinot ar DATEDIF formulām? Tagad funkcija automātiski atņem visas sestdienas, svētdienas un divas brīvdienas, kas ir piektdien un pirmdien.

Piezīme. Atšķirībā no DATEDIF Google tabulās, NETWORKDAYS skaita start_day un end_day kā darba dienas, ja vien tās nav brīvdienas. Tādējādi D7 atgriež 1 .

Piemērs 2. NETWORKDAYS.INTL priekš Google Sheets

Ja jums ir pielāgots nedēļas nogales grafiks, jums noderēs vēl viena funkcija: NETWORKDAYS.INTL. Tā ļauj jums Google tabulās skaitīt darba dienas, pamatojoties uz personīgi iestatītajām nedēļas nogalēm:

• start_date - datums, ko izmanto kā sākuma punktu. Vajadzīgs.
• end_date - datums, ko izmanto kā beigu punktu. Obligāti.

  Piezīme. NETWORKDAYS.INTL Google tabulās arī tiek ieskaitīts. start_day un end_day kā darba dienas, ja vien tās nav brīvdienas.

  Skatīt arī: Kā aprēķināt vecumu programmā Excel no dzimšanas dienas
• nedēļas nogale - Ja šī opcija nav obligāta, sestdiena un svētdiena tiek uzskatītas par brīvdienām. Bet to var mainīt, izmantojot divus veidus:
  • Maskas .

    Padoms. Šis veids ir lieliski piemērots, ja brīvdienas ir izkaisītas pa visu nedēļu.

    Maska ir septiņu ciparu modelis, kurā ir 1 un 0. 1 apzīmē nedēļas nogali, 0 - darba dienu. Pirmais cipars šajā modelī vienmēr ir pirmdiena, pēdējais - svētdiena.

    Piemēram, "1100110" nozīmē, ka jūs strādājat trešdien, ceturtdien, piektdien un sestdien.

    Piezīme. Maskai jābūt dubultiekavītēs.

  • Skaitļi .

    Izmantojiet vienciparu skaitļus (1-7), kas apzīmē komplekta nedēļas nogales pāri:

    Numurs	Nedēļas nogale
    1	Sestdiena, svētdiena
    2	Svētdiena, pirmdiena
    3	Pirmdiena, otrdiena
    4	Otrdiena, trešdiena
    5	Trešdiena, ceturtdiena
    6	Ceturtdiena, piektdiena
    7	Piektdiena, sestdiena

    Vai arī strādājiet ar divciparu skaitļiem (11-17), kas apzīmē vienu atpūtas dienu nedēļas laikā:

    Numurs	Nedēļas nogales diena
    11	Svētdiena
    12	Pirmdiena
    13	Otrdiena
    14	Trešdiena
    15	Ceturtdiena
    16	Piektdiena
    17	Sestdiena

• brīvdienas - tas arī nav obligāts un tiek izmantots, lai norādītu brīvdienas.

Šī funkcija var šķist sarežģīta visu šo skaitļu dēļ, taču es aicinu jūs to izmēģināt.

Vispirms vienkārši skaidri izprotiet savas brīvās dienas. Ļaujiet tam Svētdiena un Pirmdiena . Tad izvēlieties, kā norādīt nedēļas nogales.

Ja izmantojat masku, tā būs šāda - 1000001 :

=NETWORKDAYS.INTL(B2, C2, "1000001")

Bet, tā kā man ir divas nedēļas nogales dienas pēc kārtas, es varu izmantot skaitli no iepriekš minētajām tabulām, 2 manā gadījumā:

=NETWORKDAYS.INTL(B2, C2, 2)

Tad vienkārši pievienojiet pēdējo argumentu - atsauce uz brīvdienām E slejā, un formula ir gatava:

=NETWORKDAYS.INTL(B2, C2, 2, $E$2:$E$4)

Google lapas un datumu starpība mēnešos

Dažreiz mēneši ir svarīgāki nekā dienas. Ja tas attiecas uz jums un vēlaties saņemt datumu starpību mēnešos, nevis dienās, ļaujiet šo uzdevumu veikt Google Sheets DATEDIF.

Piemērs 1. Pilnu mēnešu skaits starp diviem datumiem

Darbs ir vienāds: start_date vispirms tiek ievadīts, pēc tam seko end_date un "M" - kas ilgst mēnešiem ilgi - kā galīgais arguments:

=DATEDIF(A2, B2, "M")

Padoms. Neaizmirstiet par funkciju ARRAUFORMULA, kas var palīdzēt jums saskaitīt mēnešus visās rindās vienlaicīgi:

=ARRAYFORMULA(DATEDIF(A2:A13, B2:B13, "M"))

Piemērs 2. Mēnešu skaits, ignorējot gadus

Iespējams, jums nav nepieciešams skaitīt mēnešus visos gados starp sākuma un beigu datumiem. DATEDIF ļauj to darīt.

Vienkārši izmantojiet "YM" un formula vispirms atņems veselus gadus un pēc tam saskaitīs mēnešu skaitu starp datumiem:

=DATEDIF(A2, B2, "YM")

Gadu starp diviem datumiem aprēķināšana Google tabulās

Pēdējā (bet ne mazāk svarīgā) lieta, kas jums jāparāda, ir, kā Google Sheets DATEDIF aprēķina datumu starpību gados.

Es aprēķināšu, cik gadu pāri ir precējušies, pamatojoties uz viņu kāzu datumiem un šodienas datumu:

Kā jau, iespējams, esat nojautuši, es izmantošu "Y" vienība, lai to izdarītu:

=DATEDIF(A2, B2, "Y")

Visas šīs DATEDIF formulas ir pirmās, ko izmēģināt, lai aprēķinātu dienas, mēnešus un gadus starp diviem datumiem Google tabulās.

Ja jūsu gadījumu nevar atrisināt ar šiem risinājumiem vai ja jums ir kādi jautājumi, aicinu jūs dalīties ar tiem ar mums tālāk komentāru sadaļā.