In diesem Artikel erfahren Sie, wie Sie eine Excel-WENN-Anweisung für verschiedene Arten von Werten erstellen können und wie Sie mehrere WENN-Anweisungen erstellen können.

IF ist eine der beliebtesten und nützlichsten Funktionen in Excel. Im Allgemeinen verwenden Sie eine IF-Anweisung, um eine Bedingung zu testen und einen Wert zurückzugeben, wenn die Bedingung erfüllt ist, und einen anderen Wert, wenn die Bedingung nicht erfüllt ist.

In diesem Lernprogramm werden wir die Syntax und die häufigen Verwendungen der Excel-Funktion IF kennenlernen und uns anschließend Formelbeispiele ansehen, die hoffentlich sowohl für Anfänger als auch für erfahrene Benutzer hilfreich sind.

IF-Funktion in Excel

IF ist eine der logischen Funktionen, die eine bestimmte Bedingung auswertet und einen Wert zurückgibt, wenn die Bedingung WAHR ist, und einen anderen Wert, wenn die Bedingung FALSCH ist.

Die Syntax der IF-Funktion lautet wie folgt:

Wie Sie sehen, benötigt IF insgesamt 3 Argumente, aber nur das erste ist obligatorisch, die beiden anderen sind optional.

Logischer_Test (erforderlich) - die zu testende Bedingung, die entweder als TRUE oder FALSE ausgewertet werden kann.

Wert_wenn_true (optional) - der Wert, der zurückgegeben werden soll, wenn der logische Test TRUE ergibt, d.h. wenn die Bedingung erfüllt ist; wenn er weggelassen wird, wird der wert_wenn_false muss definiert werden.

Wert_wenn_falsch (optional) - der Wert, der zurückgegeben werden soll, wenn der logische Test FALSE ergibt, d.h. die Bedingung nicht erfüllt ist. Wird er weggelassen, wird der wert_wenn_true muss gesetzt werden.

Grundlegende IF-Formel in Excel

So erstellen Sie eine einfache Wenn dann Anweisung in Excel, müssen Sie Folgendes tun:

• Für logischer_Test schreiben Sie einen Ausdruck, der entweder TRUE oder FALSE zurückgibt. Dazu verwenden Sie normalerweise einen der logischen Operatoren.
• Für wert_wenn_true geben Sie an, was zurückgegeben werden soll, wenn der logische Test TRUE ergibt.
• Für wert_wenn_false geben Sie an, was zurückgegeben werden soll, wenn der logische Test FALSE ergibt. Obwohl dieses Argument optional ist, empfehlen wir, es immer zu konfigurieren, um unerwartete Ergebnisse zu vermeiden. Eine detaillierte Erklärung finden Sie unter Excel IF: Wissenswertes.

Lassen Sie uns als Beispiel eine sehr einfache WENN-Formel schreiben, die einen Wert in Zelle A2 überprüft und "Gut" zurückgibt, wenn der Wert größer als 80 ist, andernfalls "Schlecht":

=IF(B2>80, "Gut", "Schlecht")

Diese Formel geht bis C2 und wird dann nach unten bis C7 kopiert:

Wenn Sie einen Wert nur dann zurückgeben möchten, wenn die Bedingung erfüllt (oder nicht erfüllt) ist, ansonsten aber nichts, dann verwenden Sie eine leere Zeichenkette ("") für das Argument "undefined". Zum Beispiel:

=IF(B2>80, "Gut", "")

Diese Formel gibt "Gut" zurück, wenn der Wert in A2 größer als 80 ist, ansonsten eine leere Zelle:

Excel Wenn-dann-Formel: Wissenswertes

Obwohl die letzten beiden Parameter der IF-Funktion optional sind, kann Ihre Formel unerwartete Ergebnisse liefern, wenn Sie die zugrunde liegende Logik nicht kennen.

Wenn value_if_true weggelassen wird

Wenn das 2. Argument Ihrer Excel-WENN-Formel weggelassen wird (d.h. zwei aufeinanderfolgende Kommas nach dem logischen Test), erhalten Sie Null (0), wenn die Bedingung erfüllt ist, was in den meisten Fällen keinen Sinn macht. Hier ist ein Beispiel für eine solche Formel:

=IF(B2>80, , "Schlecht")

Um stattdessen eine leere Zelle zurückzugeben, geben Sie für den zweiten Parameter eine leere Zeichenkette ("") ein, etwa so:

=IF(B2>80, "", "Schlecht")

Die folgende Abbildung verdeutlicht den Unterschied:

Wenn value_if_false weggelassen wird

Das Weglassen des 3. Parameters von IF führt zu folgenden Ergebnissen, wenn der logische Test zu FALSE ausgewertet wird.

Wenn es nur eine schließende Klammer nach wert_wenn_true wird die Funktion IF den logischen Wert FALSE zurückgeben. Das ist ziemlich unerwartet, nicht wahr? Hier ist ein Beispiel für eine solche Formel:

=IF(B2>80, "Gut")

Die Eingabe eines Kommas nach der wert_wenn_true Argument zwingt Excel dazu, 0 zurückzugeben, was auch nicht sehr sinnvoll ist:

=IF(B2>80, "Gut",)

Der vernünftigste Ansatz ist die Verwendung einer Zeichenkette mit der Länge Null (""), um eine leere Zelle zu erhalten, wenn die Bedingung nicht erfüllt ist:

=IF(B2>80, "Gut", "")

Tipp: Um einen logischen Wert zurückzugeben, wenn die angegebene Bedingung erfüllt oder nicht erfüllt ist, geben Sie TRUE für wert_wenn_true und FALSE für wert_wenn_false Damit die Ergebnisse boolesche Werte sind, die von anderen Excel-Funktionen erkannt werden können, dürfen TRUE und FALSE nicht in Anführungszeichen gesetzt werden, da sie sonst zu normalen Textwerten werden.

Verwendung der IF-Funktion in Excel - Formelbeispiele

Nachdem Sie nun mit der Syntax der IF-Funktion vertraut sind, wollen wir uns einige Formelbeispiele ansehen und lernen, wie man Wenn dann Aussagen in realen Szenarien.

Excel IF-Funktion mit Zahlen

Um eine IF-Anweisung für Zahlen zu erstellen, verwenden Sie logische Operatoren wie z. B.:

• Gleich (=)
• Nicht gleich ()
• Größer als (>)
• Größer als oder gleich (>=)
• Weniger als (<)
• Kleiner als oder gleich (<=)

Oben haben Sie bereits ein Beispiel für eine solche Formel gesehen, die prüft, ob eine Zahl größer als eine bestimmte Zahl ist.

Und hier ist eine Formel, die prüft, ob eine Zelle ein negative Zahl :

=IF(B2<0, "Ungültig", "")

Für negative Zahlen (die kleiner als 0 sind) gibt die Formel "Ungültig" zurück; für Nullen und positive Zahlen - eine leere Zelle.

Excel IF-Funktion mit Text

Üblicherweise schreiben Sie eine IF-Anweisung für Textwerte, wobei Sie entweder den Operator "gleich" oder "nicht gleich" verwenden.

Zum Beispiel prüft die folgende Formel die Status der Lieferung in B2, um festzustellen, ob eine Maßnahme erforderlich ist oder nicht:

=IF(B2="geliefert", "Nein", "Ja")

Übersetzt in einfaches Englisch lautet die Formel: Gib "Nein" zurück, wenn B2 gleich "geliefert" ist, ansonsten "Ja".

Eine andere Möglichkeit, das gleiche Ergebnis zu erzielen, besteht darin, den Operator "ungleich" zu verwenden und die wert_wenn_true und wert_wenn_false Werte:

=IF(C2 "geliefert", "Ja", "Nein")

Anmerkungen:

• Wenn Sie Textwerte für IF-Parameter verwenden, denken Sie daran, sie immer in Anführungszeichen .
• Wie die meisten anderen Excel-Funktionen, IF unterscheidet standardmäßig nicht zwischen Groß- und Kleinschreibung Im obigen Beispiel wird nicht zwischen "delivered", "Delivered" und "DELIVERED" unterschieden.

Groß- und Kleinschreibung beachtende IF-Anweisung für Textwerte

Um Groß- und Kleinbuchstaben als unterschiedliche Zeichen zu behandeln, verwenden Sie IF in Kombination mit der case-sensitiven EXACT-Funktion.

Wenn Sie zum Beispiel "Nein" nur dann zurückgeben möchten, wenn B2 "DELIVERED" (Großbuchstaben) enthält, würden Sie diese Formel verwenden:

=IF(EXACT(B2, "GELIEFERT"), "Nein", "Ja")

Wenn die Zelle einen Teil des Textes enthält

In Situationen, in denen Sie die Bedingung auf teilweise Übereinstimmung statt einer exakten Übereinstimmung zu verwenden, ist eine sofortige Lösung, die einem in den Sinn kommt, die Verwendung von Platzhaltern im logischen Test. Dieser einfache und offensichtliche Ansatz funktioniert jedoch nicht. Viele Funktionen akzeptieren Platzhalter, aber leider gehört IF nicht dazu.

Eine praktikable Lösung ist die Verwendung von IF in Kombination mit ISNUMBER und SEARCH (Groß-/Kleinschreibung wird nicht berücksichtigt) oder FIND (Groß-/Kleinschreibung wird berücksichtigt).

Wenn zum Beispiel die Aktion "Nein" sowohl für "Geliefert" als auch für "Zur Lieferung" erforderlich ist, funktioniert die folgende Formel sehr gut:

=IF(ISNUMBER(SEARCH("deliv", B2)), "Nein", "Ja")

Weitere Informationen finden Sie unter:

• Excel IF-Anweisung für partielle Textübereinstimmung
• Wenn Zelle enthält dann

Excel IF-Anweisung mit Daten

Auf den ersten Blick könnte man meinen, dass IF-Formeln für Datumsangaben mit IF-Anweisungen für numerische und Textwerte vergleichbar sind. Leider ist dem nicht so. Im Gegensatz zu vielen anderen Funktionen erkennt IF Datumsangaben in logischen Tests und interpretiert sie als reine Textzeichenfolgen. Mit anderen Worten, Sie können ein Datum nicht in der Form "1/1/2020" oder ">1/1/2020" angeben. Damit die IF-Funktion ein Datum erkennt, müssen Sie es indie Funktion DATEVALUE.

So können Sie zum Beispiel prüfen, ob ein bestimmtes Datum größer ist als ein anderes Datum:

=IF(B2>DATEVALUE("7/18/2022"), "Demnächst", "Abgeschlossen")

Diese Formel wertet die Daten in Spalte B aus und gibt "Coming soon" zurück, wenn ein Spiel für den 18-Jul-2022 oder später geplant ist, "Completed" für ein früheres Datum.

Es spricht natürlich nichts dagegen, das Zieldatum in eine vordefinierte Zelle (z.B. E2) einzugeben und auf diese Zelle zu verweisen. Denken Sie nur daran, die Zelladresse mit dem $-Zeichen zu verriegeln, damit es sich um einen absoluten Verweis handelt. Zum Beispiel:

=IF(B2>$E$2, "Demnächst", "Abgeschlossen")

So vergleichen Sie ein Datum mit dem aktuelles Datum verwenden Sie die Funktion TODAY(), zum Beispiel:

=IF(B2>TODAY(), "Demnächst", "Abgeschlossen")

Excel IF-Anweisung für Leerzeichen und Nicht-Leerzeichen

Wenn Sie Ihre Daten auf der Grundlage bestimmter leerer oder nicht leerer Zellen markieren möchten, können Sie dies entweder tun:

• Verwenden Sie die Funktion IF zusammen mit ISBLANK, oder
• Verwenden Sie die logischen Ausdrücke (gleich Leerzeichen) oder "" (nicht gleich Leerzeichen).

In der nachstehenden Tabelle wird der Unterschied zwischen diesen beiden Ansätzen anhand von Formelbeispielen erläutert.

Gibt 0 zurück, wenn A1 visuell leer ist; andernfalls wird 1 zurückgegeben.

Wenn A1 eine leere Zeichenfolge ("") enthält, gibt die Formel 0 zurück. ISBLANK()

Wird als TRUE ausgewertet, wenn eine Zelle Folgendes enthält absolut nichts - keine Formel, keine Leerzeichen, keine leeren Zeichenfolgen.

Andernfalls wird FALSE ausgewertet.

Gibt 0 zurück, wenn A1 absolut leer ist, andernfalls 1.

Wenn A1 eine leere Zeichenfolge ("") enthält, gibt die Formel 1 zurück. Nicht-Leerzellen "" Ergibt TRUE, wenn eine Zelle Daten enthält, ansonsten FALSE.

Zellen mit Zeichenfolgen mit Null-Länge werden als leer . =IF(A1"", 1, 0)

Gibt 1 zurück, wenn A1 nicht leer ist; andernfalls 0.

Wenn A1 eine leere Zeichenfolge enthält, gibt die Formel 0 zurück. ISBLANK()=FALSE Ergibt TRUE, wenn eine Zelle nicht leer ist, andernfalls FALSE.

Zellen mit Zeichenfolgen mit Null-Länge werden als nicht-blank . =IF(ISBLANK(A1)=FALSE, 0, 1)

Funktioniert genauso wie die obige Formel, gibt aber 1 zurück, wenn A1 eine leere Zeichenfolge enthält.

Und nun sehen wir uns die leeren und nicht leeren IF-Anweisungen in Aktion an. Angenommen, Sie haben nur dann ein Datum in Spalte B, wenn ein Spiel bereits gespielt wurde. Um die abgeschlossenen Spiele zu kennzeichnen, verwenden Sie eine dieser Formeln:

=IF(B2="", "", "Abgeschlossen")

=IF(ISBLANK(B2), "", "Abgeschlossen")

=IF($B2"", "Abgeschlossen", "")

=IF(ISBLANK($B2)=FALSE, "Abgeschlossen", "")

Wenn die getesteten Zellen keine Zeichenketten mit der Länge Null enthalten, liefern alle Formeln genau die gleichen Ergebnisse:

Prüfen, ob zwei Zellen gleich sind

Um eine Formel zu erstellen, die prüft, ob zwei Zellen übereinstimmen, vergleichen Sie die Zellen, indem Sie das Gleichheitszeichen (=) im logischen Test von IF verwenden, z. B:

=IF(B2=C2, "Gleiche Punktzahl", "")

Um zu prüfen, ob die beiden Zellen denselben Text einschließlich der Groß- und Kleinschreibung enthalten, machen Sie Ihre WENN-Formel mit Hilfe der Funktion EXAKT case-sensitive.

Um z. B. die Kennwörter in A2 und B2 zu vergleichen und "übereinstimmen" zurückzugeben, wenn die beiden Zeichenfolgen genau gleich sind, und andernfalls "nicht übereinstimmen", lautet die Formel:

=IF(EXACT(A2, B2), "Übereinstimmen", "Nicht übereinstimmen")

IF dann Formel zur Ausführung einer anderen Formel

In allen vorangegangenen Beispielen gab eine Excel-IF-Anweisung Werte zurück. Sie kann aber auch eine bestimmte Berechnung durchführen oder eine andere Formel ausführen, wenn eine bestimmte Bedingung erfüllt oder nicht erfüllt ist. Dazu betten Sie eine andere Funktion oder einen arithmetischen Ausdruck in die wert_wenn_true und/oder wert_wenn_false Argumente.

Wenn zum Beispiel B2 größer als 80 ist, wird es mit 7 % multipliziert, ansonsten mit 3 %:

=IF(B2>80, B2*7%, B2*3%)

Mehrere IF-Anweisungen in Excel

Es gibt im Wesentlichen zwei Möglichkeiten, mehrere IF-Anweisungen in Excel zu schreiben:

• Verschachtelung mehrerer IF-Funktionen ineinander
• Verwendung der Funktion AND oder OR in der logischen Prüfung

Verschachtelte IF-Anweisung

Mit verschachtelten WENN-Funktionen können Sie mehrere WENN-Anweisungen in derselben Zelle platzieren, d. h. mehrere Bedingungen innerhalb einer Formel testen und je nach den Ergebnissen dieser Tests unterschiedliche Werte zurückgeben.

Gehen Sie davon aus, dass Ihr Ziel darin besteht, je nach Punktzahl unterschiedliche Boni zu vergeben:

• Über 90 - 10%
• 90 bis 81 - 7%
• 80 bis 70 - 5%
• Weniger als 70 - 3%

Um diese Aufgabe zu bewältigen, schreiben Sie 3 separate IF-Funktionen und schachteln sie wie folgt ineinander:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%)))

Weitere Beispiele für Formeln finden Sie unter:

• Excel verschachtelte IF-Formel
• Verschachtelte IF-Funktion: Beispiele, bewährte Verfahren und Alternativen

Excel IF-Anweisung mit mehreren Bedingungen

Um mehrere Bedingungen mit der UND- oder ODER-Logik auszuwerten, betten Sie die entsprechende Funktion in den logischen Test ein:

• AND - gibt TRUE zurück, wenn alle die Bedingungen erfüllt sind.
• OR - gibt TRUE zurück, wenn jede der Bedingungen erfüllt ist.

Um zum Beispiel "Bestanden" zu erhalten, wenn beide Ergebnisse in B2 und C2 höher als 80 sind, lautet die Formel:

=IF(AND(B2>80, C2>80), "Bestanden", "Nicht bestanden")

Die Formel für "Bestehen" lautet, wenn eine der beiden Punktzahlen über 80 liegt:

=IF(OR(B2>80, C2>80), "Bestanden", "Nicht bestanden")

Ausführliche Informationen finden Sie unter:

• IF AND-Formel in Excel
• Excel IF OR-Funktion mit Formelbeispielen

Wenn Fehler in Excel

Ab Excel 2007 gibt es eine spezielle Funktion namens IFERROR, um Formeln auf Fehler zu überprüfen. In Excel 2013 und höher gibt es auch die Funktion IFNA, um #N/A-Fehler zu behandeln.

Und dennoch kann es Umstände geben, unter denen die Verwendung der IF-Funktion zusammen mit ISERROR oder ISNA die bessere Lösung ist. Grundsätzlich ist IF ISERROR die Formel, die Sie verwenden sollten, wenn Sie etwas zurückgeben möchten, wenn ein Fehler auftritt, und etwas anderes, wenn kein Fehler vorliegt. Die IFERROR-Funktion ist dazu nicht in der Lage, da sie immer das Ergebnis der Hauptformel zurückgibt, wenn es sich nicht um einen Fehler handelt.

Um zum Beispiel jede Punktzahl in Spalte B mit den 3 besten Punktzahlen in E2:E4 zu vergleichen und "Ja" zurückzugeben, wenn eine Übereinstimmung gefunden wird, und "Nein" andernfalls, geben Sie diese Formel in C2 ein und kopieren sie dann nach unten bis C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "Nein", "Ja" )

Weitere Informationen finden Sie unter IF ISERROR-Formel in Excel.

Ich hoffe, unsere Beispiele haben Ihnen geholfen, die Excel IF-Grundlagen zu verstehen. Ich danke Ihnen für die Lektüre und hoffe, Sie nächste Woche in unserem Blog wiederzusehen!

Arbeitsbuch für die Praxis

Excel IF-Anweisung - Formelbeispiele (.xlsx-Datei)