Šiame straipsnyje sužinosite, kaip sukurti "Excel" IF teiginį įvairių tipų reikšmėms ir kaip sukurti kelis IF teiginius.

IF yra viena populiariausių ir naudingiausių "Excel" funkcijų. Paprastai sakinį IF naudojate norėdami patikrinti sąlygą ir grąžinti vieną reikšmę, jei sąlyga tenkinama, ir kitą reikšmę, jei sąlyga netenkinama.

Šioje pamokoje susipažinsime su "Excel" funkcijos IF sintakse ir dažniausiais jos naudojimo atvejais, o tada atidžiau apžvelgsime formulių pavyzdžius, kurie, tikimės, bus naudingi ir pradedantiesiems, ir patyrusiems naudotojams.

IF funkcija programoje "Excel

IF yra viena iš loginių funkcijų, kuri įvertina tam tikrą sąlygą ir grąžina vieną reikšmę, jei sąlyga yra TRUE, ir kitą reikšmę, jei sąlyga yra FALSE.

Funkcijos IF sintaksė yra tokia:

Kaip matote, IF iš viso priima 3 argumentus, tačiau tik pirmasis iš jų yra privalomas, kiti du - neprivalomi.

Loginis_testas (privaloma) - tikrinama sąlyga. Gali būti vertinama kaip TRUE arba FALSE.

Value_if_true (neprivaloma) - reikšmė, kurią reikia grąžinti, kai loginis testas yra TRUE, t. y. sąlyga įvykdyta. value_if_false argumentas turi būti apibrėžtas.

Value_if_false (neprivaloma) - reikšmė, kurią reikia grąžinti, kai loginis testas įvertinamas kaip FALSE, t. y. sąlyga neįvykdyta. value_if_true argumentas turi būti nustatytas.

Pagrindinė IF formulė programoje "Excel

Norėdami sukurti paprastą Jei tada teiginį "Excel" programoje, jums reikia padaryti štai ką:

• Tinklalapiui logical_test , parašykite išraišką, kuri grąžina TRUE arba FALSE. Tam paprastai naudojamas vienas iš loginių operatorių.
• Tinklalapiui value_if_true , nurodykite, kas turi būti grąžinama, kai loginis testas įvertinamas kaip TRUE.
• Tinklalapiui value_if_false , nurodykite, ką grąžinti, kai loginis testas įvertinamas kaip FALSE. Nors šis argumentas neprivalomas, rekomenduojame visada jį konfigūruoti, kad būtų išvengta netikėtų rezultatų. Išsamų paaiškinimą rasite skyriuje "Excel IF: ką reikia žinoti".

Pavyzdžiui, parašykime labai paprastą IF formulę, kuri tikrina A2 ląstelės vertę ir grąžina "Gerai", jei vertė didesnė nei 80, ir "Blogai", jei ne:

=IF(B2>80, "Geras", "Blogas")

Ši formulė perkeliama į C2 ir kopijuojama žemyn iki C7:

Jei norite grąžinti reikšmę tik tada, kai sąlyga yra įvykdyta (arba neįvykdyta), o kitu atveju - nieko, tuomet argumentui "neapibrėžta" naudokite tuščią eilutę (""). Pavyzdžiui:

=IF(B2>80, "Gerai", "")

Ši formulė grąžins "Gerai", jei A2 reikšmė bus didesnė nei 80, o priešingu atveju - tuščią langelį:

"Excel" formulė If then: ką reikia žinoti

Nors du paskutiniai funkcijos IF parametrai yra neprivalomi, jūsų formulė gali duoti netikėtų rezultatų, jei nežinote pagrindinės logikos.

Jei value_if_true praleista

Jei "Excel" formulės IF 2-asis argumentas bus praleistas (t. y. po loginio testo bus du kableliai iš eilės), įvykdžius sąlygą gausite nulį (0), o tai daugeliu atvejų neturi prasmės. Pateikiame tokios formulės pavyzdį:

=IF(B2>80, , "Blogai")

Jei norite grąžinti tuščią langelį, kaip antrąjį parametrą nurodykite tuščią eilutę (""), pvz., taip:

=IF(B2>80, "", "Blogai")

Toliau pateiktoje ekrano nuotraukoje matomas skirtumas:

Jei value_if_false praleista

Jei praleisite trečiąjį IF parametrą, kai loginis testas bus įvertintas kaip FALSE, gausite tokius rezultatus.

Jei po value_if_true , funkcija IF grąžins loginę reikšmę FALSE. Gana netikėta, ar ne? Štai tokios formulės pavyzdys:

=IF(B2>80, "Gerai")

Įvesdami kablelį po value_if_true argumentas privers "Excel" grąžinti 0, o tai taip pat nėra labai prasminga:

=IF(B2>80, "Gerai",)

Tinkamiausias būdas - naudoti nulinio ilgio eilutę (""), kad būtų gautas tuščias langelis, kai sąlyga netenkinama:

=IF(B2>80, "Gerai", "")

Patarimas. Jei norite grąžinti loginę vertę, kai nurodyta sąlyga įvykdyta arba neįvykdyta, nurodykite TRUE value_if_true ir FALSE, jei value_if_false Kad rezultatai būtų loginės reikšmės, kurias gali atpažinti kitos "Excel" funkcijos, neįrašykite TRUE ir FALSE į dvigubas kabutes, nes tai jas pavers įprastomis teksto reikšmėmis.

Funkcijos IF naudojimas programoje "Excel" - formulės pavyzdžiai

Dabar, kai jau susipažinote su funkcijos IF sintakse, pažvelkime į keletą formulės pavyzdžių ir sužinokite, kaip naudoti Jei tada teiginius pagal realaus gyvenimo scenarijus.

"Excel" IF funkcija su skaičiais

Norėdami sudaryti IF teiginį skaičiams, naudokite loginius operatorius, pvz.,:

• Lygus (=)
• Nelygu ()
• Didesnis nei (>)
• Didesnis už arba lygus (>=)
• Mažiau nei (<)
• Mažiau arba lygu (<=)

Aukščiau jau matėte tokios formulės pavyzdį, kuriuo tikrinama, ar skaičius yra didesnis už nurodytą skaičių.

Čia pateikiama formulė, kuri tikrina, ar ląstelėje yra neigiamas skaičius :

=IF(B2<0, "Invalid", "")

Jei skaičiai neigiami (mažesni už 0), formulė grąžina užrašą "Negalioja"; jei skaičiai nuliniai ir teigiami - tuščią langelį.

"Excel" IF funkcija su tekstu

Dažniausiai teksto reikšmėms rašomas IF sakinys, kuriame naudojamas operatorius "lygu" arba "nelygu".

Pavyzdžiui, pagal šią formulę tikrinama Pristatymo būsena B2, kad būtų galima nustatyti, ar reikia imtis veiksmų, ar ne:

=IF(B2="pristatyta", "Ne", "Taip")

Išvertus į paprastą anglų kalbą, formulė skamba taip: grąžinti "Ne", jei B2 yra lygus "pristatyta", priešingu atveju - "Taip".

Kitas būdas pasiekti tą patį rezultatą - naudoti operatorių "nelygu" ir sukeisti value_if_true ir value_if_false vertės:

=IF(C2 "pristatytas", "Taip", "Ne")

Pastabos:

• Naudodami teksto reikšmes IF parametrams, nepamirškite jų visada uždaryti dvigubos kabutės .
• Kaip ir dauguma kitų "Excel" funkcijų, Pagal numatytuosius nustatymus IF neatsižvelgiama į mažųjų ir didžiųjų raidžių skirtumus . Pirmiau pateiktame pavyzdyje neskiriama "pristatytas", "Pristatytas" ir "DELIVERED".

Didžiosios raidės IF teiginys teksto reikšmėms

Norėdami didžiąsias ir mažąsias raides traktuoti kaip skirtingus simbolius, naudokite IF kartu su EXACT funkcija, kuri skiria didžiąsias ir mažąsias raides.

Pavyzdžiui, norėdami grąžinti "Ne" tik tada, kai B2 yra "DELIVERED" (didžioji raidė), naudokite šią formulę:

=IF(EXACT(B2, "DELIVERED"), "No", "Yes")

Jei ląstelėje yra dalinis tekstas

Jei norite sąlygą pagrįsti dalinis atitikimas vietoj tikslaus atitikimo, iš karto ateina į galvą sprendimas - loginiame teste naudoti pakaitinius simbolius. Tačiau šis paprastas ir akivaizdus metodas neveiks. Daug funkcijų priima pakaitinius simbolius, bet, deja, IF nėra viena iš jų.

Veiksmingas sprendimas - naudoti IF kartu su ISNUMBER ir SEARCH (neskaitant didžiųjų raidžių) arba FIND (neskaitant didžiųjų raidžių).

Pavyzdžiui, jei veiksmo "Ne" reikia ir elementams "Pristatytas", ir elementams "Išsiųstas pristatymui", puikiai tiks ši formulė:

=IF(ISNUMBER(SEARCH("deliv", B2)), "Ne", "Taip")

Daugiau informacijos žr:

• "Excel" IF teiginys daliniam teksto atitikimui
• Jei ląstelėje yra tada

"Excel" IF teiginys su datomis

Iš pirmo žvilgsnio gali atrodyti, kad datoms skirtos IF formulės yra panašios į IF teiginius, skirtus skaitinėms ir tekstinėms reikšmėms. Deja, taip nėra. Kitaip nei daugelis kitų funkcijų, IF neatpažįsta datų loginiuose testuose ir interpretuoja jas kaip paprastas teksto eilutes. Kitaip tariant, negalite pateikti datos forma "1/1/2020" arba ">1/1/2020". Kad funkcija IF atpažintų datą, turite ją įvilkti įfunkcija DATEVALUE.

Pavyzdžiui, štai kaip galite patikrinti, ar tam tikra data yra didesnė už kitą datą:

=IF(B2>DATEVALUE("7/18/2022"), "Netrukus", "Baigta")

Ši formulė įvertina B stulpelyje esančias datas ir grąžina "Netrukus", jei žaidimas numatytas 2022 m. liepos 18 d. arba vėliau, ir "Baigtas", jei žaidimas numatytas anksčiau.

Žinoma, niekas nedraudžia tikslinę datą įrašyti į iš anksto nustatytą ląstelę (pvz., E2) ir pateikti nuorodą į tą ląstelę. Tik nepamirškite ląstelės adresą užrakinti ženklu $, kad tai būtų absoliuti nuoroda. Pvz:

=IF(B2>$E$2, "Coming soon", "Completed")

Jei norite palyginti datą su dabartinė data , naudokite funkciją TODAY(). Pavyzdžiui:

=IF(B2>TODAY(), "Netrukus", "Baigta")

"Excel" IF teiginys dėl tuščių ir ne tuščių langelių

Jei norite kaip nors pažymėti duomenis pagal tai, ar tam tikra (-os) ląstelė (-ės) yra tuščia (-os), ar ne, galite:

• Naudokite IF funkciją kartu su ISBLANK arba
• Naudokite logines išraiškas (lygu tuščiajai) arba "" (nelygu tuščiajai).

Toliau pateiktoje lentelėje paaiškinamas šių dviejų metodų skirtumas, pateikiant formulės pavyzdžių.

Grąžina 0, jei A1 yra vizualiai tuščias. Priešingu atveju grąžinama 1.

Jei A1 yra tuščia eilutė (""), formulė grąžina 0. ISBLANK()

Vertinama kaip TRUE, jei ląstelėje yra visiškai nieko - jokių formulių, jokių tarpų, jokių tuščių eilučių.

Priešingu atveju įvertinama kaip FALSE.

Grąžina 0, jei A1 yra visiškai tuščias, 1 - priešingu atveju.

Jei A1 yra tuščia eilutė (""), formulė grąžina 1. Ne tuščios ląstelės "" Įvertinama TRUE, jei ląstelėje yra kokių nors duomenų. Priešingu atveju įvertinama FALSE.

Ląstelės su nulinio ilgio eilutės laikomi tuščia . =IF(A1"", 1, 0)

Grąžina 1, jei A1 yra ne tuščias; priešingu atveju - 0.

Jei A1 yra tuščia eilutė, formulė grąžina 0. ISBLANK()=FALSE Įvertinama TRUE, jei langelis nėra tuščias. Priešingu atveju įvertinama FALSE.

Ląstelės su nulinio ilgio eilutės laikomi ne tuščias . =IF(ISBLANK(A1)=FALSE, 0, 1)

Veikia taip pat, kaip ir pirmiau pateikta formulė, tačiau grąžina 1, jei A1 yra tuščia eilutė.

O dabar pažiūrėkime, kaip veikia tušti ir netušti IF teiginiai. Tarkime, kad B stulpelyje data nurodoma tik tada, jei žaidimas jau buvo sužaistas. Norėdami pažymėti sužaistus žaidimus, naudokite vieną iš šių formulių:

=IF(B2="", "", "Baigta")

=IF(ISBLANK(B2), "", "Baigta")

=IF($B2"", "Baigta", "")

=IF(ISBLANK($B2)=FALSE, "Baigta", "")

Jei testuojamuose langeliuose nėra nulinio ilgio eilučių, visos formulės duos lygiai tokius pačius rezultatus:

Patikrinkite, ar dvi ląstelės yra vienodos

Jei norite sukurti formulę, kuri tikrina, ar dvi ląstelės sutampa, palyginkite ląsteles naudodami lygybės ženklą (=) loginiame teste IF. Pavyzdžiui:

=IF(B2=C2, "Tas pats rezultatas", "")

Norėdami patikrinti, ar abiejuose langeliuose yra tas pats tekstas, įskaitant ir raidžių raidę, naudodami funkciją EXACT padarykite IF formulę jautrią raidėms.

Pavyzdžiui, norint palyginti A2 ir B2 slaptažodžius ir grąžinti "Sutampa", jei abi eilutės yra visiškai vienodos, "Nesutampa", jei ne, formulė yra tokia:

=IF(EXACT(A2, B2), "Sutampa", "Nesutampa")

IF tada formulė paleisti kitą formulę

Visuose ankstesniuose pavyzdžiuose "Excel" IF teiginys grąžino reikšmes. Tačiau jis taip pat gali atlikti tam tikrus skaičiavimus arba įvykdyti kitą formulę, kai įvykdoma arba neįvykdoma tam tikra sąlyga. Šiuo tikslu įterpkite kitą funkciją arba aritmetinę išraišką į value_if_true ir (arba) value_if_false argumentai.

Pavyzdžiui, jei B2 yra didesnis nei 80, jį padauginsime iš 7 %, kitu atveju - iš 3 %:

=IF(B2>80, B2*7%, B2*3%)

Keli IF teiginiai programoje "Excel

Iš esmės yra du būdai, kaip "Excel" programoje rašyti kelis IF teiginius:

• Kelių IF funkcijų įterpimas viena į kitą
• Funkcijos AND arba OR naudojimas atliekant loginį testą

Įterptinis IF teiginys

Naudodami įterptąsias IF funkcijas į tą pačią ląstelę galite įterpti kelis IF teiginius, t. y. vienoje formulėje patikrinti kelias sąlygas ir, atsižvelgiant į šių testų rezultatus, grąžinti skirtingas reikšmes.

Tarkime, kad jūsų tikslas yra priskirti skirtingas premijas, atsižvelgiant į rezultatą:

• Vyresni nei 90 metų - 10%
• nuo 90 iki 81 - 7%
• nuo 80 iki 70 - 5%
• Mažiau nei 70 % - 3 %

Norėdami atlikti šią užduotį, parašykite 3 atskiras IF funkcijas ir įterpkite jas vieną į kitą taip:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%)))

Daugiau formulės pavyzdžių rasite:

• "Excel" įterpta IF formulė
• Įterpta IF funkcija: pavyzdžiai, geriausia praktika ir alternatyvos

"Excel" IF teiginys su keliomis sąlygomis

Jei norite įvertinti kelias sąlygas naudodami AND arba OR logiką, į loginį testą įterpkite atitinkamą funkciją:

• AND - grąžina TRUE, jei visi įvykdytos sąlygos.
• ARBA - bus grąžinama TRUE, jei bet kuris tenkinama viena iš sąlygų.

Pavyzdžiui, jei B2 ir C2 balai yra didesni nei 80, formulė yra tokia:

=IF(AND(B2>80, C2>80), "Įskaityta", "Neįskaityta")

Jei bet kuris iš šių balų yra didesnis nei 80, formulė yra tokia:

=IF(OR(B2>80, C2>80), "Įskaityta", "Neįskaityta")

Išsamią informaciją rasite svetainėje:

• IF IR formulė programoje "Excel
• "Excel" funkcija IF ARBA su formulės pavyzdžiais

Jei "Excel" klaida

Nuo "Excel 2007" yra speciali funkcija IFERROR, skirta formulėms tikrinti, ar jose nėra klaidų. 2013 m. ir vėlesnėse "Excel" versijose taip pat yra funkcija IFNA, skirta #N/A klaidoms tvarkyti.

Ir vis dėlto gali būti aplinkybių, kai funkcija IF kartu su ISERROR arba ISNA yra geresnis sprendimas. Iš esmės IF ISERROR yra formulė, kurią reikia naudoti, kai norite grąžinti kažką, jei yra klaida, ir kažką kitą, jei klaidos nėra. Funkcija IFERROR to padaryti negali, nes ji visada grąžina pagrindinės formulės rezultatą, jei tai nėra klaida.

Pavyzdžiui, norėdami palyginti kiekvieną B stulpelio rezultatą su 3 aukščiausiais E2:E4 stulpelio rezultatais ir grąžinti "Taip", jei rastas atitikmuo, arba "Ne", įveskite šią formulę į C2 ir nukopijuokite ją į C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "Ne", "Taip" )

Daugiau informacijos rasite skyriuje IF ISERROR formulė programoje "Excel".

Tikimės, kad mūsų pavyzdžiai padėjo jums suprasti "Excel IF" pagrindus. Dėkoju, kad perskaitėte, ir tikiuosi, kad kitą savaitę susitiksime mūsų tinklaraštyje!

Praktikos sąsiuvinis

"Excel" IF teiginys - formulės pavyzdžiai (.xlsx failas)