In dit artikel leert u hoe u een Excel IF statement opbouwt voor verschillende soorten waarden en hoe u meerdere IF statements maakt.

IF is een van de meest populaire en nuttige functies in Excel. In het algemeen gebruikt u een IF-instructie om een voorwaarde te testen en een waarde terug te geven als aan de voorwaarde wordt voldaan, en een andere waarde als niet aan de voorwaarde wordt voldaan.

In deze handleiding leren we de syntaxis en het gebruikelijke gebruik van de IF-functie in Excel, en gaan we vervolgens dieper in op formulevoorbeelden die hopelijk nuttig zijn voor zowel beginners als ervaren gebruikers.

IF-functie in Excel

IF is een van de logische functies die een bepaalde voorwaarde evalueert en een waarde teruggeeft als de voorwaarde TRUE is, en een andere waarde als de voorwaarde FALSE is.

De syntaxis van de IF-functie is als volgt:

Zoals je ziet, neemt IF in totaal 3 argumenten, maar alleen het eerste is verplicht, de andere twee zijn optioneel.

Logische_test (vereist) - de te testen voorwaarde. Kan worden geëvalueerd als TRUE of FALSE.

Waarde_indien_waar (optioneel) - de waarde die moet worden teruggegeven wanneer de logische test op TRUE uitkomt, d.w.z. dat aan de voorwaarde is voldaan. Indien weggelaten, wordt de waarde_als_vals argument moet worden gedefinieerd.

Waarde_als_valse (optioneel) - de waarde die moet worden teruggegeven als de logische test op FALSE uitkomt, d.w.z. dat niet aan de voorwaarde is voldaan. Indien weggelaten, wordt de waarde_indien_waar argument moet worden ingesteld.

Basis IF-formule in Excel

Om een eenvoudige Als dan verklaring in Excel, is dit wat u moet doen:

• Voor logische_test Schrijf een uitdrukking die TRUE of FALSE geeft. Hiervoor gebruik je normaal een van de logische operatoren.
• Voor waarde_indien_waar geeft aan wat moet worden teruggegeven wanneer de logische test op TRUE uitkomt.
• Voor waarde_als_vals Geef aan wat moet worden teruggegeven wanneer de logische test op FALSE uitkomt. Hoewel dit argument optioneel is, raden wij aan het altijd te configureren om onverwachte resultaten te voorkomen. Voor een gedetailleerde uitleg, zie Excel IF: dingen die u moet weten.

Laten we als voorbeeld een heel eenvoudige IF-formule schrijven die een waarde in cel A2 controleert en "Goed" teruggeeft als de waarde groter is dan 80, en "Slecht" in alle andere gevallen:

=IF(B2>80, "Goed", "Slecht")

Deze formule gaat naar C2, en wordt dan gekopieerd tot en met C7:

Als u alleen een waarde wilt teruggeven als aan de voorwaarde is voldaan (of niet is voldaan), en anders - niets, gebruik dan een lege tekenreeks ("") voor het "ongedefinieerde" argument. Bijvoorbeeld:

=IF(B2>80, "Good", "")

Deze formule geeft "Goed" als de waarde in A2 groter is dan 80, anders een lege cel:

Excel Als dan formule: dingen om te weten

Hoewel de laatste twee parameters van de IF-functie optioneel zijn, kan uw formule onverwachte resultaten opleveren als u de onderliggende logica niet kent.

Als value_if_true is weggelaten

Indien het 2e argument van uw Excel IF-formule wordt weggelaten (d.w.z. er staan twee opeenvolgende komma's na de logische test), krijgt u nul (0) wanneer aan de voorwaarde is voldaan, hetgeen in de meeste gevallen geen zin heeft. Hier volgt een voorbeeld van een dergelijke formule:

=IF(B2>80, , "Slecht")

Om in plaats daarvan een lege cel terug te geven, geeft u een lege tekenreeks ("") op voor de tweede parameter, zoals dit:

=IF(B2>80, "", "Slecht")

Het onderstaande screenshot toont het verschil:

Als value_if_false is weggelaten

Het weglaten van de derde parameter van IF geeft het volgende resultaat wanneer de logische test op FALSE uitkomt.

Als er alleen een haakje achter waarde_indien_waar zal de IF-functie de logische waarde FALSE teruggeven. Nogal onverwacht, nietwaar? Hier is een voorbeeld van zo'n formule:

=IF(B2>80, "Good")

Het typen van een komma na de waarde_indien_waar argument zal Excel dwingen 0 terug te geven, wat ook niet veel zin heeft:

=IF(B2>80, "Good",)

De meest redelijke aanpak is het gebruik van een tekenreeks van nul lengte ("") om een lege cel te krijgen wanneer niet aan de voorwaarde is voldaan:

=IF(B2>80, "Good", "")

Tip. Om een logische waarde terug te geven wanneer aan de opgegeven voorwaarde is voldaan of niet, geeft u TRUE op voor waarde_indien_waar en FALSE voor waarde_als_vals Om ervoor te zorgen dat de resultaten Booleaanse waarden zijn die andere Excel-functies kunnen herkennen, moet u TRUE en FALSE niet tussen dubbele aanhalingstekens zetten, want dan worden het normale tekstwaarden.

IF-functie gebruiken in Excel - formulevoorbeelden

Nu u vertrouwd bent met de syntaxis van de IF-functie, laten we eens kijken naar enkele formulevoorbeelden en leren hoe u het volgende kunt gebruiken Als dan verklaringen in reële scenario's.

Excel IF-functie met getallen

Om een IF-instructie voor getallen te maken, gebruikt u logische operatoren zoals:

• Gelijk aan (=)
• Niet gelijk aan ()
• Groter dan (>)
• Groter dan of gelijk aan (>=)
• Minder dan (<)
• Minder dan of gelijk aan (<=)

Hierboven hebt u al een voorbeeld gezien van zo'n formule die controleert of een getal groter is dan een bepaald getal.

En hier is een formule die controleert of een cel een negatief getal :

=IF(B2<0, "Ongeldig", "")

Voor negatieve getallen (die kleiner zijn dan 0) geeft de formule "Ongeldig"; voor nullen en positieve getallen - een lege cel.

Excel IF-functie met tekst

Gewoonlijk schrijft u een IF-instructie voor tekstwaarden met de operator "gelijk aan" of "niet gelijk aan".

De volgende formule controleert bijvoorbeeld de Leveringsstatus in B2 om te bepalen of een actie nodig is of niet:

=IF(B2="geleverd", "Nee", "Ja")

Vertaald in gewoon Engels zegt de formule: stuur "Nee" terug als B2 gelijk is aan "geleverd", anders "Ja".

Een andere manier om hetzelfde resultaat te bereiken is door de "niet gelijk aan"-operator te gebruiken en de waarde_indien_waar en waarde_als_vals waarden:

=IF(C2"delivered", "Yes", "No")

Opmerkingen:

• Wanneer u tekstwaarden gebruikt voor de parameters van IF, vergeet dan niet deze altijd in te sluiten in dubbele aanhalingstekens .
• Zoals de meeste andere Excel functies, IF is standaard hoofdletterongevoelig In bovenstaand voorbeeld wordt geen onderscheid gemaakt tussen "delivered", "Delivered" en "DELIVERED".

Hoofdlettergevoelige IF-instructie voor tekstwaarden

Om hoofdletters en kleine letters als verschillende tekens te behandelen, gebruikt u IF in combinatie met de hoofdlettergevoelige functie EXACT.

Om bijvoorbeeld alleen "Nee" te geven als B2 "LEVERD" (de hoofdletters) bevat, gebruikt u deze formule:

=IF(EXACT(B2,"LEVERD"), "Nee", "Ja")

Als cel gedeeltelijke tekst bevat

In de situatie waarin u de voorwaarde wilt baseren op gedeeltelijke overeenkomst in plaats van een exacte overeenkomst, is een onmiddellijke oplossing die in je opkomt het gebruik van jokertekens in de logische test. Deze eenvoudige en voor de hand liggende aanpak werkt echter niet. Veel functies accepteren jokertekens, maar IF hoort daar helaas niet bij.

Een werkende oplossing is het gebruik van IF in combinatie met ISNUMBER en SEARCH (hoofdletterongevoelig) of FIND (hoofdlettergevoelig).

Bijvoorbeeld, indien "Geen" actie is vereist voor zowel "Geleverd" als "Uit te leveren" items, zal de volgende formule goed werken:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes")

Voor meer informatie, zie:

• Excel IF-instructie voor gedeeltelijke tekstovereenkomst
• Als cel bevat dan

Excel IF-instructie met data

Op het eerste gezicht lijkt het misschien dat IF formules voor datums verwant zijn aan IF statements voor numerieke en tekstwaarden. Helaas is dat niet zo. In tegenstelling tot veel andere functies herkent IF datums wel in logische tests en interpreteert ze als louter tekststrings. Met andere woorden, u kunt geen datum opgeven in de vorm van "1/1/2020" of ">1/1/2020". Om de IF functie een datum te laten herkennen, moet u deze omwikkelen metde functie DATEVALUE.

Zo kun je bijvoorbeeld controleren of een bepaalde datum groter is dan een andere datum:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

Deze formule evalueert de data in kolom B en geeft "Coming soon" als een spel gepland staat voor 18-jul-2022 of later, "Completed" voor een eerdere datum.

Natuurlijk is er niets dat u belet om de beoogde datum in te voeren in een vooraf gedefinieerde cel (bijvoorbeeld E2) en naar die cel te verwijzen. Vergeet alleen niet om het celadres vast te zetten met het $-teken om er een absolute verwijzing van te maken. Bijvoorbeeld:

=IF(B2>$E$2, "Coming soon", "Completed")

Om een datum te vergelijken met de huidige datum gebruik dan de TODAY() functie. Bijvoorbeeld:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF-instructie voor spaties en niet-spaties

Als u uw gegevens op de een of andere manier wilt markeren op basis van het al dan niet leeg zijn van een bepaalde cel(len), kunt u dat doen:

• Gebruik de IF-functie in combinatie met ISBLANK, of
• Gebruik de logische uitdrukkingen (gelijk aan leeg) of "" (niet gelijk aan leeg).

In de onderstaande tabel wordt het verschil tussen deze twee benaderingen toegelicht aan de hand van formulevoorbeelden.

Geeft 0 als A1 visueel leeg is, anders 1.

Indien A1 een lege tekenreeks ("") bevat, geeft de formule 0 terug. ISBLANK()

Evalueert naar TRUE als een cel bevat helemaal niets - geen formule, geen spaties, geen lege strings.

Anders is de uitkomst FALSE.

Geeft 0 als A1 absoluut leeg is, anders 1.

Indien A1 een lege tekenreeks ("") bevat, geeft de formule 1 terug. Niet-blanke cellen "" Evalueert naar TRUE als een cel gegevens bevat, anders naar FALSE.

Cellen met strings van nul lengte worden beschouwd als blanco . =IF(A1"", 1, 0)

Geeft 1 als A1 niet leeg is; anders 0.

Als A1 een lege tekenreeks bevat, geeft de formule 0 terug. ISBLANK()=FALSE Evalueert naar TRUE als een cel niet leeg is, anders naar FALSE.

Cellen met strings van nul lengte worden beschouwd als niet-blanco . =IF(ISBLANK(A1)=FALSE, 0, 1)

Werkt hetzelfde als de bovenstaande formule, maar geeft 1 als A1 een lege tekenreeks bevat.

En nu, laten we blanco en niet blanco IF statements in actie zien. Stel dat je in kolom B alleen een datum hebt als er al een spel is gespeeld. Om de voltooide spellen te labelen, gebruik je een van deze formules:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

Indien de geteste cellen geen strings van nul lengte hebben, zullen alle formules precies dezelfde resultaten opleveren:

Controleer of twee cellen hetzelfde zijn

Om een formule te maken die controleert of twee cellen overeenkomen, vergelijkt u de cellen door het gelijkteken (=) te gebruiken in de logische test van IF. Bijvoorbeeld:

=IF(B2=C2, "Zelfde score", "")

Om te controleren of de twee cellen dezelfde tekst bevatten, inclusief de hoofdletters, maakt u uw IF-formule hoofdlettergevoelig met behulp van de functie EXACT.

Om bijvoorbeeld de wachtwoorden in A2 en B2 te vergelijken, en "Match" te retourneren als de twee strings precies hetzelfde zijn, en "Do not match" anders, is de formule:

=IF(EXACT(A2, B2), "Komt overeen", "Komt niet overeen")

IF dan formule om een andere formule uit te voeren

In alle voorgaande voorbeelden gaf een Excel IF statement waarden terug. Maar het kan ook een bepaalde berekening uitvoeren of een andere formule uitvoeren wanneer al dan niet aan een bepaalde voorwaarde wordt voldaan. Neem hiervoor een andere functie of rekenkundige uitdrukking op in de waarde_indien_waar en/of waarde_als_vals argumenten.

Bijvoorbeeld, als B2 groter is dan 80, laten we het vermenigvuldigen met 7%, anders met 3%:

=IF(B2>80, B2*7%, B2*3%)

Meerdere IF-statements in Excel

In wezen zijn er twee manieren om meerdere IF-statements in Excel te schrijven:

• Verschillende IF-functies in elkaar schuiven
• Gebruik van de AND- of OR-functie in de logische test

Geneste IF-instructie

Met geneste IF-functies kunt u meerdere IF statements in dezelfde cel plaatsen, d.w.z. meerdere voorwaarden testen binnen één formule en verschillende waarden retourneren, afhankelijk van de resultaten van die tests.

Neem aan dat je doel is om verschillende bonussen toe te kennen op basis van de score:

• Meer dan 90 - 10%
• 90 tot 81 - 7%
• 80 tot 70 - 5%
• Minder dan 70 - 3%

Om de taak te volbrengen, schrijft u 3 afzonderlijke IF-functies en nestelt u ze als volgt in elkaar:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))

Zie voor meer formulevoorbeelden:

• Excel geneste IF-formule
• Geneste IF-functie: voorbeelden, beste praktijken en alternatieven

Excel IF-instructie met meerdere voorwaarden

Om meerdere voorwaarden met de AND- of OR-logica te evalueren, neemt u de overeenkomstige functie op in de logische test:

• AND - geeft WAAR als alle de voorwaarden zijn vervuld.
• OF - geeft WAAR als elke van de voorwaarden is voldaan.

Om bijvoorbeeld "geslaagd" te geven als beide scores in B2 en C2 hoger zijn dan 80, is de formule:

=IF(AND(B2>80, C2>80), "geslaagd", "gezakt")

Om "Pass" te krijgen als een van beide scores hoger is dan 80, is de formule:

=IF(OR(B2>80, C2>80), "geslaagd", "gezakt")

Ga voor alle details naar:

• IF EN formule in Excel
• Excel IF OR-functie met formulevoorbeelden

Indien fout in Excel

Vanaf Excel 2007 hebben we een speciale functie, genaamd IFERROR, om formules te controleren op fouten. In Excel 2013 en hoger is er ook de IFNA-functie om #N/A-fouten af te handelen.

En toch kunnen er omstandigheden zijn waarin het gebruik van de IF-functie samen met ISERROR of ISNA een betere oplossing is. In principe is IF ISERROR de formule die u moet gebruiken wanneer u iets wilt teruggeven als er een fout optreedt en iets anders als er geen fout optreedt. De IFERROR-functie kan dat niet, omdat die altijd het resultaat van de hoofdformule teruggeeft als het geen fout is.

Bijvoorbeeld, om elke score in kolom B te vergelijken met de top 3 scores in E2:E4, en "Ja" te retourneren als er een overeenkomst is gevonden, en "Nee" anders, voert u deze formule in C2 in, en kopieert u deze naar beneden tot en met C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "Nee", "Ja" )

Zie voor meer informatie IF ISERROR-formule in Excel.

Hopelijk hebben onze voorbeelden u geholpen grip te krijgen op de basisbeginselen van Excel IF. Ik dank u voor het lezen en hoop u volgende week op onze blog te zien!

Praktijk werkboek

Excel IF-instructie - formulevoorbeelden (.xlsx bestand)