Wenn Sie Daten in Ihrem Blatt finden müssen, die einem bestimmten Schlüsseldatensatz entsprechen, wenden Sie sich in der Regel an Google Sheets VLOOKUP. Aber da Sie wissen, dass VLOOKUP fast sofort an seine Grenzen stößt, sollten Sie besser die Ressourcen für diese Aufgabe erhöhen, indem Sie INDEX MATCH lernen.

INDEX MATCH in Google Sheets ist eine Kombination aus zwei Funktionen: INDEX und MATCH. Wenn sie zusammen verwendet werden, stellen sie eine bessere Alternative zu Google Sheets VLOOKUP dar. In diesem Blogbeitrag werden wir ihre Fähigkeiten gemeinsam herausfinden. Aber zuerst möchte ich Ihnen einen kurzen Überblick über ihre eigenen Funktionen in Tabellenkalkulationen geben.

Google Sheets MATCH-Funktion

Ich möchte mit Google Sheets MATCH beginnen, weil es wirklich einfach ist: Es durchsucht Ihre Daten nach einem bestimmten Wert und gibt dessen Position zurück:

• such_schlüssel ist die Platte, nach der Sie suchen. erforderlich.
• Bereich ist entweder eine Zeile oder eine Spalte, in der gesucht werden soll. erforderlich.

  Hinweis: MATCH akzeptiert nur eindimensionale Arrays: entweder Zeilen oder Spalten.

• such_art ist optional und legt fest, ob die Übereinstimmung exakt oder annähernd sein soll; wird sie weggelassen, ist sie standardmäßig 1:
  • 1 bedeutet, dass der Bereich in aufsteigender Reihenfolge sortiert wird. Die Funktion ermittelt den größten Wert, der kleiner oder gleich Ihrem such_schlüssel .
  • 0 lässt die Funktion nach der exakten Übereinstimmung suchen, falls Ihr Bereich nicht sortiert ist.
  • -1 weist darauf hin, dass die Datensätze in absteigender Reihenfolge sortiert werden. In diesem Fall erhält die Funktion den kleinsten Wert, der größer oder gleich Ihrem such_schlüssel .

Hier ein Beispiel: Um die Position einer bestimmten Beere in der Liste aller Beeren zu ermitteln, benötige ich die folgende MATCH-Formel in meinen Google Sheets:

=MATCH("Heidelbeere", A1:A10, 0)

Google Sheets INDEX-Funktion

Während MATCH anzeigt, wo der Wert zu suchen ist (seine Position im Bereich), holt die INDEX-Funktion von Google Sheets den Wert selbst auf der Grundlage seiner Zeilen- und Spaltenabstände:

• Referenz ist der Bereich, in dem zu suchen ist. erforderlich.
• Zeile ist die Anzahl der Zeilen, die von der allerersten Zelle des Bereichs aus verschoben werden sollen (optional, 0, wenn nicht angegeben).
• Spalte , genau wie Zeile ist die Anzahl der Offset-Spalten, ebenfalls optional, auch 0, wenn sie weggelassen wird.

Wenn Sie beide optionalen Argumente (Zeile und Spalte) angeben, wird Google Sheets INDEX einen Datensatz aus einer Zielzelle zurückgeben:

=INDEX(A1:C10, 7, 1)

Wenn Sie eines dieser Argumente weglassen, wird die Funktion die gesamte Zeile oder Spalte entsprechend anzeigen:

=INDEX(A1:C10, 7)

Wie verwendet man INDEX MATCH in Google Sheets - Formelbeispiele

Wenn INDEX und MATCH zusammen in Tabellenkalkulationen verwendet werden, sind sie am mächtigsten: Sie können Google Sheets VLOOKUP absolut ersetzen und den gewünschten Datensatz aus einer Tabelle auf der Grundlage Ihres Schlüsselwerts abrufen.

Erstellen Sie Ihre erste INDEX MATCH Formel für Google Sheets

Nehmen wir an, Sie möchten die Informationen über die Preiselbeerbestände aus derselben Tabelle wie oben entnehmen, wobei ich nur die Spalten B und C vertauscht habe (warum, erfahren Sie später).

1. Jetzt sind alle Beeren in Spalte C aufgelistet. Die MATCH-Funktion von Google Sheets hilft Ihnen, die genaue Zeile der Cranberry zu finden: 8

   =MATCH("Cranberry", C1:C10, 0)

2. Setzen Sie diese ganze MATCH-Formel in eine Zeile Argument in der Funktion INDEX:

   =INDEX(A1:C10, MATCH("Cranberry", C1:C10, 0))

   Dieser wird die gesamte Reihe mit Cranberrys zurückgeben.

3. Da Sie aber nur die Bestandsinformationen benötigen, geben Sie auch die Nummer der Nachschlage-Spalte an: 3

   =INDEX(A1:C10, MATCH("Cranberry", C1:C10,0), 2)

4. Voilà!

   

5. Sie können noch weiter gehen und auf den letzten Spaltenindikator verzichten ( 2 Sie brauchen sie nicht, wenn Sie nur die Lookup-Spalte verwenden ( B1:B10 ) und nicht die gesamte Tabelle ( A1:C10 ) als erstes Argument:

   =INDEX(B1:B10, MATCH("Cranberry", C1:C10, 0))

   

   Tipp: Eine bequemere Möglichkeit, die Verfügbarkeit verschiedener Beeren zu prüfen, wäre es, sie in einer Dropdown-Liste zu platzieren ( E2 ) und beziehen Sie Ihre MATCH-Funktion auf die Zelle mit dieser Liste:

   =INDEX(B1:B10, MATCH(E2, C1:C10, 0))

   Sobald Sie eine Beere auswählen, ändert sich der zugehörige Wert entsprechend:

   

Warum INDEX MATCH in Google Sheets besser ist als VLOOKUP

Sie wissen bereits, dass Google Sheets INDEX MATCH Ihren Wert in einer Tabelle nachschlägt und einen anderen Bezugsdatensatz aus derselben Zeile zurückgibt. Und Sie wissen, dass Google Sheets VLOOKUP genau dasselbe tut. Warum also die Mühe?

Die Sache ist die, INDEX MATCH hat einige wichtige Vorteile über VLOOKUP:

1. Linksseitiges Nachschlagen ist möglich Ich habe vorhin die Position der Spalten geändert, um dies zu verdeutlichen: Die INDEX MATCH-Funktion in Google Sheets kann und wird auch links von der Suchspalte suchen. VLOOKUP sucht immer in der ersten Spalte des Bereichs und sucht nach Übereinstimmungen rechts davon - sonst gibt es nur #N/A-Fehler:

   

2. Keine unübersichtlichen Verweise beim Hinzufügen neuer und Verschieben vorhandener Spalten. Wenn Sie Spalten hinzufügen oder verschieben, spiegelt INDEX MATCH die Änderungen automatisch wider, ohne in das Ergebnis einzugreifen. Da Sie Spaltenreferenzen verwenden, werden diese von Google Sheets sofort angepasst:

   

   Versuchen Sie es mit VLOOKUP: Es benötigt die Bestellnummer und keine Zellbezüge für eine Nachschlage-Spalte, so dass Sie am Ende nur den falschen Wert erhalten, weil eine andere Spalte den gleichen Platz einnimmt - Spalte 2 in meinem Beispiel:

   

3. Betrachtet den Textfall wenn nötig (mehr dazu gleich unten).
4. Kann für die vertikale Suche nach mehreren Kriterien verwendet werden.

Ich lade Sie ein, sich die letzten beiden Punkte im Folgenden genauer anzusehen.

Groß- und Kleinschreibung beachtende v-lookup mit INDEX MATCH in Google Sheets

INDEX MATCH ist die erste Wahl, wenn es um die Unterscheidung von Groß- und Kleinschreibung geht.

Angenommen, alle Beeren werden auf zwei Arten verkauft - lose (an der Ladentheke gewogen) und in Kisten verpackt. Folglich gibt es zwei Vorkommen jeder Beere in verschiedenen Fällen in der Liste, jede mit ihrer eigenen ID, die auch in den Fällen variiert:

Wie können Sie also die Bestandsinformationen zu einer Beere nachschlagen, die auf eine bestimmte Weise verkauft wird? VLOOKUP gibt den ersten Namen zurück, den es findet, egal wie er lautet.

Glücklicherweise kann INDEX MATCH für Google Sheets dies korrekt ausführen, Sie müssen nur eine zusätzliche Funktion verwenden - FIND oder EXACT.

Beispiel 1: FIND für Vlookup mit Groß- und Kleinschreibung

FIND ist in Google Sheets eine Funktion, die Groß- und Kleinschreibung berücksichtigt, und eignet sich daher hervorragend für die vertikale Suche nach Groß- und Kleinschreibung:

=ArrayFormula(INDEX(B2:B19, MATCH(1, FIND(E2, C2:C19)), 0))

Schauen wir mal, was in dieser Formel passiert:

1. FIND durchsucht Spalte C ( C2:C19 ) für den Rekord von E2 ( Kirsche ), wobei die Groß- und Kleinschreibung berücksichtigt wird. Sobald die Formel gefunden ist, wird die Zelle mit einer Zahl "markiert" - 1 .
2. MATCH sucht nach dieser Marke - 1 - in derselben Spalte ( C ) und übergibt die Nummer seiner Zeile an INDEX.
3. INDEX geht bis zu dieser Zeile in Spalte B ( B2:B19 ) und holt den gewünschten Datensatz zu Ihnen.
4. Wenn Sie mit dem Erstellen der Formel fertig sind, drücken Sie Strg+Umschalt+Eingabe, um ArrayFormula am Anfang hinzuzufügen. Dies ist erforderlich, da FIND sonst nicht in der Lage ist, in Arrays (in mehr als einer Zelle) zu suchen. Oder Sie können ' ArrayFormel ' auf Ihrer Tastatur.

Beispiel 2: EXACT für case-sensitive Vlookup

Wenn Sie FIND durch EXACT ersetzen, sucht letzteres nach Datensätzen mit exakt denselben Zeichen, einschließlich ihrer Groß- und Kleinschreibung.

Der einzige Unterschied ist, dass EXACT eine Übereinstimmung mit WAHR statt Nummer 1 Das erste Argument für MATCH sollte daher lauten WAHR :

=ArrayFormula(INDEX(B2:B19, MATCH(TRUE, EXACT(E2, C2:C19), 0)))

Google Sheets INDEX MATCH mit mehreren Kriterien

Was, wenn es mehrere Bedingungen gibt, auf deren Grundlage Sie den Datensatz abrufen möchten?

Prüfen wir den Preis der Kirsche die verkauft wird in PP-Eimer und ist bereits hinauslaufend :

Ich habe alle Kriterien in den Dropdown-Listen in Spalte F angeordnet. Und es ist Google Sheets INDEX MATCH, das mehrere Kriterien unterstützt, nicht VLOOKUP. Hier ist die Formel, die Sie verwenden müssen:

=ArrayFormula(INDEX(B2:B24, MATCH(CONCATENATE(F2:F4), A2:A24&C2:C24&D2:D24, 0),))

Keine Panik! :) Die Logik ist eigentlich ganz einfach:

1. VERKETTUNG(F2:F4) kombiniert alle drei Datensätze aus den Zellen mit den Kriterien zu einer Zeichenkette wie folgt:

   CherryPP EimerAuslauf

   Dies ist eine such_schlüssel für MATCH, oder mit anderen Worten, wonach Sie in der Tabelle suchen.

2. A2:A24&C2:C24&D2:D24 bilden eine Bereich Da alle drei Kriterien in drei separaten Spalten vorkommen, werden sie auf diese Weise quasi kombiniert:

   KirscheKartontablettAuf Lager

   CherryFilm VerpackungAusverkauft

   CherryPP EimerAuslauf

   usw.

3. Das letzte Argument in MATCH - 0 - macht es möglich, die genaue Übereinstimmung zu finden für CherryPP EimerAuslauf Wie Sie sehen können, befindet sie sich in der 3. Zeile.
4. Und dann tut INDEX seine Arbeit: Es holt den Datensatz aus der 3. Zeile der Spalte B.
5. ArrayFormula wird verwendet, um anderen Funktionen zu ermöglichen, mit Arrays zu arbeiten.

Tipp: Wenn Ihre Formel keine Übereinstimmung findet, gibt sie einen Fehler zurück. Um dies zu vermeiden, können Sie die gesamte Formel in IFERROR einschließen (als erstes Argument) und als zweites Argument eingeben, was Sie in einer Zelle anstelle von Fehlern sehen möchten:

=IFERROR(ArrayFormula(INDEX(B2:B27, MATCH(CONCATENATE(F2:F4), A2:A27&C2:C27&D2:D27, 0),)), "Nicht gefunden")

Bessere Alternative zu INDEX MATCH in Google Sheets - Mehrere VLOOKUP-Abgleiche

Unabhängig davon, welche Lookup-Funktion Sie bevorzugen, VLOOKUP oder INDEX MATCH, es gibt eine bessere Alternative zu beiden.

Multiple VLOOKUP Matches ist ein spezielles Add-on für Google Sheets, das entwickelt wurde, um:

• Nachschlagen ohne Formeln
• Nachschlagen in alle Richtungen
• Suche nach mehreren Bedingungen für verschiedene Datentypen: Text, Zahlen, Daten, Zeit, usw.
• mehrere Streichhölzer holen, so viele, wie Sie brauchen (vorausgesetzt natürlich, es sind so viele in Ihrer Tabelle vorhanden)

Die Schnittstelle ist einfach, so dass Sie nicht zweifeln müssen, ob Sie alles richtig machen:

1. Quellbereich auswählen.
2. Legen Sie die Anzahl der Treffer und Spalten fest, die zurückgegeben werden sollen.
3. Feinabstimmung der Bedingungen mit Hilfe der vordefinierten Operatoren ( enthält, =, nicht leer , zwischen , usw.).

Sie werden auch in der Lage sein:

• Vorschau des Ergebnisses
• entscheiden, wo er platziert werden soll
• und wie: als Formel oder nur Werte

Verpassen Sie nicht die Gelegenheit, das Add-on auszuprobieren. Installieren Sie es vom Google Workspace Marketplace. Auf der Tutorial-Seite werden alle Optionen im Detail erklärt.

Wir haben auch ein spezielles Lehrvideo vorbereitet:

Wir sehen uns in den Kommentaren unten oder im nächsten Artikel ;)