Šajā pamācībā ir izskaidrots, kā lietot funkciju MATCH programmā Excel, izmantojot formulas piemērus. Tajā arī parādīts, kā uzlabot meklēšanas formulas, izveidojot dinamisku formulu ar VLOOKUP un MATCH.

Programmā Microsoft Excel ir daudz dažādu meklēšanas/atsauksmes funkciju, kas var palīdzēt atrast noteiktu vērtību šūnu diapazonā, un MATCH ir viena no tām. Būtībā tā nosaka elementa relatīvo pozīciju šūnu diapazonā. Tomēr funkcija MATCH var paveikt daudz vairāk nekā tikai tās būtība.

Excel MATCH funkcija - sintakse un lietojums

Ar funkciju MATCH programmā Excel tiek meklēta norādītā vērtība šūnu diapazonā un atgriezta šīs vērtības relatīvā pozīcija.

Funkcijas MATCH sintakse ir šāda:

Lookup_value (obligāts) - vērtība, ko vēlaties atrast. Tā var būt skaitliska, teksta vai loģiska vērtība, kā arī atsauce uz šūnu.

Lookup_array (obligāts) - meklēšanai paredzēto šūnu diapazons.

Match_type (nav obligāts) - nosaka atbilstības tipu. Tas var būt viena no šīm vērtībām: 1, 0, -1. Arguments match_type, kas iestatīts uz 0, atgriež tikai precīzu atbilstību, bet pārējie divi tipi ļauj veikt aptuvenu atbilstību.

• 1 vai izlaists (noklusējuma iestatījums) - atrast lielākā vērtība meklēšanas masīvā, kas ir mazāks vai vienāds ar meklēšanas vērtību. Nepieciešams sakārtot meklēšanas masīvu augošā secībā no mazākā līdz lielākajam vai no A līdz Z.
• 0 - atrast pirmo vērtību masīvā, kas ir precīzi vienāds uz meklēšanas vērtību. Šķirošana nav nepieciešama.
• -1 - atrast mazākā vērtība masīvā, kas ir lielāka vai vienāda ar meklēšanas vērtību. Masu jāsarindo dilstošā secībā no lielākās uz mazāko vai no Z uz A.

Lai labāk izprastu funkciju MATCH, izveidosim vienkāršu formulu, pamatojoties uz šiem datiem: studentu vārdi A slejā un viņu eksāmenu rezultāti B slejā, sakārtoti no lielākā līdz mazākajam. Lai uzzinātu, kur atrodas konkrēts students (piem, Laura ) stendos cita starpā izmanto šo vienkāršo formulu:

=MATCH("Laura", A2:A8, 0)

Pēc izvēles varat ievietot meklēšanas vērtību kādā šūnā (šajā piemērā E1) un atsaukties uz šo šūnu Excel atbilstības formulā:

=MATCH(E1, A2:A8, 0)

Kā redzams iepriekš redzamajā ekrānšāviņas attēlā, skolēnu vārdi ir ievadīti patvaļīgā secībā, un tāpēc mēs iestatām match_type argumentam 0 (precīza atbilstība), jo tikai šim atbilstības veidam nav nepieciešama vērtību šķirošana meklēšanas masīvā. Tehniski atbilstības formula atgriež Lauras relatīvo pozīciju diapazonā. Bet, tā kā rezultāti ir sakārtoti no lielākā līdz mazākajam, tā mums arī norāda, ka Laurai ir 5. labākais rezultāts starp visiem skolēniem.

Padoms. Programmās Excel 365 un Excel 2021 varat izmantot funkciju XMATCH, kas ir moderna un jaudīgāka MATCH pēctecis.

4 lietas, kas jāzina par funkciju MATCH

Kā tikko redzējāt, MATCH izmantošana programmā Excel ir vienkārša. Tomēr, tāpat kā gandrīz jebkuras citas funkcijas gadījumā, ir dažas īpatnības, kas jums jāzina:

1. MATCH funkcija atgriež relatīvā pozīcija meklēšanas vērtību masīvā, nevis pašu vērtību.
2. MATCH ir lielo un mazo burtu un atbilžu , kas nozīmē, ka, strādājot ar teksta vērtībām, tas nenošķir mazos un lielos burtus.
3. Ja meklēšanas masīvs satur vairākus meklēšanas vērtības atkārtojumus, tiek atgriezta pirmās vērtības pozīcija.
4. Ja meklēšanas vērtība nav atrasta meklēšanas masīvā, tiek atgriezta #N/A kļūda.

Kā lietot MATCH programmā Excel - formulu piemēri

Tagad, kad esat iepazinušies ar Excel MATCH funkcijas pamatlietām, aplūkosim vēl dažus formulas piemērus, kas pārsniedz pamatprincipus.

Daļēja atbilstība ar aizstājējzīmēm

Tāpat kā daudzas citas funkcijas, arī MATCH saprot šādas aizstājējzīmes:

• Jautājuma zīme (?) - aizstāj jebkuru atsevišķu rakstzīmi.
• Zvaigznīte (*) - aizvieto jebkuru rakstzīmju virkni.

Piezīme. aizstājējzīmes var izmantot tikai vienādojuma formulās ar match_type iestatīts uz 0.

Saskaņošanas formula ar aizstājējzīmēm ir noderīga situācijās, kad vēlaties saskaņot nevis visu teksta virkni, bet tikai dažas rakstzīmes vai daļu no virknes. Lai ilustrētu šo punktu, aplūkojiet šādu piemēru.

Pieņemsim, ka jums ir reģionālo tālākpārdevēju saraksts un to pārdošanas apjomi par pēdējo mēnesi. Jūs vēlaties atrast kāda konkrēta tālākpārdevēja relatīvo pozīciju sarakstā (sakārtots pēc pārdošanas apjomiem dilstošā secībā), bet jūs nevarat precīzi atcerēties viņa vārdu, lai gan atceraties dažus pirmos burtus.

Pieņemot, ka tālākpārdevēju nosaukumi ir diapazonā A2:A11 un tiek meklēts nosaukums, kas sākas ar "car", formula ir šāda:

=MATCH("car*", A2:A11,0)

Lai padarītu mūsu Saskaņošanas formulu daudzpusīgāku, varat ievadīt meklēšanas vērtību kādā šūnā (šajā piemērā - E1) un savienot šo šūnu ar aizstājējzīmju, piemēram, šādi:

=MATCH(E1& "*", A2:A11,0)

Kā redzams zemāk redzamajā ekrānšāviņas attēlā, formula atgriež 2, kas ir "Carter" pozīcija:

Lai aizstātu tikai vienu meklēšanas vērtības rakstzīmi, izmantojiet aizstājējzīmju operatoru "?", piemēram, šādi:

=MATCH("ba?er", A2:A11,0)

Iepriekš minētā formula atbilst nosaukumam " Baker " un atkārtoti palaidiet tā relatīvo pozīciju, kas ir 5.

Lietošanai lietoto burtu MATCH formula

Kā minēts šīs pamācības sākumā, funkcija MATCH nenošķir lielo un mazo burtu rakstzīmes. Lai izveidotu lielo un mazo burtu rakstzīmju Saskaņošanas formulu, izmantojiet MATCH kopā ar funkciju EXACT, kas salīdzina šūnas precīzi, ieskaitot rakstzīmju lielumu.

Šeit ir dota vispārīgā burtu un lielo un mazo burtu sensitīvā formula, lai saskaņotu datus:

Formula darbojas pēc šādas loģikas:

• EXACT funkcija salīdzina meklēšanas vērtību ar katru meklēšanas masīva elementu. Ja salīdzinātie elementi ir pilnīgi vienādi, funkcija atgriež TRUE, pretējā gadījumā FALSE.
• Un tad funkcija MATCH salīdzina TRUE (kas ir tās lookup_value ) ar katru vērtību masīvā, ko atgriež EXACT, un atgriež pirmās atbilstības pozīciju.

Lūdzu, ņemiet vērā, ka tā ir masīva formula, kuras pareizai izpildei nepieciešams nospiest taustiņus Ctrl + Shift + Enter.

Pieņemot, ka jūsu meklēšanas vērtība ir šūnā E1 un meklēšanas masīvs ir A2:A9, formula ir šāda:

=MATCH(TRUE, EXACT(A2:A9,E1),0)

Tālāk redzamajā ekrānšāviņas attēlā ir parādīta uz mazajiem un lielajiem burtiem jutīgā Saskaņošanas formula programmā Excel:

Salīdziniet 2 kolonnas, lai atrastu sakritības un atšķirības (ISNA MATCH)

Divu sarakstu atbilstības un atšķirību pārbaude ir viens no visbiežāk sastopamajiem uzdevumiem programmā Excel, un to var veikt dažādos veidos. Viens no tiem ir ISNA/MATCH formula:

Jebkurai 2. saraksta vērtībai, kas nav iekļauta 1. sarakstā, formula atgriež " Nav 1. sarakstā ". Un lūk, kā:

• Ar funkciju MATCH tiek meklēta vērtība no saraksta List 1 sarakstā List 2. Ja vērtība tiek atrasta, tiek atgriezta tās relatīvā pozīcija, pretējā gadījumā tiek atgriezta #N/A kļūda.
• ISNA funkcija programmā Excel veic tikai vienu funkciju - pārbauda, vai nav #N/A kļūdas (kas nozīmē "nav pieejams"). Ja dotā vērtība ir #N/A kļūda, funkcija atgriež TRUE, pretējā gadījumā FALSE. Mūsu gadījumā TRUE nozīmē, ka vērtība no saraksta 1 nav atrodama sarakstā 2 (t. i., MATCH atgriež #N/A kļūdu).
• Tā kā lietotājiem var būt ļoti mulsinoši redzēt TRUE vērtībām, kas nav parādījušās 1. sarakstā, jūs ietinat IF funkciju ap ISNA, lai parādītu " Nav 1. sarakstā " vai jebkuru citu tekstu.

Piemēram, lai salīdzinātu vērtības B slejā ar vērtībām A slejā, formulas forma ir šāda (kur B2 ir augšējā šūna):

=IF(ISNA(MATCH(B2,A:A,0)), "Nav 1. sarakstā", "")

Kā atceraties, MATCH funkcija programmā Excel pati par sevi nav jutīga pret rakstzīmju lielumu. Lai panāktu, ka tā atšķir rakstzīmju lielumu, iestrādājiet EXACT funkciju programmā. lookup_array argumentu un atcerieties nospiest Ctrl + Shift + Enter, lai to pabeigtu. masīva formula :

=IF(ISNA(MATCH(TRUE, EXACT(A:A, B2),0)), "Nav 1. sarakstā", "")

Nākamajā ekrāna attēlā redzamas abas formulas:

Lai uzzinātu citus veidus, kā salīdzināt divus sarakstus programmā Excel, skatiet šādu pamācību: Kā salīdzināt 2 kolonnas programmā Excel.

Excel VLOOKUP un MATCH

Šajā piemērā tiek pieņemts, ka jums jau ir pamatzināšanas par Excel VLOOKUP funkciju. Un, ja ir, iespējams, ka esat saskāries ar tās daudzajiem ierobežojumiem (detalizētu pārskatu par tiem var atrast sadaļā Kāpēc Excel VLOOKUP nedarbojas) un meklējat stabilāku alternatīvu.

Viens no kaitinošākajiem VLOOKUP trūkumiem ir tas, ka tas pārstāj darboties pēc kolonnas ievietošanas vai dzēšanas uzmeklēšanas tabulā. Tas notiek tāpēc, ka VLOOKUP iegūst atbilstošo vērtību, pamatojoties uz norādītās atgrieztās kolonnas numuru (indeksa numuru). indeksa numurs formulā ir "cietā kodā", Excel nespēj to pielāgot, ja tabulā tiek pievienota(-as) jauna(-as) sleja(-as) vai tā(-as) tiek dzēsta(-as).

Excel MATCH funkcija apstrādā relatīvā pozīcija meklēšanas vērtības, tāpēc tas ir ideāli piemērots lietojumprogrammai col_index_num Citiem vārdiem sakot, tā vietā, lai norādītu atgriežamo kolonnu kā statisku skaitli, jūs izmantojat MATCH, lai iegūtu šīs kolonnas pašreizējo pozīciju.

Lai būtu vieglāk saprast, atkal izmantosim tabulu ar studentu eksāmenu rezultātiem (līdzīgu tai, ko izmantojām šīs pamācības sākumā), taču šoreiz mēs iegūsim reālo rezultātu, nevis tā relatīvo pozīciju.

Pieņemot, ka meklēšanas vērtība atrodas šūnā F1, tabulas masīvs ir $A$1:$C$2 (ja plānojat kopēt formulu uz citām šūnām, ir ieteicams to bloķēt, izmantojot absolūtās šūnu atsauces), formula ir šāda:

=VLOOKUP(F1, $A$1:$C$8, 3, FALSE)

Trešais arguments ( col_index_num ) ir 3, jo Matemātikas rezultāts kuru mēs vēlamies izvilkt, ir tabulas 3. sleja. Kā redzams zemāk redzamajā ekrānšāviņas attēlā, šī parastā Vlookup formula darbojas labi:

Bet tikai līdz kolonnas(-u) ievietošanai vai dzēšanai:

Kāpēc #REF! kļūda? Jo col_index_num iestatīts uz 3, liek programmai Excel iegūt vērtību no trešās kolonnas, lai gan tagad tabulas masīvā ir tikai 2 kolonnas.

Lai to novērstu, varat padarīt savu Vlookup formulu dinamiskāku, iekļaujot šādu Saskaņošanas funkciju:

MATCH(E2,A1:C1,0)

Kur:

• E2 ir meklēšanas vērtība, kas ir precīzi vienāds uz atgrieztās kolonnas nosaukumu, t. i., kolonnu, no kuras vēlaties iegūt vērtību ( Matemātikas rezultāts šajā piemērā).
• A1:C1 ir meklēšanas masīvs, kas satur tabulas galvenes.

Un tagad iekļaujiet šo Saskaņošanas funkciju col_index_num Vlookup formulas argumentu, piemēram, šādi:

=VLOOKUP(F1,$A$1:$C$8, MATCH(E2,$A$1:$C$1, 0), FALSE)

Un pārliecinieties, ka tas darbojas nevainojami neatkarīgi no tā, cik daudz kolonnu pievienojat vai dzēšat:

Iepriekš redzamajā ekrānšāviņas attēlā es bloķēju visas šūnu atsauces, lai formula darbotos pareizi pat tad, ja mani lietotāji to pārvieto uz citu darblapas vietu. Kā redzat zemāk redzamajā ekrānšāviņas attēlā, formula darbojas pareizi arī pēc kolonnas dzēšanas; turklāt Excel ir pietiekami gudrs, lai šajā gadījumā pareizi pielāgotu absolūtās atsauces:

Excel HLOOKUP un MATCH

Līdzīgā veidā varat izmantot Excel MATCH funkciju, lai uzlabotu HLOOKUP formulas. Vispārējais princips būtībā ir tāds pats kā Vlookup gadījumā: jūs izmantojat Match funkciju, lai iegūtu atgrieztās kolonnas relatīvo pozīciju, un sniedzat šo skaitli funkcijai HLOOKUP. rindu_indekss_num jūsu Hlookup formulas arguments.

Pieņemsim, ka meklēšanas vērtība ir šūnā B5, tabulas masīvs ir B1:H3, atgrieztās rindas nosaukums (MATCH meklēšanas vērtība) ir šūnā A6 un rindas virsraksti ir A1:A3, pilnā formula ir šāda:

=HLOOKUP(B5, B1:H3, MATCH(A6, A1:A3, 0), FALSE)

Kā tikko redzējāt, Hlookup/Vlookup & amp; Match kombinācija noteikti ir uzlabojums salīdzinājumā ar parastajām Hlookup un Vlookup formulām. Tomēr MATCH funkcija nenovērš visus to ierobežojumus. Jo īpaši Vlookup Match formula joprojām nevar meklēt pa kreisi, un Hlookup Match nespēj meklēt nevienā rindā, izņemot augšējo.

Lai pārvarētu iepriekš minētos (un dažus citus) ierobežojumus, apsveriet iespēju izmantot INDEX MATCH kombināciju, kas nodrošina patiešām jaudīgu un daudzpusīgu veidu, kā veikt meklēšanu programmā Excel, kas daudzējādā ziņā pārspēj Vlookup un Hlookup. Sīki norādījumi un formulu piemēri ir atrodami INDEX & amp; MATCH programmā Excel - labāka alternatīva VLOOKUP.

Šādi Excel programmā tiek izmantotas MATCH formulas. Cerams, ka šajā pamācībā aplūkotie piemēri būs noderīgi jūsu darbā. Paldies, ka izlasījāt, un ceru, ka nākamnedēļ tiksimies mūsu blogā!

Prakses darba burtnīca lejupielādei

Excel MATCH formulas piemēri (.xlsx fails)