In diesem Tutorial werden wir etwas Licht in einen der geheimnisvollsten Bewohner des Excel-Universums bringen - die OFFSET-Funktion.

Was bedeutet OFFSET in Excel? Kurz gesagt gibt die OFFSET-Formel einen Verweis auf einen Bereich zurück, der von einer Startzelle oder einem Zellbereich um eine bestimmte Anzahl von Zeilen und Spalten versetzt ist.

Die Funktion OFFSET ist vielleicht ein wenig kompliziert zu verstehen, also lassen Sie uns zunächst eine kurze technische Erklärung geben (ich werde mein Bestes tun, um es einfach zu halten), und dann werden wir einige der effizientesten Möglichkeiten zur Verwendung von OFFSET in Excel behandeln.

Excel OFFSET-Funktion - Syntax und grundlegende Anwendungen

Die Funktion OFFSET in Excel gibt eine Zelle oder einen Bereich von Zellen zurück, die bzw. der eine bestimmte Anzahl von Zeilen und Spalten von einer bestimmten Zelle oder einem bestimmten Bereich entfernt ist.

Die Syntax der OFFSET-Funktion lautet wie folgt:

Die ersten 3 Argumente sind obligatorisch, die letzten 2 sind optional. Alle Argumente können Verweise auf andere Zellen oder Ergebnisse sein, die von anderen Formeln zurückgegeben werden.

Es sieht so aus, als hätte sich Microsoft bemüht, den Namen der Parameter eine gewisse Bedeutung zu verleihen, und sie geben einen Hinweis darauf, was Sie in jedem einzelnen Parameter angeben sollen.

Erforderliche Argumente:

• Referenz - eine Zelle oder einen Bereich benachbarter Zellen, von der/dem aus Sie den Offset berechnen, sozusagen als Startpunkt.
• Zeilen - Die Anzahl der Zeilen, die vom Startpunkt aus nach oben oder unten verschoben werden sollen. Ist rows eine positive Zahl, bewegt sich die Formel unterhalb der Startreferenz, bei einer negativen Zahl geht sie über die Startreferenz hinaus.
• Die Spalten - Die Anzahl der Spalten, die die Formel vom Startpunkt aus verschieben soll. Neben Zeilen können auch Spalten positiv (rechts vom Startbezug) oder negativ (links vom Startbezug) sein.

Optionale Argumente:

• Höhe - die Anzahl der zurückzugebenden Zeilen.
• Breite - die Anzahl der zurückzugebenden Spalten.

Die beiden Argumente Höhe und Breite müssen immer positive Zahlen sein. Wird eines der beiden weggelassen, wird standardmäßig die Höhe oder Breite von Referenz .

Hinweis: OFFSET ist eine flüchtige Funktion und kann Ihr Arbeitsblatt verlangsamen. Die Verlangsamung ist direkt proportional zur Anzahl der neu berechneten Zellen.

Und nun wollen wir die Theorie mit einem Beispiel für die einfachste OFFSET-Formel veranschaulichen.

Excel OFFSET-Formel Beispiel

Hier ein Beispiel für eine einfache OFFSET-Formel, die einen Zellbezug auf der Grundlage eines Startpunkts, von Zeilen und Spalten, die Sie angeben, zurückgibt:

=OFFSET(A1,3,1)

Die Formel weist Excel an, die Zelle A1 als Ausgangspunkt (Referenz) zu nehmen, dann 3 Zeilen nach unten (Argument rows) und 1 Spalte nach links (Argument cols) zu verschieben. Als Ergebnis liefert diese OFFSET-Formel den Wert in Zelle B4.

Die linke Abbildung zeigt den Weg der Funktion und der rechte Screenshot demonstriert, wie Sie die OFFSET-Formel auf reale Daten anwenden können. Der einzige Unterschied zwischen den beiden Formeln besteht darin, dass die zweite Formel (rechts) einen Zellbezug (E1) im Argument rows enthält. Da die Zelle E1 aber die Zahl 3 enthält, erscheint genau dieselbe Zahl im Argument rows der ersten Formel,würden beide ein identisches Ergebnis liefern - den Wert in B4.

Excel OFFSET-Formeln - was zu beachten ist

• Die Funktion OFFSET in Excel verschiebt keine Zellen oder Bereiche, sondern gibt nur einen Verweis zurück.
• Wenn eine OFFSET-Formel einen Bereich von Zellen zurückgibt, beziehen sich die Argumente rows und cols immer auf die obere linke Zelle im zurückgegebenen Bereich.
• Das Referenzargument muss eine Zelle oder einen Bereich von benachbarten Zellen enthalten, andernfalls gibt Ihre Formel den Fehler #VALUE! zurück.
• Wenn die angegebenen Zeilen und/oder Spalten eine Referenz über den Rand des Arbeitsblatts hinaus verschieben, gibt Ihre Excel OFFSET-Formel den Fehler #REF! zurück.
• Die Funktion OFFSET kann in jeder anderen Excel-Funktion verwendet werden, die einen Zell-/Bereichsbezug in ihren Argumenten akzeptiert.

Wenn Sie zum Beispiel versuchen, die folgende Formel zu verwenden =OFFSET(A1,3,1,1,3) für sich genommen einen #VALUE!-Fehler, da der zurückzugebende Bereich (1 Zeile, 3 Spalten) nicht in eine einzige Zelle passt. Wenn Sie ihn jedoch in die Funktion SUMME einbetten, etwa so:

=SUM(OFFSET(A1,3,1,1,3))

Die Formel gibt die Summe der Werte in einem einzeiligen und dreispaltigen Bereich zurück, der sich drei Zeilen unterhalb und eine Spalte rechts von Zelle A1 befindet, d. h. die Summe der Werte in den Zellen B4:D4.

Warum verwende ich OFFSET in Excel?

Da Sie nun wissen, was die Funktion OFFSET bewirkt, fragen Sie sich vielleicht: "Warum sollte ich sie benutzen?" Warum nicht einfach eine direkte Referenz wie B4:D4 schreiben?

Die Excel-Formel OFFSET ist sehr gut geeignet für:

Erstellen von Dynamikbereichen Referenzen wie B1:C4 sind statisch, d.h. sie beziehen sich immer auf einen bestimmten Bereich. Manche Aufgaben lassen sich jedoch leichter mit dynamischen Bereichen durchführen. Dies ist insbesondere dann der Fall, wenn Sie mit sich ändernden Daten arbeiten, z.B. wenn Sie ein Arbeitsblatt haben, bei dem jede Woche eine neue Zeile oder Spalte hinzugefügt wird.

Ermittlung des Bereichs ab der Startzelle Manchmal kennen Sie die tatsächliche Adresse des Bereichs nicht, aber Sie wissen, dass er mit einer bestimmten Zelle beginnt. In solchen Fällen ist die Verwendung von OFFSET in Excel die richtige Vorgehensweise.

Wie verwendet man die Funktion OFFSET in Excel - Formelbeispiele

Ich hoffe, Sie haben sich mit so viel Theorie nicht gelangweilt. Wie auch immer, jetzt kommen wir zum spannendsten Teil - der praktischen Anwendung der OFFSET-Funktion.

Excel-Funktionen OFFSET und SUMME

Das soeben besprochene Beispiel zeigt die einfachste Anwendung von OFFSET & SUM. Betrachten wir diese Funktionen nun aus einem anderen Blickwinkel und sehen wir uns an, was sie sonst noch tun können.

Beispiel 1: Eine dynamische SUMME / OFFSET-Formel

Wenn Sie mit ständig aktualisierten Arbeitsblättern arbeiten, möchten Sie vielleicht eine SUMMEN-Formel haben, die automatisch alle neu hinzugefügten Zeilen auswählt.

Nehmen wir an, Sie haben Quelldaten, die dem Screenshot unten ähneln. Jeden Monat wird eine neue Zeile direkt über der SUMME-Formel hinzugefügt, und natürlich möchten Sie diese in die Gesamtsumme einbeziehen. Im Großen und Ganzen gibt es zwei Möglichkeiten - entweder Sie aktualisieren den Bereich in der SUMME-Formel jedes Mal manuell oder Sie lassen die OFFSET-Formel dies für Sie erledigen.

Da die erste Zelle des zu summierenden Bereichs direkt in der SUMMEN-Formel angegeben wird, müssen Sie nur noch die Parameter für die Excel-Funktion OFFSET festlegen, die die letzte Zelle des Bereichs ermittelt:

• Referenz - die Zelle, die die Summe enthält, in unserem Fall B9.
• Zeilen - die Zelle direkt über der Summe, die die negative Zahl -1 erfordert.
• Die Spalten - Es ist 0, weil Sie die Spalte nicht ändern wollen.

Hier also das Muster der SUMME / OFFSET-Formel:

Für das obige Beispiel sieht die Formel wie folgt aus:

=SUM(B2:(OFFSET(B9, -1, 0)))

Und wie der unten stehende Screenshot zeigt, funktioniert es einwandfrei:

Beispiel 2: Excel OFFSET-Formel für die Summe der letzten N Zeilen

Im obigen Beispiel wollen Sie nicht die Gesamtsumme, sondern den Betrag der Boni für die letzten N Monate wissen. Sie möchten auch, dass die Formel automatisch alle neuen Zeilen einbezieht, die Sie dem Blatt hinzufügen.

Für diese Aufgabe werden wir Excel OFFSET in Kombination mit den Funktionen SUM und COUNT / COUNTA verwenden:

=SUM(OFFSET(B1,COUNT(B:B)-E1+1,0,E1,1))

oder

=SUM(OFFSET(B1,COUNTA(B:B)-E1,0,E1,1))

Die folgenden Angaben können Ihnen helfen, die Formeln besser zu verstehen:

• Referenz - die Überschrift der Spalte, deren Werte Sie summieren möchten, in diesem Beispiel die Zelle B1.
• Zeilen - um die Anzahl der zu verschiebenden Zeilen zu berechnen, verwenden Sie entweder die Funktion COUNT oder COUNTA.

  COUNT gibt die Anzahl der Zellen in Spalte B zurück, die Zahlen enthalten, von denen Sie die letzten N Monate subtrahieren (die Zahl ist Zelle E1) und 1 addieren.

  Wenn COUNTA die Funktion Ihrer Wahl ist, brauchen Sie keine 1 hinzuzufügen, da diese Funktion alle nicht leeren Zellen zählt und eine Kopfzeile mit einem Textwert eine zusätzliche Zelle hinzufügt, die unsere Formel benötigt. Bitte beachten Sie, dass diese Formel nur bei einer ähnlichen Tabellenstruktur korrekt funktioniert - eine Kopfzeile gefolgt von Zeilen mit Zahlen. Bei anderen Tabellenlayouts müssen Sie möglicherweise einige Anpassungen in derOFFSET/COUNTA-Formel.

• Die Spalten - die Anzahl der zu verschiebenden Spalten ist Null (0).
• Höhe - die Anzahl der zu summierenden Zeilen wird in E1 angegeben.
• Breite - 1 Spalte.

Verwendung der Funktion OFFSET mit AVERAGE, MAX, MIN

Auf die gleiche Weise, wie wir die Boni für die letzten N Monate berechnet haben, können Sie den Durchschnitt der letzten N Tage, Wochen oder Jahre ermitteln und deren Höchst- oder Mindestwerte bestimmen. Der einzige Unterschied zwischen den Formeln ist der Name der ersten Funktion:

=DURCHSCHNITT(OFFSET(B1,COUNT(B:B)-E1+1,0,E1,1))

=MAX(OFFSET(B1,COUNT(B:B)-E1+1,0,E1,1))

=MIN(OFFSET(B1,COUNT(B:B)-E1+1,0,E1,1))

Der Hauptvorteil dieser Formeln gegenüber den üblichen AVERAGE(B5:B8) oder MAX(B5:B8) besteht darin, dass Sie die Formel nicht jedes Mal aktualisieren müssen, wenn Ihre Quelltabelle aktualisiert wird. Unabhängig davon, wie viele neue Zeilen in Ihrem Arbeitsblatt hinzugefügt oder gelöscht werden, beziehen sich die OFFSET-Formeln immer auf die angegebene Anzahl der letzten (untersten) Zellen in der Spalte.

Excel OFFSET-Formel zum Erstellen eines dynamischen Bereichs

In Verbindung mit COUNTA kann die Funktion OFFSET Ihnen helfen, einen dynamischen Bereich zu erstellen, der sich in vielen Szenarien als nützlich erweisen kann, zum Beispiel bei der Erstellung automatisch aktualisierbarer Dropdown-Listen.

Die OFFSET-Formel für einen Dynamikbereich lautet wie folgt:

=OFFSET(Blatt_Name!$A$1, 0, 0, COUNTA(Blatt_Name!$A:$A), 1)

Im Kern dieser Formel verwenden Sie die Funktion COUNTA, um die Anzahl der nicht leeren Zellen in der Zielspalte zu ermitteln. Diese Zahl geht in das Höhenargument von OFFSET ein und gibt an, wie viele Zeilen zurückgegeben werden sollen.

Abgesehen davon ist es eine normale Offset-Formel, bei der:

• Referenz ist der Ausgangspunkt, von dem aus Sie den Versatz berechnen, z. B. Sheet1!$A$1.
• Zeilen und Die Spalten sind beide 0, weil es keine zu versetzenden Spalten oder Zeilen gibt.
• Breite ist 1 Spalte.

Hinweis: Wenn Sie einen dynamischen Bereich im aktuellen Blatt erstellen, müssen Sie den Blattnamen nicht in die Verweise aufnehmen, da Excel dies beim Erstellen des benannten Bereichs automatisch tut. Andernfalls müssen Sie den Blattnamen gefolgt von einem Ausrufezeichen angeben, wie in diesem Formelbeispiel.

Sobald Sie einen dynamischen benannten Bereich mit der obigen OFFSET-Formel erstellt haben, können Sie die Datenüberprüfung verwenden, um eine dynamische Dropdown-Liste zu erstellen, die automatisch aktualisiert wird, sobald Sie Elemente aus der Ausgangsliste hinzufügen oder entfernen.

Eine detaillierte Schritt-für-Schritt-Anleitung zum Erstellen von Dropdown-Listen in Excel finden Sie in den folgenden Tutorials:

• Erstellen von Dropdown-Listen in Excel - statisch, dynamisch, aus einer anderen Arbeitsmappe
• Erstellen einer abhängigen Dropdown-Liste

Excel OFFSET & VLOOKUP

Wie jeder weiß, werden einfache vertikale und horizontale Lookups mit der VLOOKUP- bzw. HLOOKUP-Funktion durchgeführt. Diese Funktionen haben jedoch zu viele Einschränkungen und stoßen bei leistungsfähigeren und komplexeren Lookup-Formeln oft an ihre Grenzen. Wenn Sie also anspruchsvollere Lookups in Ihren Excel-Tabellen durchführen möchten, müssen Sie nach Alternativen wie INDEX, MATCH und OFFSET suchen.

Beispiel 1: OFFSET-Formel für ein linkes Vlookup in Excel

Eine der berüchtigtsten Einschränkungen der VLOOKUP-Funktion ist die Unfähigkeit, auf der linken Seite zu suchen, was bedeutet, dass VLOOKUP nur einen Wert rechts von der Suchspalte zurückgeben kann.

In unserer Beispieltabelle gibt es zwei Spalten - Monatsnamen (Spalte A) und Prämien (Spalte B). Wenn Sie eine Prämie für einen bestimmten Monat erhalten möchten, funktioniert diese einfache VLOOKUP-Formel problemlos:

=VLOOKUP(B1, A5:B11, 2, FALSE)

Sobald Sie jedoch die Spalten in der Lookup-Tabelle vertauschen, führt dies sofort zu dem Fehler #N/A:

Für eine linksseitige Suche benötigen Sie eine vielseitigere Funktion, die sich nicht darum kümmert, wo sich die Rückgabespalte befindet. Eine der möglichen Lösungen ist die Verwendung einer Kombination aus INDEX- und MATCH-Funktionen. Ein anderer Ansatz ist die Verwendung von OFFSET, MATCH und ROWS:

Wo:

• Lookup_col_offset - ist die Anzahl der zu verschiebenden Spalten vom Startpunkt bis zur Nachschlagspalte.
• Rückgabe_col_offset - ist die Anzahl der zu verschiebenden Spalten vom Startpunkt bis zur Rückgabespalte.

In unserem Beispiel ist die Nachschlagetabelle A5:B9 und der Nachschlagewert befindet sich in Zelle B1, der Nachschlage-Spalten-Offset ist 1 (weil wir nach dem Nachschlagewert in der zweiten Spalte (B) suchen, müssen wir 1 Spalte nach rechts vom Anfang der Tabelle verschieben), der Rückgabe-Spalten-Offset ist 0, weil wir Werte aus der ersten Spalte (A) zurückgeben:

=OFFSET(A5:B9, MATCH(B1, OFFSET(A5:B9, 0, 1, ROWS(A5:B9), 1) ,0) -1, 0, 1, 1)

Ich weiß, die Formel sieht ein bisschen unbeholfen aus, aber sie funktioniert :)

Beispiel 2: Wie man eine obere Suche in Excel durchführt

So wie VLOOKUP nicht nach links schauen kann, kann auch sein horizontales Gegenstück - die Funktion HLOOKUP - nicht nach oben schauen, um einen Wert zurückzugeben.

Wenn Sie eine obere Zeile nach Übereinstimmungen durchsuchen müssen, kann die Formel OFFSET MATCH wieder helfen, aber dieses Mal müssen Sie sie mit der Funktion COLUMNS erweitern, wie hier:

Wo:

• Lookup_row_offset - die Anzahl der Zeilen, die vom Startpunkt bis zur Nachschlagezeile verschoben werden sollen.
• Rückgabe_Zeilenversatz - die Anzahl der Zeilen, die vom Startpunkt bis zur Rückgabezeile verschoben werden sollen.

Angenommen, die Nachschlagetabelle lautet B4:F5 und der Nachschlagewert befindet sich in Zelle B1, dann sieht die Formel wie folgt aus:

=OFFSET(B4:F5, 0, MATCH(B1, OFFSET(B4:F5, 1, 0, 1, COLUMNS(B4:F5)), 0) -1, 1, 1)

In unserem Fall ist der Suchzeilenversatz 1, weil unser Suchbereich 1 Zeile unterhalb des Startpunkts liegt, der Rückgabezeilenversatz ist 0, weil wir Übereinstimmungen aus der ersten Zeile der Tabelle zurückgeben.

Beispiel 3: Zwei-Wege-Suche (nach Spalten- und Zeilenwerten)

Die Zwei-Wege-Suche gibt einen Wert zurück, der auf Übereinstimmungen in den Zeilen und Spalten basiert. Sie können die folgende Formel für die Zwei-Wege-Suche verwenden, um einen Wert an der Schnittstelle einer bestimmten Zeile und Spalte zu finden:

Angesichts dessen:

• Die Nachschlagetabelle lautet A5:G9
• Der Wert, der in den Zeilen übereinstimmen soll, steht in B2
• Der Wert, der in den Spalten übereinstimmen muss, steht in B1

Sie erhalten die folgende zweidimensionale Lookup-Formel:

=OFFSET(A5:G9, MATCH(B2, OFFSET(A5:G9, 0, 0, ROWS(A5:G9), 1), 0)-1, MATCH(B1, OFFSET(A5:G9, 0, 0, 1, COLUMNS(A5:G9)), 0) -1)

Außerdem handelt es sich um eine Array-Formel, also vergessen Sie nicht, Strg + Shift + Enter zu drücken, um sie korrekt einzugeben.

Natürlich ist diese langwierige OFFSET-Formel nicht die einzige Möglichkeit, eine doppelte Suche in Excel durchzuführen. Sie können das gleiche Ergebnis mit den Funktionen VLOOKUP & MATCH, SUMPRODUCT oder INDEX & MATCH erzielen. Es gibt sogar einen formelfreien Weg - die Verwendung von benannten Bereichen und dem Schnittpunkt-Operator (Leerzeichen). Das folgende Tutorial erklärt alle alternativen Lösungen in allen Einzelheiten: How to do two-wayNachschlagen in Excel.

OFFSET-Funktion - Einschränkungen und Alternativen

Wir hoffen, dass die Formelbeispiele auf dieser Seite etwas Licht in die Verwendung von OFFSET in Excel gebracht haben. Um die Funktion jedoch effizient in Ihren eigenen Arbeitsmappen einsetzen zu können, sollten Sie nicht nur die Stärken der Funktion kennen, sondern sich auch vor ihren Schwächen in Acht nehmen.

Die wichtigsten Einschränkungen der Excel-Funktion OFFSET sind die folgenden:

• Wie andere flüchtige Funktionen ist auch OFFSET eine ressourcenintensive Funktion Bei jeder Änderung der Quelldaten werden Ihre OFFSET-Formeln neu berechnet, wodurch Excel etwas länger beschäftigt ist. Bei einer einzelnen Formel in einem kleinen Arbeitsblatt ist dies kein Problem, aber bei Dutzenden oder Hunderten von Formeln in einer Arbeitsmappe kann die Neuberechnung durch Microsoft Excel eine ganze Weile dauern.
• Excel OFFSET-Formeln sind schwer zu überprüfen Da die von der OFFSET-Funktion zurückgegebenen Referenzen dynamisch sind, kann die Fehlersuche bei großen Formeln (insbesondere bei verschachtelten OFFSETs) recht schwierig sein.

Alternativen zur Verwendung von OFFSET in Excel

Wie so oft in Excel kann das gleiche Ergebnis auf verschiedene Weise erreicht werden. Hier also drei elegante Alternativen zu OFFSET.

1. Excel-Tabellen

   Seit Excel 2002 haben wir eine wirklich wunderbare Funktion - vollwertige Excel-Tabellen, im Gegensatz zu den üblichen Bereichen. Um eine Tabelle aus strukturierten Daten zu erstellen, klicken Sie einfach auf Einfügen> Tabelle über die Startseite oder drücken Sie die Tastenkombination Strg + T .

   Wenn Sie eine Formel in eine Zelle einer Excel-Tabelle eingeben, können Sie eine so genannte "berechnete Spalte" erstellen, die die Formel automatisch in alle anderen Zellen dieser Spalte kopiert und die Formel für jede Zeile der Tabelle anpasst.

   Darüber hinaus passt sich jede Formel, die sich auf die Daten einer Tabelle bezieht, automatisch an alle neuen Zeilen an, die Sie der Tabelle hinzufügen, oder schließt die Zeilen aus, die Sie löschen. Dynamikbereiche Jede Tabelle in einer Arbeitsmappe hat einen eindeutigen Namen (die Standardnamen sind Tabelle1, Tabelle2 usw.), und es steht Ihnen frei, Ihre Tabelle mit dem Befehl Gestaltung tab> Eigenschaften Gruppe> Tabelle Name Textfeld.

   Der folgende Screenshot zeigt die SUMmenformel, die sich auf die Bonus Bitte beachten Sie, dass die Formel den Wert der Tabelle enthält. Spaltenname und nicht einen Bereich von Zellen.

   

2. Excel-Funktion INDEX

   Im Gegensatz zu OFFSET ist die INDEX-Funktion nicht flüchtig und verlangsamt Ihr Excel daher nicht.

3. Excel-Funktion INDIRECT

   Mit der Funktion INDIRECT können Sie dynamische Bereichsreferenzen aus vielen Quellen erstellen, wie z.B. Zellwerte, Zellwerte und Text, benannte Bereiche. Sie kann auch dynamisch auf ein anderes Excel-Blatt oder eine Arbeitsmappe verweisen. Sie finden alle diese Formelbeispiele in unserem Excel-Tutorial zur Funktion INDIRECT.

Erinnern Sie sich an die Frage, die zu Beginn dieses Tutorials gestellt wurde? Was bedeutet OFFSET in Excel? Ich hoffe, Sie kennen jetzt die Antwort : ) Wenn Sie noch mehr praktische Erfahrungen sammeln möchten, können Sie unser Übungsheft (siehe unten) herunterladen, das alle auf dieser Seite besprochenen Formeln enthält, und sie für ein tieferes Verständnis nachbauen. Danke fürs Lesen!

Übungsheft zum Herunterladen

Beispiele für OFFSET-Formeln (.xlsx-Datei)