Kada trebate pronaći podatke u vašem listu koji odgovaraju određenom ključnom zapisu, obično se obraćate Google Sheets VLOOKUP-u. Ali izvolite: VLOOKUP vas gotovo odmah postavlja ograničenjima. Zato je bolje da povećate resurse za zadatak tako što ćete naučiti INDEX MATCH.

INDEX MATCH u Google Sheets je kombinacija dvije funkcije: INDEX i MATCH. Kada se koriste u tandemu, djeluju kao bolja alternativa za Google Sheets VLOOKUP. Hajde da zajedno saznamo njihove mogućnosti u ovom blog postu. Ali prvo, želio bih vam dati kratak pregled njihovih uloga u proračunskim tabelama.

Google Sheets MATCH funkcija

Želio bih početi s Googleom Listovi se poklapaju jer je zaista jednostavno. Skenira vaše podatke za određenu vrijednost i vraća njihovu poziciju:

• ključ_pretrage je zapis koji tražite. Obavezno.
• opseg je ili red ili kolona za traženje. Obavezno.

  Napomena. MATCH prihvata samo jednodimenzionalne nizove: red ili kolonu.

• tip_pretraži je opciono i definira da li podudaranje treba biti točno ili približno. Ako se izostavi, po defaultu je 1:
  • 1 znači da je raspon sortiran uzlaznim redoslijedom. Funkcija dobiva najveću vrijednost manju ili jednaku vašem ključ_pretraži .
  • 0 će učiniti da funkcija traži točno podudaranje u slučaju da vaš raspon nijesortirano.
  • -1 nagoveštava da su zapisi rangirani korišćenjem opadajućeg sortiranja. U ovom slučaju, funkcija dobiva najmanju vrijednost veću ili jednaku vašem ključ_pretraži .

Evo primjera: da dobijete poziciju određene bobica na listi svih bobica, potrebna mi je sljedeća MATCH formula u mojim Google Sheets:

=MATCH("Blueberry", A1:A10, 0)

Google Sheets INDEX funkcija

Dok MATCH pokazuje gdje tražiti vašu vrijednost (njenu lokaciju u rasponu), funkcija Google Sheets INDEX dohvaća samu vrijednost na osnovu pomaka reda i stupaca:

• referenca je raspon za traženje. Obavezno.
• red je broj redaka za pomak od prve ćelije vašeg raspona . Opciono, 0 ako je izostavljeno.
• kolona , baš kao i red , je broj pomaknutih stupaca. Također opciono, također 0 ako je izostavljeno.

Ako navedete oba neobavezna argumenta (red i stupac), Google Sheets INDEX će vratiti zapis iz odredišne ​​ćelije:

=ArrayFormula(INDEX(B2:B19, MATCH(TRUE, EXACT(E2, C2:C19), 0)))

Preskočite jedan od tih argumenata i funkcija će vam dati cijeli red ili stupac u skladu s tim:

=INDEX(A1:C10, 7)

Kako koristiti INDEX MATCH u Google tablicama — primjeri formule

Kada se INDEX i MATCH koriste zajedno u proračunskim tabelama, oni su najmoćniji. Oni mogu apsolutno zamijeniti Google Sheets VLOOKUP i preuzeti traženi zapis iz tabele na osnovusvoju ključnu vrijednost.

Napravite svoju prvu formulu INDEX MATCH za Google Sheets

Pretpostavimo da želite da dobijete informacije o zalihama brusnice iz iste tabele koju sam koristio gore. Zamijenio sam samo stupce B i C (zašto ćete saznati malo kasnije).

1. Sada su sve bobice navedene u stupcu C. Funkcija Google Sheets MATCH će vam pomoći da locirate tačan red brusnica: 8

   =MATCH("Cranberry", C1:C10, 0)

2. Stavi tu cijelu MATCH formulu u red argument u funkciji INDEX:

   =INDEX(A1:C10, MATCH("Cranberry", C1:C10, 0))

   Ovaj će vratiti cijeli red sa brusnicom u njemu.

3. Ali pošto su vam potrebne samo informacije o zalihama, navedite i broj kolone za pretraživanje: 3

   =INDEX(A1:C10, MATCH("Cranberry", C1:C10,0), 2)

4. Voila !

   

5. Možete ići dalje i odustati od posljednjeg indikatora stupca ( 2 ). Uopće vam neće trebati ako koristite samo kolonu za traženje ( B1:B10 ) umjesto cijele tablice ( A1:C10 ) kao prvi argument:

   =INDEX(B1:B10, MATCH("Cranberry", C1:C10, 0))

   

   Savjet. Pogodniji način da provjerite dostupnost raznih bobica bi bio da ih postavite na padajuću listu ( E2 ) i uputite svoju funkciju MATCH na ćeliju s tom listom:

   =INDEX(B1:B10, MATCH(E2, C1:C10, 0))

   Nakon što odaberete bobicu, odgovarajuća vrijednost će se promijeniti u skladu s tim:

   

Zašto je INDEX MATCH u Google tablicama bolji od VLOOKUP-a

Već znate da Google Sheets INDEX MATCH traži vašu vrijednost u tabeli i vraća drugi srodni zapis iz istogred. I znate da Google Sheets VLOOKUP radi potpuno isto. Pa zašto se mučiti?

Stvar je u tome da INDEX MATCH ima neke velike prednosti u odnosu na VLOOKUP:

1. Ljeva strana traženje je moguće . Ranije sam promijenio mjesta kolona kako bih ilustrovao ovo: funkcija INDEX MATCH u Google Sheets može i gleda lijevo od kolone za pretraživanje. VLOOKUP uvijek pretražuje prvu kolonu raspona i traži podudaranja s desne strane — inače, dobiva samo #N/A greške:

   

2. Nema zabrljano reference prilikom dodavanja novih kolona i premještanja postojećih. Ako dodate ili premjestite stupce, INDEX MATCH će automatski odražavati promjene bez miješanja u rezultat. Budući da koristite reference kolona, ​​Google Sheets ih trenutno prilagođava:

   

   Samo naprijed i pokušajte to učiniti pomoću VLOOKUP-a: zahtijeva broj narudžbe, a ne reference ćelije za kolonu za pretraživanje. Dakle, jednostavno ćete dobiti pogrešnu vrijednost jer druga kolona zauzima isto mjesto — kolona 2 u mom primjeru:

   

3. Razmatra velika i mala slova kada je potrebno (više o ovome desno ispod).
4. Može se koristiti za vertikalno traženje na osnovu više kriterija.

Pozivam vas da pogledate u posljednje dvije tačke detaljno u nastavku.

V-potraživanje osjetljivo na velika i mala slova sa INDEX MATCH u Google tablicama

INDEX MATCH je najbolji kada je u pitanju velika i mala slova-osjetljivost.

Pretpostavimo da se sve bobičasto voće prodaje na dva načina - rastresito (izvagano na tezgi) i pakirano u kutije. Dakle, postoje dva pojavljivanja svake bobice napisane u različitim slučajevima na listi, svaka sa svojim ID-om koji se također razlikuje u slučajevima:

Pa kako možete potražiti informacije o zalihama bobica koje se prodaju na određeni način? VLOOKUP će vratiti prvo ime koje pronađe bez obzira na velika i mala slova.

Srećom, INDEX MATCH za Google Sheets može to učiniti ispravno. Trebat ćete samo koristiti jednu dodatnu funkciju — FIND ili EXACT.

Primjer 1. FIND za Vlookup osjetljiv na velika i mala slova

FIND je funkcija osjetljiva na velika i mala slova u Google Sheets što je čini sjajnom za vertikalno traženje osjetljivo na velika i mala slova:

=ArrayFormula(INDEX(B2:B19, MATCH(1, FIND(E2, C2:C19)), 0))

Da vidimo šta se događa u ovoj formuli:

1. FIND skenira stupac C ( C2:C19 ) za zapis iz E2 ( trešnja ) s obzirom na velika slova. Jednom kada se pronađe, formula "označava" tu ćeliju brojem — 1 .
2. MATCH traži ovu oznaku — 1 — u istoj koloni ( C ) i predaje broj svog reda INDEX-u.
3. INDEX se spušta na taj red u koloni B ( B2:B19 ) i dohvaća vam traženi zapis.
4. Kada završite sa izradom formule, pritisnite Ctrl+Shift+Enter da dodate ArrayFormulu na početak. Potreban je jer bez njega FIND neće moći pretraživati ​​nizove (u više od jedne ćelije). Ili možete kucati' ArrayFormula ' sa vaše tastature.

Primjer 2. EXACT za Vlookup osjetljiv na velika i mala slova

Ako zamijenite FIND sa EXACT, potonji će tražiti zapise sa potpuno istim znakovima, uključujući njihova velika i mala slova.

Jedina razlika je u tome što EXACT "označava" podudaranje sa TRUE umjesto brojem 1 . Dakle, prvi argument za MATCH bi trebao biti TRUE :

=ArrayFormula(INDEX(B2:B19, MATCH(TRUE, EXACT(E2, C2:C19), 0)))

Google Sheets INDEX MATCH s više kriterija

Šta ako postoji nekoliko uslova na osnovu kojih želite da preuzmete zapisnik?

Hajde da provjerimo cijenu trešnje koja se prodaje u PP kantama i već istječe :

Sve kriterije sam posložio u padajuće liste u kolonu F. I to je Google Sheets INDEX MATCH koji podržava više kriterija, a ne VLOOKUP. Evo formule koju ćete morati koristiti:

=ArrayFormula(INDEX(B2:B24, MATCH(CONCATENATE(F2:F4), A2:A24&C2:C24&D2:D24, 0),))

Ne paničarite! :) Njegova logika je zapravo prilično jednostavna:

1. CONCATENATE(F2:F4) kombinuje sva tri zapisa iz ćelija sa kriterijumima u jedan niz ovako:

   CherryPP bucketRunning out

   Ovo je ključ_pretraživanja za MATCH, ili, drugim riječima, ono što tražite u tabeli.

2. A2:A24&C2:C24&D2:D24 čine opseg za funkciju MATCH koju treba tražiti. Pošto se sva tri kriterija odvijaju u tri odvojene kolone, na ovaj način ih kombinujete:

   CherryCardboard ladicaNa zalihama

   Pakovanje CherryFilmNema na zalihama

   CherryPP kantaIstiče

   itd .

3. Posljednji argument u MATCH — 0 — omogućava pronalaženje tačnog podudaranja za CherryPP bucketRunning out među svim tim redovima kombiniranih stupaca. Kao što vidite, nalazi se u 3. redu.
4. I onda INDEX radi svoje: preuzima zapis iz 3. reda kolone B.
5. ArrayFormula se koristi da omogući drugim funkcijama da rad s nizovima.

Savjet. Ako vaša formula ne pronađe podudaranje, vratit će grešku. Da biste to izbjegli, možete zamotati cijelu formulu u IFERROR (učinite je prvim argumentom) i unesite sve što želite da vidite u ćeliji umjesto grešaka kao drugi argument:

=IFERROR(ArrayFormula(INDEX(B2:B27, MATCH(CONCATENATE(F2:F4), A2:A27&C2:C27&D2:D27, 0),)), "Not found")

Bolja alternativa INDEX MATCH u Google tablicama — višestruka podudaranja VLOOKUP

Koju god funkciju pretraživanja želite, VLOOKUP ili INDEX MATCH, postoji bolja alternativa za oboje.

Višestruko VLOOKUP Matches je poseban dodatak za Google tablice dizajniran da:

• traži bez formula
• pretražuje u svim smjerovima
• pretražuje po više uslova za različite tipove podataka : tekst, brojevi, datumi, vrijeme, itd.
• dohvatite nekoliko podudaranja, koliko vam je potrebno (naravno, pod uvjetom da ih ima u vašoj tablici toliko)

Sučelje je jednostavno, tako da nećete morati sumnjati da li raditesve ispravno:

1. Odaberite izvorni raspon.
2. Postavite broj podudaranja i stupaca za povratak.
3. Fino podesite uslove koristeći unaprijed definirane operatore ( sadrži, =, nije prazno , između , itd.).

Moći ćete i:

• pregledajte rezultat
• odlučite gdje ćete ga postaviti
• i kako: kao formulu ili samo vrijednosti

Ne propustite ovu priliku da provjerite dodatak. Samo naprijed i instalirajte ga sa Google Workspace Marketplacea. Njegova stranica sa vodičem će detaljno objasniti svaku opciju.

Pripremili smo i poseban video s uputama:

Vidimo se u komentarima ispod ili u sljedećem članku ;)