Dnešný príspevok na blogu je venovaný zisťovaniu rozdielu medzi dvoma dátumami v tabuľkách Google. Uvidíte veľa vzorcov DATEDIF na počítanie dní, mesiacov a rokov a dozviete sa, ako sa používa vzorec NETWORKDAYS na počítanie iba pracovných dní, aj keď sú vaše sviatky založené na vlastnom rozvrhu.

Mnohí používatelia tabuľkových kalkulátorov považujú prácu s dátumami za mätúcu, ak nie za veľmi náročnú. Ale verte alebo nie, na tento účel existuje niekoľko praktických a jednoduchých funkcií. DATEDIF a NETWORKDAYS sú jedny z nich.

Funkcia DATEDIF v tabuľkách Google

Ako to už pri funkciách býva, ich názvy naznačujú činnosť. To isté platí pre DATEDIF. Je potrebné ho čítať ako dátum dif , nie s dátumom, ak a znamená rozdiel dátumov . Preto funkcia DATEDIF v tabuľkách Google vypočíta rozdiel dátumov medzi dvoma dátumami.

Rozdeľme ju na časti. Funkcia vyžaduje tri argumenty:

• start_date - dátum, ktorý sa používa ako východiskový bod. Musí to byť jeden z týchto údajov:
  • samotný dátum v dvojitých úvodzovkách: "8/13/2020"
  • odkaz na bunku s dátumom: A2
  • vzorec, ktorý vracia dátum: DATE(2020, 8, 13)
  • číslo, ktoré označuje konkrétny dátum a ktoré môže byť interpretované ako dátum v Google Sheets, napr. 44056 predstavuje august 13, 2020 .
• end_date - dátum použitý ako koncový bod. Musí mať rovnaký formát ako start_date .
• jednotka - sa používa na určenie rozdielu, ktorý má funkcia vrátiť. Tu je úplný zoznam jednotiek, ktoré môžete použiť:
  • "D" - (skratka pre dni ) vráti počet dní medzi dvoma dátumami.
  • "M" - (mesiace) počet celých mesiacov medzi dvoma dátumami.
  • "Y" - (roky) počet celých rokov.
  • "MD" - (dni bez mesiacov) počet dní po odpočítaní celých mesiacov.
  • "YD" - (dni bez rokov) počet dní po odpočítaní celých rokov.
  • "YM" - (mesiace bez rokov) počet celých mesiacov po odpočítaní celých rokov.

Poznámka: Všetky jednotky sa musia do vzorcov uvádzať rovnakým spôsobom, ako sú uvedené vyššie - v dvojitých úvodzovkách.

Teraz spojme všetky tieto časti dohromady a pozrime sa, ako vzorce DATEDIF fungujú v hárkoch Google.

Výpočet dní medzi dvoma dátumami v hárkoch Google

Príklad 1. Spočítajte všetky dni

Mám malú tabuľku na sledovanie niektorých objednávok. Všetky boli odoslané v prvej polovici augusta - Dátum odoslania - čo bude môj dátum nástupu. Je tu aj približný dátum dodania - Dátum splatnosti .

Budem počítať dni - "D" - medzi dátumom odoslania a dátumom splatnosti, aby som zistil, ako dlho trvá, kým tovar dorazí. Tu je vzorec, ktorý by som mal použiť:

=DATEDIF(B2, C2, "D")

Vzorec DATEDIF zadám do D2 a potom ho skopírujem do stĺpca, aby sa použil na ďalšie riadky.

Tip: Pomocou vzorca ARRAYFORMULA môžete vždy vypočítať celý stĺpec naraz:

=ArrayFormula(DATEDIF(B2:B13, C2:C13, "D"))

Príklad 2. Počítanie dní bez ohľadu na mesiace

Predstavte si, že medzi dvoma dátumami je niekoľko mesiacov:

Ako sa počítajú len dni, akoby patrili do toho istého mesiaca? Správne: ignorovaním celých mesiacov, ktoré už uplynuli. DATEDIF to vypočíta automaticky, keď použijete "MD" jednotka:

=DATEDIF(A2, B2, "MD")

Funkcia odpočíta uplynulé mesiace a spočíta zostávajúce dni.

Príklad 3. Počítanie dní bez ohľadu na roky

Ďalšia jednotka - "YD" - pomôže, keď je medzi dátumami viac ako rok:

=DATEDIF(A2, B2, "YD")

Vzorec najprv odčíta roky a potom vypočíta zostávajúce dni, ako keby patrili do toho istého roka.

Počítanie pracovných dní v hárkoch Google

Existuje špeciálny prípad, keď potrebujete v hárkoch Google počítať len pracovné dni. Vzorce DATEDIF vám tu veľmi nepomôžu. A verím, že budete súhlasiť, že ručné odčítanie víkendov nie je najelegantnejšia možnosť.

Našťastie, Google Sheets má na to niekoľko nie až tak magických kúziel :)

Príklad 1. Funkcia NETWORKDAYS

Prvá z nich sa nazýva NETWORKDAYS. Táto funkcia vypočíta počet pracovných dní medzi dvoma dátumami bez víkendov (soboty a nedele) a v prípade potreby aj sviatkov:

• start_date - dátum, ktorý sa používa ako východiskový bod. Požadované.

  Poznámka: Ak tento dátum nie je sviatok, počíta sa ako pracovný deň.

• end_date - dátum použitý ako koncový bod. Požadované.

  Poznámka: Ak tento dátum nie je sviatok, počíta sa ako pracovný deň.

• Dovolenka - tento údaj je nepovinný, ak potrebujete poukázať na konkrétne sviatky. Musí to byť rozsah dátumov alebo čísel predstavujúcich dátumy.

Na ilustráciu toho, ako to funguje, pridám zoznam sviatkov, ktoré sa konajú medzi dátumami odoslania a splatnosti:

Takže stĺpec B je môj dátum začiatku, stĺpce C - dátum konca. Dátumy v stĺpci E sú sviatky, ktoré treba zohľadniť. Takto by mal vyzerať vzorec:

=NETWORKDAYS(B2, C2, $E$2:$E$4)

Tip. Ak sa chystáte kopírovať vzorec do iných buniek, použite absolútne odkazy na bunky pre prázdniny, aby ste sa vyhli chybám alebo nesprávnym výsledkom. Alebo namiesto toho zvážte vytvorenie vzorca poľa.

Všimli ste si, ako sa počet dní znížil v porovnaní so vzorcami DATEDIF? Pretože teraz funkcia automaticky odpočíta všetky soboty, nedele a dva sviatky, ktoré pripadajú na piatok a pondelok.

Poznámka: Na rozdiel od DATEDIF v hárkoch Google, NETWORKDAYS počíta start_day a end_day ako pracovné dni, pokiaľ nie sú sviatkami. Preto D7 vracia 1 .

Príklad 2. NETWORKDAYS.INTL pre tabuľky Google

Ak máte vlastný rozvrh víkendov, využijete ďalšiu funkciu: NETWORKDAYS.INTL. Umožňuje vám počítať pracovné dni v hárkoch Google na základe osobne nastavených víkendov:

• start_date - dátum, ktorý sa používa ako východiskový bod. Požadované.
• end_date - dátum použitý ako koncový bod. Požadované.

  Poznámka: NETWORKDAYS.INTL v hárkoch Google sa tiež počíta start_day a end_day ako pracovné dni, pokiaľ nie sú sviatkami.

• víkend - Tento údaj je nepovinný. Ak sa vynechá, sobota a nedeľa sa považujú za víkendy. Môžete to však zmeniť dvoma spôsobmi:
  • Masky .

    Tip. Tento spôsob je ideálny, keď máte voľné dni roztrúsené po celom týždni.

    Maska je sedemmiestny vzor 1 a 0. 1 znamená víkend, 0 pracovný deň. Prvá číslica vo vzore je vždy pondelok, posledná nedeľa.

    Napríklad, "1100110" znamená, že pracujete v stredu, štvrtok, piatok a sobotu.

    Poznámka: Maska musí byť uvedená v dvojitých úvodzovkách.

  • Čísla .

    Použite jednociferné čísla (1-7), ktoré označujú dvojicu nastavených víkendov:

    Číslo	Víkend
    1	Sobota, nedeľa
    2	nedeľa, pondelok
    3	Pondelok, utorok
    4	Utorok, streda
    5	Streda, štvrtok
    6	Štvrtok, piatok
    7	Piatok, sobota

    Alebo pracujte s dvojcifernými číslami (11-17), ktoré označujú jeden deň odpočinku v rámci týždňa:

    Číslo	Víkendový deň
    11	Nedeľa
    12	Pondelok
    13	Utorok
    14	Streda
    15	Štvrtok
    16	Piatok
    17	Sobota

• Dovolenka - je tiež nepovinný a používa sa na zadanie sviatkov.

Táto funkcia sa môže zdať zložitá kvôli všetkým tým číslam, ale odporúčam vám, aby ste ju vyskúšali.

Najskôr si ujasnite, aké sú vaše voľné dni. Nedeľa a Pondelok Potom sa rozhodnite, ako označíte svoje víkendy.

Ak použijete masku, bude to takto - 1000001 :

=NETWORKDAYS.INTL(B2, C2, "1000001")

Ale keďže mám dva víkendové dni po sebe, môžem použiť číslo z vyššie uvedených tabuliek, 2 v mojom prípade:

=NETWORKDAYS.INTL(B2, C2, 2)

Potom stačí pridať posledný argument - odkaz na dovolenku v stĺpci E a vzorec je pripravený:

=NETWORKDAYS.INTL(B2, C2, 2, $E$2:$E$4)

Tabuľky Google a rozdiel dátumov v mesiacoch

Niekedy sú mesiace dôležitejšie ako dni. Ak to platí aj pre vás a uprednostňujete získavanie rozdielu dátumov v mesiacoch pred dňami, nechajte to urobiť funkciu DATEDIF v tabuľkách Google.

Príklad 1. Počet celých mesiacov medzi dvoma dátumami

Postup je rovnaký: start_date ide ako prvý, po ňom nasleduje end_date a "M" - ktorá stojí mesiace - ako posledný argument:

=DATEDIF(A2, B2, "M")

Tip: Nezabudnite na funkciu ARRAUFORMULA, ktorá vám pomôže spočítať mesiace vo všetkých riadkoch naraz:

=ARRAYFORMULA(DATEDIF(A2:A13, B2:B13, "M")

Príklad 2. Počet mesiacov ignorujúcich roky

Nemusíte potrebovať počítať mesiace vo všetkých rokoch medzi začiatočným a koncovým dátumom. A DATEDIF vám to umožňuje.

Stačí použiť "YM" a vzorec najprv odpočíta celé roky a potom spočíta počet mesiacov medzi dátumami:

=DATEDIF(A2, B2, "YM")

Výpočet rokov medzi dvoma dátumami v hárkoch Google

Posledná (ale nie posledná) vec, ktorú vám ukážeme, je spôsob, akým tabuľka Google DATEDIF vypočíta rozdiel dátumov v rokoch.

Na základe dátumu svadby a dnešného dátumu vypočítam počet rokov, ktoré páry prežili v manželstve:

Ako ste už možno uhádli, použijem "Y" jednotka pre túto oblasť:

=DATEDIF(A2, B2, "Y")

Všetky tieto vzorce DATEDIF sú prvé, ktoré môžete vyskúšať pri výpočte dní, mesiacov a rokov medzi dvoma dátumami v hárkoch Google.

Ak sa váš prípad nedá vyriešiť pomocou týchto riešení alebo ak máte nejaké otázky, odporúčam vám, aby ste sa s nami o ne podelili v sekcii komentárov nižšie.