Калі адзіны спосаб стварэння фільтра ў Табліцах Google - гэта стандартны інструмент, у мяне ёсць для вас сюрпрыз. :) Прыходзьце даследаваць функцыю FILTER са мной. Ёсць шмат гатовых формул, якія вы можаце пазычыць, а таксама новы магутны інструмент, які значна дапаўняе набор інструментаў фільтрацыі.

Некаторы час таму мы тлумачылі, як фільтраваць у Табліцах Google з дапамогай стандартнага інструмента. Мы згадвалі, як фільтраваць па значэнні і па ўмове. Аднак у электронных табліцах заўсёды больш, чым мы ведаем. І на гэты раз я збіраюся вывучыць з вамі функцыю Google Sheets FILTER.

Вы не знойдзеце яе ў Excel, таму яе, безумоўна, варта праверыць.

Сінтаксіс функцыі Google Sheets FILTER

FILTER у Google Sheets скануе вашы даныя і вяртае неабходную інфармацыю, якая адпавядае вашым крытэрыям.

У адрозненне ад стандартнага фільтра Google Sheets, гэтая функцыя не рабіць што-небудзь з вашымі зыходнымі дадзенымі. Ён капіруе знойдзеныя радкі і змяшчае іх усюды, дзе вы будуеце формулу.

Сінтаксіс даволі просты, бо кожны аргумент гаворыць сам за сябе:

=ФІЛЬТР(дыяпазон, умова1, [умова2, ...])

• дыяпазон - гэта даныя, якія вы хочаце адфільтраваць. Абавязкова.
• умова1 - гэта слупок або радок разам з крытэрыямі ПРАЎДА/ХЛУСНЯ, якім яны павінны падпадаць. Абавязковы.
• умова2,... і г.д., азначаюць іншыя слупкі/радкі і/ці іншыя крытэрыі. Неабавязкова.

Заўвага. Кожны умова павінна быць такога ж памеру, што і дыяпазон .

Заўвага. Калі вы выкарыстоўваеце некалькі ўмоў, усе яны павінны быць альбо для слупкоў, альбо для радкоў. Функцыя Google Sheets FILTER не дазваляе змешаныя ўмовы.

Зараз, маючы на ​​ўвазе гэтыя заўвагі, давайце паглядзім, як аргументы прымаюць форму розных формул.

Як выкарыстоўваць функцыю FILTER у Табліцах Google

Я збіраюся паказаць вам усё прыклады падчас фільтрацыі невялікай табліцы, дзе я адсочваю некаторыя заказы:

Табліца змяшчае 20 радкоў з рознымі тыпамі даных, што ідэальна падыходзіць для вывучэння функцыі.

Як фільтраваць у Табліцах Google па тэксце

Прыклад 1. Тэкст дакладны

Спачатку я папрашу функцыю паказваць толькі тыя заказы, якія выконваюцца са спазненнем. Я ўводжу дыяпазон для фільтрацыі — A1:E20 — а потым задаю ўмову — слупок E павінен раўняцца Late :

=FILTER(A1:E20,E1:E20="Late")

Прыклад 2. Тэкст зусім не

Я магу папрасіць функцыю атрымаць усе заказы, акрамя тых, якія са спазненнем. Для гэтага мне спатрэбіцца спецыяльны аператар параўнання (), які азначае не роўна :

=FILTER(A1:E20,E1:E20"Late")

Прыклад 3. Тэкст змяшчае

Зараз я хацеў бы паказаць вам, як стварыць функцыю FILTER Google Sheets на аснове частковага супадзення. Ці іншымі словамі — калі тэкст утрымлівае .

Ці заўважылі вы, што ідэнтыфікатары заказаў у слупку A ўтрымліваюць у канцы абрэвіятуры краіны? Давайце створым формулу толькі для атрыманнязаказы, якія былі дастаўлены з Канады ( CA ).

Звычайна для гэтай задачы вы выкарыстоўваеце сімвалы падстаноўкі. Але калі справа даходзіць да формулы ФІЛЬТРА, такім чынам працуюць функцыі ПОШУК і ПОШУК.

Парада. Калі вы аддаеце перавагу пазбягаць укладання іншых функцый пры фільтрацыі па простых словах, не саромейцеся паспрабаваць дапаўненне, апісанае ў канцы.

Заўвага. Калі важны рэгістр тэксту, выкарыстоўвайце ЗНАЙСІЦЬ, у адваротным выпадку абярыце ПОШУК.

Функцыя SEARCH выдатна падыдзе для майго прыкладу, паколькі рэгістр тэксту не мае значэння:

=SEARCH(search_for, text_to_search, [starting_at])

• search_for гэта тэкст Я хачу знайсці. Вельмі важна заключыць яго ў двукоссі: "ca" . Абавязкова.
• text_to_search гэта дыяпазон для пошуку патрэбнага тэксту. абавязковы. Для мяне гэта A1:A20 .
• starting_at паказвае пачатковую пазіцыю для пошуку — нумар сімвала, з якога трэба пачаць пошук. Гэта зусім неабавязкова, але мне трэба яго выкарыстоўваць. Разумееце, усе ідэнтыфікатары заказаў складаюцца з літар і лічбаў, што азначае, што пара CA можа знаходзіцца дзесьці паміж імі. Ідэнтычны шаблон усіх ідэнтыфікатараў дазваляе мне шукаць CA , пачынаючы з 8-га сімвала.

Пасля збору ўсіх гэтых частак разам я атрымліваю жаданы вынік:

=FILTER(A1:E20,SEARCH("ca",A1:A20,8))

Як фільтраваць па даце і часе ў Табліцах Google

Фільтрацыя па даце і часе таксама патрабуе выкарыстаннядадатковыя функцыі. У залежнасці ад вашых крытэрыяў вам можа спатрэбіцца ўбудаваць ДЗЕНЬ, МЕСЯЦ, ГОД ці нават ДАТУ і ЧАС у галоўную функцыю ФІЛЬТРА Табліц Google.

Парада. Калі вы не знаёмыя з гэтымі ці заўсёды блытаеце рэчы з датамі - не хвалюйцеся. Інструмент, апісаны ў канцы, не патрабуе ніякіх функцый.

Прыклад 1. Дата:

Каб атрымаць тыя заказы, якія павінны быць выкананы 9 студзеня 2020 г., я запрашу функцыю ДАТА:

=FILTER(A1:E20,C1:C20=DATE(2020,1,9))

Заўвага. Гэта працуе, толькі калі вашы ячэйкі не ўтрымліваюць адзінак часу разам з датай (электронная табліца можа дадаць іх па змаўчанні). Каб пераканацца ў гэтым, проста выберыце ячэйку і праверце, што з'явіцца ў радку формул:

Калі час ёсць і выдаліць яго нельга, вы павінны выкарыстоўваць альбо QUERY або больш складаная ўмова ў вашай функцыі FILTER Google Sheets, напрыклад:

=FILTER(A1:E20,C1:C20>=DATE(2020,1,9),C1:C20

Падказка. Ніжэй я распавяду пра некалькі ўмоў больш падрабязна.

Прыклад 2. Дата змяшчае

Калі вас цікавіць толькі пэўны месяц ці год, вы можаце абысціся функцыямі MONTH і YEAR. Змесціце дыяпазон з датамі прама ў яго ( C1:C20 ) і ўкажыце нумар месяца (ці года), якому ён павінен быць роўны ( =1 ):

=FILTER(A1:E20,MONTH(C1:C20)=1)

Прыклад 3. Дата да/пасля

Каб атрымаць даныя да або пасля ўказанай даты, вам спатрэбіцца ДАТА функцыя і такія аператары параўнання, як большчым (>), больш або роўна (>=), менш (<), менш або роўна (<=).

Вось заказы, якія былі атрыманы і пасля 1 студзеня 2020 г.:

=FILTER(A1:E20,D1:D20>=DATE(2020,1,1))

Вядома, тут можна лёгка замяніць ДАТУ на МЕСЯЦ або ГОД. Вынік не будзе адрознівацца ад прыведзенага вышэй:

=FILTER(A1:E20,YEAR(D1:D20)>=2020)

Прыклад 4. Час

Пры фільтрацыі ў Табліцах Google па часе праца сапраўды такая ж, як і з даты. Вы выкарыстоўваеце дадатковую функцыю ЧАС.

Напрыклад, каб атрымаць толькі дні з пазнакай часу пасля 14:00, формула будзе наступнай:

=FILTER(A1:B10,A1:A10>TIME(14,0,0))

Аднак, калі справа даходзіць да выкарыстання функцыі ГАДЗІНА (як і МЕСЯЦ для дат), гульня крыху мяняецца. Час досыць складаны ў электронных табліцах, таму неабходныя некаторыя карэкціроўкі.

Каб вярнуць усе радкі з пазнакамі часу паміж 14:00 і 12:00 , зрабіце гэта:

1. Уключыце дыяпазон з пазнакамі часу ( A1:A10 ) у асобную функцыю ГАДЗІНА. Гэта пакажа, дзе шукаць.
2. Затым дадайце іншую функцыю ГАДЗІНА, каб усталяваць час.

=FILTER(A1:B10,HOUR(A1:A10)>=HOUR("2:00:00 PM"))

Парада . Бачыце, што вынік не ўключае 12:41 ? Гэта таму, што электронная табліца разглядае гэта як 00:41 , што менш за 2:00 .

Калі вы знойдзеце больш элегантнае рашэнне, падзяліцеся ім у раздзеле каментарыяў ніжэй.

Як фільтраваць у Табліцах Google з дапамогай спасылак на ячэйкі

Кожны раз, калі вы ствараеце фільтр Табліц Googleформулу, вам трэба ўвесці ўмову як ёсць: слова ці яго частку, дату і г.д. Калі вы не знаёмыя са спасылкамі на ячэйкі.

Яны палягчаюць шмат рэчаў у формулах. Таму што замест таго, каб уводзіць усё, вы можаце проста спасылацца на ячэйкі з умовамі.

Памятаеце, як я шукаў усе заказы са спазненнем? Я магу хутка звярнуцца да E4 з тэкстам Позні , каб зрабіць тое ж самае:

=FILTER(A1:E20,E1:E20=E4)

Вынік зусім не будзе адрознівацца:

Вы можаце паўтарыць гэта з усімі вышэйзгаданымі формуламі. Напрыклад, пазбягайце дадання іншых функцый, такіх як ДАТА, і проста спасылайцеся на ячэйку з цікавай датай:

=FILTER(A1:E20,C1:C20=C15)

Савет. Спасылкі на ячэйкі таксама дазваляюць фільтраваць з іншага аркуша. Вам проста трэба ўвесці назву аркуша:

=FILTER(Orders!A1:E20,Orders!C1:C20=Orders!C15)

ФІЛЬТРАЦІЯ формул Google Табліц з некалькімі крытэрыямі

Хоць раней я ў асноўным выкарыстоўваў адну ўмову ва ўсіх формулах фільтра Google Табліц, гэта больш верагодна што вам трэба будзе адфільтраваць табліцу па некалькіх умовах адначасова.

Прыклад 1. логіка IS BETWEEN

Каб знайсці ўсе радкі, якія знаходзяцца паміж дзвюма лічбамі/датамі/часамі, неабавязковы аргументы функцыі спатрэбяцца — умова2 , умова3 і г.д. Вы проста дублюеце адзін і той жа дыяпазон кожны раз, але з новай умовай.

Глядзіце, я Я збіраюся вярнуць толькі тыя заказы, якія каштуюць мне больш за 250 долараў, але менш за 350 долараў:

=FILTER(A1:E20,B1:B20>=250,B1:B20<350)

Прыклад 2. Логіка АБО ўФункцыя Google Sheets FILTER

На жаль, каб атрымаць усе радкі, якія змяшчаюць розныя запісы ў цікавым слупку, папярэдні спосаб не падыдзе. Такім чынам, як я магу праверыць усе заказы, якія ў дарозе і са спазненнем?

Калі я паспрабую папярэдні метад і ўвяду статус кожнага заказу ў асобную ўмову, я атрымаю памылку #N/A:

Такім чынам, каб правільна ўсталяваць логіку АБО ў функцыі FILTER, я павінен сумаваць гэтыя два крытэрыі ў адной умове:

=FILTER(A1:E20,(E1:E20="Late")+(E1:E20="On the way"))

Дадайце фільтр у Google Sheets для некалькіх слупкоў

Што нават больш верагодна, чым прымяненне некалькіх умоў да аднаго слупка, так гэта стварэнне фільтра ў Google Sheets для некалькіх слупкоў.

Аргументы аднолькавыя. Але кожная новая частка формулы патрабуе новага дыяпазону з уласнымі крытэрамі.

Давайце паспрабуем зрабіць так, каб функцыя FILTER у Табліцах Google вяртала заказы, якія падпадаюць пад усе наступныя правілы:

1. Яны павінны каштаваць 200-400 долараў:

   A1:E20,B1:B20>=200,B1:B20<=400

2. Трэба падаць у студзені 2020 г.:

   MONTH(C1:C20)=1

3. І ўсё яшчэ ў дарозе:

   E1:E20="on the way"

Збярыце ўсе гэтыя часткі разам, і ваша формула фільтра Табліц Google для некалькіх слупкоў гатовая:

=FILTER(A1:E20,B1:B20>=200,B1:B20<=400,MONTH(C1:C20)=1,E1:E20="on the way")

Спосаб без формул для пашыранага фільтра Табліц Google

Функцыя FILTER выдатная і ўсё, але часам можа быць занадта шмат. Адсочванне ўсіх аргументаў, раздзяляльнікаў, укладзеных функцый і ўсяго іншага можа быць надзвычай заблытаным і часовымспажываючы.

На шчасце, у нас ёсць лепшае рашэнне, якое пераўзыходзіць як функцыю Google Sheets FILTER, так і іх стандартны інструмент — некалькі супадзенняў VLOOKUP.

Не збянтэжыцеся яго назвай. Ён нагадвае функцыю Google Sheets VLOOKUP, таму што шукае супадзенні. Гэтак жа, як гэта робіць функцыя FILTER. Гэтак жа, як я зрабіў вышэй.

Вось 5 асноўных пераваг інструмента перад функцыяй Google Sheets FILTER:

1. Вы выйгралі Не трэба думаць пра аператары для розных умоў — проста абярыце адзін са спісу:

Увядзіце даты і час, як заўсёды ў электронных табліцах — больш ніякіх спецыяльных функцый:

Стварэнне і выдаленне некалькіх умоў для некалькі слупкоў вельмі хутка :

Папярэдні прагляд выніку і адкарэктуйце ўмовы (пры неабходнасці), перш чым уставіць усё на свой аркуш:

Атрымайце вынік у выглядзе значэнняў або як гатовую формулу .

Я шчыра раю вам усталяваць Multiple VLOOKUP Супадае і паспрабуйце. Каб падрабязней азнаёміцца ​​з яго варыянтамі, наведайце старонку падручніка або паглядзіце спецыяльнае навучальнае відэа: