Apabila anda perlu mencari data dalam helaian anda yang sepadan dengan rekod kunci tertentu, biasanya VLOOKUP Helaian Google yang anda gunakan. Tetapi begitulah: VLOOKUP menampar anda dengan pengehadan hampir serta-merta. Itulah sebabnya anda lebih baik meningkatkan sumber untuk tugas itu dengan mempelajari PADANAN INDEX.

PADANAN INDEKS dalam Helaian Google ialah gabungan dua fungsi: INDEX dan PADANAN. Apabila digunakan bersama-sama, mereka bertindak sebagai alternatif yang lebih baik untuk VLOOKUP Helaian Google. Mari kita ketahui keupayaan mereka bersama-sama dalam catatan blog ini. Tetapi pertama-tama, saya ingin memberi anda lawatan pantas tentang peranan mereka sendiri dalam hamparan.

Fungsi PADANAN Helaian Google

Saya ingin bermula dengan Google Helaian MATCH kerana ia sangat mudah. Ia mengimbas data anda untuk nilai tertentu dan mengembalikan kedudukannya:

• kunci_carian ialah rekod yang anda cari. Diperlukan.
• julat ialah sama ada baris atau lajur untuk dilihat. Diperlukan.

  Nota. MATCH hanya menerima tatasusunan satu dimensi: sama ada baris atau lajur.

• jenis_carian adalah pilihan dan menentukan sama ada padanan sepatutnya tepat atau anggaran. Jika ditinggalkan, ia adalah 1 secara lalai:
  • 1 bermakna julat diisih dalam tertib menaik. Fungsi mendapat nilai terbesar kurang daripada atau sama dengan kunci_carian anda.
  • 0 akan menjadikan fungsi mencari padanan tepat sekiranya julat anda tidakdiisih.
  • -1 membayangkan bahawa rekod disusun menggunakan pengisihan menurun. Dalam kes ini, fungsi mendapat nilai terkecil yang lebih besar daripada atau sama dengan kunci_carian anda.

Berikut ialah contoh: untuk mendapatkan kedudukan tertentu beri dalam senarai semua beri, saya memerlukan formula MATCH berikut dalam Helaian Google saya:

=MATCH("Blueberry", A1:A10, 0)

Fungsi INDEX Helaian Google

Sementara MATCH menunjukkan tempat untuk mencari nilai anda (lokasinya dalam julat), fungsi INDEX Helaian Google mengambil nilai itu sendiri berdasarkan offset baris dan lajurnya:

• rujukan ialah julat untuk dilihat. Diperlukan.
• baris ialah bilangan baris untuk diimbangi daripada sel pertama julat anda . Pilihan, 0 jika diabaikan.
• lajur , sama seperti baris , ialah bilangan lajur mengimbangi. Juga pilihan, juga 0 jika ditinggalkan.

Jika anda menentukan kedua-dua argumen pilihan (baris dan lajur), Helaian Google INDEX akan mengembalikan rekod daripada sel destinasi:

=INDEX(A1:C10, 7, 1)

Langkau salah satu argumen tersebut dan fungsi itu akan memberikan anda keseluruhan baris atau lajur dengan sewajarnya:

=INDEX(A1:C10, 7)

Cara menggunakan INDEX MATCH dalam Helaian Google — contoh formula

Apabila INDEX dan MATCH digunakan bersama dalam hamparan, ia adalah yang paling hebat. Mereka benar-benar boleh menggantikan Helaian Google VLOOKUP dan mengambil rekod yang diperlukan daripada jadual berdasarkannilai kunci anda.

Bina formula PADANAN INDEX pertama anda untuk Helaian Google

Andaikan anda ingin mendapatkan maklumat stok tentang kranberi daripada jadual yang sama yang saya gunakan di atas. Saya hanya menukar lajur B dan C (anda akan mengetahui mengapa sedikit kemudian).

1. Kini semua beri disenaraikan dalam lajur C. Fungsi PADANAN Helaian Google akan membantu anda mencari baris tepat bagi cranberry: 8

   =MATCH("Cranberry", C1:C10, 0)

2. Letakkan keseluruhan formula MATCH itu kepada argumen baris dalam fungsi INDEX:

   =INDEX(A1:C10, MATCH("Cranberry", C1:C10, 0))

   Lihat juga: 5 cara untuk memasukkan lajur baharu dalam Excel: pintasan, masukkan berbilang, makro VBA dan banyak lagi

   Yang ini akan mengembalikan keseluruhan baris dengan kranberi di dalamnya.

3. Tetapi kerana anda hanya perlukan maklumat stok, nyatakan bilangan lajur carian juga: 3

   =INDEX(A1:C10, MATCH("Cranberry", C1:C10,0), 2)

4. Voila !

   

5. Anda boleh pergi lebih jauh dan menyerahkan penunjuk lajur terakhir itu ( 2 ). Anda tidak akan memerlukannya sama sekali jika anda hanya menggunakan lajur carian ( B1:B10 ) dan bukannya keseluruhan jadual ( A1:C10 ) sebagai hujah pertama:

   =INDEX(B1:B10, MATCH("Cranberry", C1:C10, 0))

   

   Petua. Cara yang lebih mudah untuk menyemak ketersediaan pelbagai buah beri adalah dengan meletakkannya dalam senarai juntai bawah ( E2 ) dan merujuk fungsi MATCH anda ke sel dengan senarai itu:

   =INDEX(B1:B10, MATCH(E2, C1:C10, 0))

   Sebaik sahaja anda memilih beri, nilai yang berkaitan akan berubah dengan sewajarnya:

   

Mengapa INDEX MATCH dalam Helaian Google lebih baik daripada VLOOKUP

Anda sudah tahu bahawa Google Sheets INDEX MATCH mencari nilai anda dalam jadual dan mengembalikan rekod berkaitan lain daripada rekod yang samabarisan. Dan anda tahu bahawa Helaian Google VLOOKUP melakukan perkara yang sama. Jadi, mengapa perlu bersusah payah?

Perkaranya, PADANAN INDEKS mempunyai beberapa kelebihan utama berbanding VLOOKUP:

1. Sebelah kiri carian boleh dilakukan . Saya menukar tempat lajur lebih awal untuk menggambarkan yang ini: fungsi INDEX MATCH dalam Helaian Google boleh dan memang melihat ke sebelah kiri lajur carian. VLOOKUP sentiasa mencari lajur pertama julat dan mencari padanan di sebelah kanannya — jika tidak, ia hanya mendapat ralat #N/A:

   

2. Tidak kacau rujukan apabila menambah lajur baharu dan mengalihkan lajur sedia ada. Jika anda menambah atau mengalihkan lajur, INDEX MATCH akan mencerminkan perubahan secara automatik tanpa mencampuri keputusan. Memandangkan anda menggunakan rujukan lajur, ia dilaraskan serta-merta oleh Helaian Google:

   

   Teruskan dan cuba lakukan ini dengan VLOOKUP: ia memerlukan nombor pesanan dan bukannya rujukan sel untuk lajur carian. Oleh itu, anda hanya akan mendapat nilai yang salah kerana lajur lain mengambil tempat yang sama — lajur 2 dalam contoh saya:

   

3. Pertimbangkan huruf besar kecil apabila perlu (lebih lanjut mengenai ini di bawah).
4. Boleh digunakan untuk carian menegak berdasarkan berbilang kriteria.

Saya menjemput anda untuk melihat pada dua perkara terakhir secara terperinci di bawah.

Pencarian v sensitif huruf besar-besaran dengan PADANAN INDEX dalam Helaian Google

PADAN INDEKS adalah pilihan utama dalam hal kes-sensitiviti.

Andaikan semua buah beri dijual dalam dua cara — longgar (ditimbang di kaunter) dan dibungkus dalam kotak. Oleh itu, terdapat dua kejadian setiap buah beri yang ditulis dalam kes yang berbeza dalam senarai, setiap satu dengan ID sendiri yang juga berbeza dalam kes:

Jadi bagaimana anda boleh mencari maklumat stok tentang buah beri yang dijual dengan cara tertentu? VLOOKUP akan mengembalikan nama pertama yang ditemuinya tidak kira kesnya.

Nasib baik, INDEX MATCH untuk Helaian Google boleh melakukannya dengan betul. Anda hanya perlu menggunakan satu fungsi tambahan — FIND atau EXACT.

Contoh 1. FIND untuk Vlookup sensitif huruf besar/kecil

FIND ialah fungsi sensitif huruf besar/kecil dalam Helaian Google yang menjadikannya hebat untuk carian menegak sensitif huruf besar dan kecil:

=ArrayFormula(INDEX(B2:B19, MATCH(1, FIND(E2, C2:C19)), 0))

Mari lihat apa yang berlaku dalam formula ini:

1. CARI imbasan lajur C ( C2:C19 ) untuk rekod daripada E2 ( ceri ) mengambil kira huruf besarnya. Setelah ditemui, formula "menanda" sel itu dengan nombor — 1 .
2. MATCH mencari tanda ini — 1 — dalam lajur yang sama ( C ) dan menyerahkan nombor barisnya kepada INDEX.
3. INDEX turun ke baris tersebut dalam lajur B ( B2:B19 ) dan mengambil rekod yang diperlukan kepada anda.
4. Apabila anda selesai membina formula, tekan Ctrl+Shift+Enter untuk menambah ArrayFormula pada permulaan. Ia diperlukan kerana tanpanya FIND tidak akan dapat mencari dalam tatasusunan (dalam lebih daripada satu sel). Atau anda boleh menaip' ArrayFormula ' daripada papan kekunci anda.

Contoh 2. EXACT untuk Vlookup sensitif huruf besar dan kecil

Jika anda menggantikan FIND dengan EXACT, yang terakhir akan mencari rekod dengan aksara yang sama, termasuk huruf besarnya.

Satu-satunya perbezaan ialah "menandai" padanan dengan BENAR dan bukannya nombor 1 . Oleh itu, hujah pertama untuk MATCH hendaklah TRUE :

=ArrayFormula(INDEX(B2:B19, MATCH(TRUE, EXACT(E2, C2:C19), 0)))

PADANAN INDEX Helaian Google dengan berbilang kriteria

Bagaimana jika terdapat beberapa syarat berdasarkan yang anda ingin ambil rekod?

Mari kita semak harga ceri yang dijual dalam baldi PP dan sudah kehabisan :

Saya menyusun semua kriteria dalam senarai juntai bawah dalam lajur F. Dan ia ialah INDEX Helaian Google MATCH yang menyokong berbilang kriteria, bukan VLOOKUP. Berikut ialah formula yang perlu anda gunakan:

=ArrayFormula(INDEX(B2:B24, MATCH(CONCATENATE(F2:F4), A2:A24&C2:C24&D2:D24, 0),))

Jangan panik! :) Logiknya sebenarnya agak mudah:

1. CONCATENATE(F2:F4) menggabungkan ketiga-tiga rekod daripada sel dengan kriteria menjadi satu rentetan seperti ini:

   Baldi CherryPPKehabisan

   Ini ialah kunci_carian untuk MATCH, atau, dengan kata lain, perkara yang anda cari dalam jadual.

2. A2:A24&C2:C24&D2:D24 membentuk julat untuk fungsi MATCH untuk dilihat. Memandangkan ketiga-tiga kriteria berlaku dalam tiga lajur berasingan, dengan cara ini anda menggabungkannya:

   Dulang CherryCardboardDalam stok

   Pembungkusan CherryFilm kehabisan stok

   baldi CherryPPKehabisan

   dll .

3. Argumen terakhir dalam MATCH — 0 — membolehkan anda mencari padanan tepat untuk CherryPP bucketRunning out antara semua baris lajur gabungan tersebut. Seperti yang anda lihat, ia berada dalam baris ke-3.
4. Dan kemudian INDEX melakukan perkara itu: ia mengambil rekod daripada baris ke-3 lajur B.
5. ArrayFormula digunakan untuk membenarkan fungsi lain untuk bekerja dengan tatasusunan.

Petua. Jika formula anda tidak menemui padanan, ia akan mengembalikan ralat. Untuk mengelakkannya, anda boleh membungkus keseluruhan formula ini dalam IFERROR (jadikan ia hujah pertama) dan masukkan apa sahaja yang anda mahu lihat dalam sel dan bukannya ralat sebagai hujah kedua:

=IFERROR(ArrayFormula(INDEX(B2:B27, MATCH(CONCATENATE(F2:F4), A2:A27&C2:C27&D2:D27, 0),)), "Not found")

Alternatif yang lebih baik kepada INDEX MATCH dalam Helaian Google — Berbilang Padanan VLOOKUP

Apa jua fungsi carian yang anda suka, VLOOKUP atau INDEX MATCH, terdapat alternatif yang lebih baik untuk kedua-duanya.

Berbilang VLOOKUP Matches ialah alat tambah khas untuk Helaian Google yang direka untuk:

• mencari tanpa formula
• mencari ke semua arah
• mencari mengikut berbilang syarat untuk jenis data yang berbeza : teks, nombor, tarikh, masa, dsb.
• ambil beberapa padanan, seberapa banyak yang anda perlukan (dengan syarat terdapat seberapa banyak padanan dalam jadual anda, sudah tentu)

Antara muka adalah mudah, jadi anda tidak perlu meragui sama ada anda melakukannyasemuanya dengan betul:

1. Pilih julat sumber.
2. Tetapkan bilangan padanan dan lajur untuk dikembalikan.
3. Perhalusi keadaan menggunakan operator yang telah ditetapkan ( mengandungi, =, bukan kosong , antara , dsb.).

Anda juga akan dapat:

• pratonton hasil
• tentukan tempat untuk meletakkannya
• dan caranya: sebagai formula atau hanya nilai

Jangan lepaskan peluang ini untuk menyemak alat tambah. Teruskan dan pasangnya daripada Google Workspace Marketplace. Halaman tutorialnya akan menerangkan setiap pilihan secara terperinci.

Kami juga menyediakan video pengajaran khas:

Jumpa anda dalam ulasan di bawah atau dalam artikel seterusnya ;)