See õpetus selgitab, kuidas kasutada MATCH funktsiooni Excelis koos valemite näidetega. Samuti näitab see, kuidas parandada oma otsinguvormeleid, tehes dünaamilise valemi VLOOKUP ja MATCH abil.

Microsoft Excelis on palju erinevaid otsingu-/viitamisfunktsioone, mis aitavad teil leida teatud väärtust rakkude vahemikus, ja MATCH on üks neist. Põhimõtteliselt tuvastab see elemendi suhtelise asukoha rakkude vahemikus. MATCH-funktsioon saab aga teha palju enamat kui selle puhas olemus.

Exceli funktsioon MATCH - süntaks ja kasutusalad

Exceli funktsioon MATCH otsib määratud väärtust rakkude vahemikus ja tagastab selle väärtuse suhtelise asukoha.

Funktsiooni MATCH süntaks on järgmine:

Lookup_value (kohustuslik) - väärtus, mida soovite leida. See võib olla numbriline, tekstiline või loogiline väärtus ning ka lahtriviide.

Lookup_array (nõutav) - lahtrite vahemik, milles otsitakse.

Match_type (valikuline) - määratleb vaste tüübi. See võib olla üks järgmistest väärtustest: 1, 0, -1. Argument match_type, mille väärtuseks on 0, annab tagasi ainult täpse vaste, teised kaks tüüpi võimaldavad ligikaudset vastet.

• 1 või jäetud (vaikimisi) - leida suurim väärtus otsingumassiivi, mis on väiksem või võrdne otsinguväärtusega. Nõuab otsingumassiivi sorteerimist kasvavas järjekorras, väikseimast suurimani või A-st Z-ni.
• 0 - leida massiivi esimene väärtus, mis on täpselt võrdne otsinguväärtusele. Sorteerimine ei ole vajalik.
• -1 - leida väikseim väärtus massiivis, mis on suurem või võrdne otsinguväärtusega. Otsingumassiivi tuleks sorteerida kahanevas järjekorras, suurimast väikseimani või Z-st A-sse.

Funktsiooni MATCH paremaks mõistmiseks teeme lihtsa valemi, mis põhineb nendel andmetel: õpilaste nimed veerus A ja nende eksamitulemused veerus B, sorteeritud suurimast väikseimani. Et leida, kus konkreetne õpilane (ütleme, Laura ) seisab teiste seas, kasutavad seda lihtsat valemit:

=MATCH("Laura", A2:A8, 0)

Valikuliselt võite panna otsinguväärtuse mõnda lahtrisse (antud näites E1) ja viidata sellele lahtrisse oma Exceli sobitamise valemis:

=MATCH(E1, A2:A8, 0)

Nagu näete ülaltoodud ekraanipildil, on õpilaste nimed sisestatud suvalises järjekorras ja seetõttu määrame me funktsiooni match_type argumendiks 0 (täpne kokkulangevus), sest ainult see kokkulangevuse tüüp ei nõua väärtuste sorteerimist otsingumassiivis. Tehniliselt annab valem Match tagasi Laura suhtelise positsiooni vahemikus. Kuid kuna hinded on sorteeritud suurimast väikseimale, ütleb see meile ka, et Laura on kõigi õpilaste seas 5. parim tulemus.

Vihje. Excel 365-s ja Excel 2021-s saate kasutada XMATCH-funktsiooni, mis on MATCHi kaasaegne ja võimsam järeltulija.

4 asja, mida peaksite teadma MATCH-funktsioonist

Nagu te just nägite, on MATCHi kasutamine Excelis lihtne. Kuid nagu peaaegu kõigi teiste funktsioonide puhul, on ka siin mõned eripärad, millest peaksite teadlik olema:

1. Funktsioon MATCH tagastab suhteline positsioon massiivis oleva otsinguväärtuse, mitte väärtuse enda kohta.
2. MATCH on suur- ja väiketähelepanuta , mis tähendab, et see ei tee tekstiväärtuste käsitlemisel vahet väikestel ja suurtel tähtedel.
3. Kui otsingumassiiv sisaldab mitu otsinguväärtuse esinemist, tagastatakse esimese väärtuse positsioon.
4. Kui otsinguväärtust ei leita otsingumassiivist, tagastatakse #N/A viga.

Kuidas kasutada MATCH-i Excelis - valemite näited

Nüüd, kui te teate Exceli MATCH-funktsiooni põhilisi kasutusvõimalusi, arutame veel paari valemite näidet, mis lähevad põhitõdedest kaugemale.

Osaline kokkulangevus metsikutega

Nagu paljud teisedki funktsioonid, mõistab MATCH järgmisi jokker-märke:

• Küsimärk (?) - asendab ükskõik millist märki.
• Tähtmärk (*) - asendab mis tahes tähemärkide jada.

Märkus. Metsikuid sümboleid saab kasutada ainult Match-valemites, mille puhul on olemas match_type 0.

Sobitusvormel koos jokkeritega on kasulik olukordades, kus soovite sobitada mitte kogu tekstijada, vaid ainult mõned tähemärgid või osa sellest. Selle punkti illustreerimiseks vaadake järgmist näidet.

Oletame, et teil on nimekiri piirkondlikest edasimüüjatest ja nende viimase kuu müüginumbritest. Te soovite leida teatava edasimüüja suhtelist positsiooni nimekirjas (sorteeritud müügisummade järgi kahanevas järjekorras), kuid te ei mäleta täpselt tema nime, kuigi mäletate mõningaid esimesi tähemärke.

Eeldades, et edasimüüjate nimed on vahemikus A2:A11 ja te otsite nime, mis algab sõnaga "auto", on valem järgmine:

=MATCH("auto*", A2:A11,0)

Et muuta meie Match-valem mitmekülgsemaks, võite sisestada otsinguväärtuse mõnda lahtrisse (siinses näites E1) ja liita see lahter metsiku sümboliga, näiteks nii:

=MATCH(E1& "*", A2:A11,0)

Nagu on näidatud allpool oleval ekraanipildil, annab valem tagasi 2, mis on "Carter" positsioon:

Ainult ühe tähemärgi asendamiseks otsinguväärtuses kasutage metsikoperaatorit "?", näiteks nii:

=MATCH("ba?er", A2:A11,0)

Ülaltoodud valem vastab nimele " Baker " ja käivitage uuesti selle suhteline asukoht, mis on 5.

Suur- ja väiketähendusega MATCH-valem

Nagu selle õpetuse alguses mainitud, ei tee funktsioon MATCH vahet suur- ja väiketähtede vahel. Suur- ja väiketähtedest sõltuva sobitamise valemi tegemiseks kasutage MATCHi koos funktsiooniga EXACT, mis võrdleb lahtreid täpselt, sealhulgas tähemärkide suurust.

Siin on üldine suur- ja väiketähenduslik valem andmete sobitamiseks:

Valem töötab järgmise loogika alusel:

• Funktsioon EXACT võrdleb otsinguväärtust otsingumassiivi iga elemendiga. Kui võrreldud lahtrid on täpselt võrdsed, tagastab funktsioon TRUE, vastasel juhul FALSE.
• Ja siis võrdleb MATCH funktsioon TRUE (mis on tema lookup_value ) iga väärtusega EXACT-i poolt tagastatud massiivi ja tagastab esimese kokkulangevuse positsiooni.

Pidage meeles, et tegemist on massiivi valemiga, mille korrektseks täitmiseks tuleb vajutada Ctrl + Shift + Enter.

Eeldades, et teie otsinguväärtus on lahtris E1 ja otsingumassiiv on A2:A9, on valem järgmine:

=MATCH(TRUE, EXACT(A2:A9,E1),0)

Järgneval ekraanipildil on näidatud Excelis suur- ja väiketähtedega sobitamise valem:

Võrdle 2 veergu kokkulangevuste ja erinevuste leidmiseks (ISNA MATCH)

Kahe loendi kontrollimine kokkulangevuste ja erinevuste suhtes on üks kõige tavalisemaid ülesandeid Excelis ja seda saab teha mitmel viisil. ISNA/MATCH valem on üks neist:

Iga nimekirja 2 väärtuse puhul, mida ei ole nimekirjas 1, annab valem tagasi " Ei ole nimekirjas 1 ". Ja siin on, kuidas:

• Funktsioon MATCH otsib loendi 1 väärtust loendis 2. Kui väärtus leitakse, siis tagastatakse selle suhteline asukoht, vastasel juhul #N/A viga.
• Exceli funktsioon ISNA teeb ainult ühte asja - kontrollib #N/A vigu (st "ei ole saadaval"). Kui antud väärtus on #N/A viga, tagastab funktsioon TRUE, vastasel juhul FALSE. Meie puhul tähendab TRUE, et loendi 1 väärtust ei leidu loendis 2 (st MATCH tagastab #N/A vea).
• Kuna kasutajate jaoks võib olla väga segadusttekitav näha TRUE väärtuste puhul, mida ei ole nimekirjas 1, siis mähite IF-funktsiooni ümber ISNA, et kuvada " Ei ole nimekirjas 1 " või mis tahes teksti, mida soovite.

Näiteks veerus B olevate väärtuste võrdlemiseks veerus A olevate väärtustega võtab valem järgmise kuju (kus B2 on kõige ülemine lahter):

=IF(ISNA(MATCH(B2,A:A,0)), "Ei ole nimekirjas 1", "")

Nagu mäletate, on MATCH-funktsioon Excelis iseenesest suur- ja väiketähtede suhtes tundmatu. Et see eristaks tähemärkide suurust, põimige EXACT-funktsiooniga lookup_array argumendi, ja ärge unustage vajutada Ctrl + Shift + Enter, et lõpetada see massiivi valem :

=IF(ISNA(MATCH(TRUE, EXACT(A:A, B2),0)), "Ei ole nimekirjas 1", "")

Järgneval ekraanipildil on mõlemad valemid töös:

Kui soovite õppida teisi võimalusi kahe loendi võrdlemiseks Excelis, vaadake järgmist õpetust: Kuidas võrrelda 2 veergu Excelis.

Excel VLOOKUP ja MATCH

See näide eeldab, et teil on juba mõningad algteadmised Exceli VLOOKUP-funktsioonist. Ja kui teil on, siis on tõenäoline, et olete kokku puutunud selle arvukate piirangutega (mille üksikasjalik ülevaade on esitatud artiklis Miks Excel VLOOKUP ei tööta) ja otsite jõulisemat alternatiivi.

Üks VLOOKUPi kõige tüütumaid puudusi on see, et see lakkab töötamast pärast veeru sisestamist või kustutamist lookup tabelis. See juhtub seetõttu, et VLOOKUP tõmbab sobiva väärtuse, mis põhineb teie poolt määratud tagastussamba numbril (indeksi number). Kuna indeksnumber on valemisse "kõvasti kodeeritud", ei saa Excel seda kohandada, kui tabelisse lisatakse või kustutatakse uus(ad) veerg(ud).

Exceli funktsioon MATCH tegeleb suhteline positsioon otsinguväärtuse, mis muudab selle ideaalselt sobivaks col_index_num argumendi VLOOKUP. Teisisõnu, selle asemel, et määrata tagastussammas staatilise numbrina, kasutate MATCHi, et saada selle veeru praegune positsioon.

Et asi oleks arusaadavam, kasutame taas tabelit õpilaste eksamitulemustega (sarnaselt sellele, mida kasutasime selle õpetuse alguses), kuid seekord otsime välja tegeliku tulemuse, mitte selle suhtelise positsiooni.

Eeldades, et otsinguväärtus on lahtris F1, tabeli massiiv on $A$1:$C$2 (hea tava on lukustada see absoluutsete lahtriviidete abil, kui plaanite valemit kopeerida teistesse lahtritesse), siis valem on järgmine:

=VLOOKUP(F1, $A$1:$C$8, 3, FALSE)

Kolmas argument ( col_index_num ) on määratud 3, sest Matemaatika tulemus mida me tahame tõmmata, on tabeli 3. veerg. Nagu allpool oleval ekraanipildil näha, töötab see tavaline Vlookup-valem hästi:

Kuid ainult seni, kuni sisestate või kustutate veeru(d):

Miks siis #REF! viga? Sest col_index_num seatud 3 käsutab Excelil saada väärtus kolmandast veerust, samas kui nüüd on tabelimassiivis ainult 2 veergu.

Selliste asjade vältimiseks võite muuta oma Vlookup-valemi dünaamilisemaks, lisades järgmise Match-funktsiooni:

MATCH(E2,A1:C1,0)

Kus:

• E2 on otsinguväärtus, mis on täpselt võrdne tagastussamba nimele, st veerule, millest soovite väärtuse välja võtta ( Matemaatika tulemus selles näites).
• A1:C1 on tabeli päiseid sisaldav otsingumassiiv.

Ja nüüd, lisada see Match funktsioon col_index_num Vlookup valemi argument, näiteks nii:

=VLOOKUP(F1,$A$1:$C$8, MATCH(E2,$A$1:$C$1, 0), FALSE)

Ja veenduge, et see töötab laitmatult, olenemata sellest, kui palju veerge te lisate või kustutate:

Ülaltoodud ekraanipildil lukustasin kõik lahtriviited, et valem töötaks korrektselt, isegi kui mu kasutajad liigutavad seda töölehel teise kohta. Nagu näete alloleval ekraanipildil, töötab valem pärast veeru kustutamist suurepäraselt; lisaks on Excel piisavalt nutikas, et sellisel juhul absoluutseid viiteid korrektselt kohandada:

Excel HLOOKUP ja MATCH

Sarnaselt saate kasutada Exceli funktsiooni MATCH, et parandada oma HLOOKUP-valemeid. Üldine põhimõte on sisuliselt sama, mis Vlookup'i puhul: kasutate funktsiooni Match, et saada tagastussamba suhteline asukoht ja esitate selle numbri funktsiooni row_index_num argument teie Hlookup valemiga.

Oletame, et otsinguväärtus on lahtris B5, tabeli massiiv on B1:H3, tagastatava rea nimi (MATCHi otsinguväärtus) on lahtris A6 ja rea päised on A1:A3, siis on täielik valem järgmine:

=HLOOKUP(B5, B1:H3, MATCH(A6, A1:A3, 0), FALSE)

Nagu te just nägite, on Hlookup/Vlookup & Match kombinatsioon kindlasti parem kui tavalised Hlookup ja Vlookup valemid. Siiski ei kõrvalda MATCH funktsioon kõiki nende piiranguid. Eelkõige ei saa Vlookup Match valem ikka veel vaadata vasakule ja Hlookup Match ei suuda otsida muudest kui kõige ülemisest reast.

Ülaltoodud (ja mõnede teiste) piirangute ületamiseks kaaluge INDEX MATCH kombinatsiooni kasutamist, mis pakub Excelis tõesti võimsat ja mitmekülgset võimalust otsingu tegemiseks, mis on paljudes aspektides parem kui Vlookup ja Hlookup. Üksikasjalikud juhised ja valemite näited leiate dokumendis INDEX & MATCH in Excel - parem alternatiiv VLOOKUPile.

Nii kasutate MATCH-vormeleid Excelis. Loodetavasti osutuvad selles õpetuses käsitletud näited teie töös kasulikuks. Tänan teid lugemise eest ja loodan, et näeme teid järgmisel nädalal meie blogis!

Praktiline töövihik allalaadimiseks

Exceli MATCH-valemi näited (.xlsx fail)