કામકાજના દિવસોની ગણતરી કરવા માટે Excel WORKDAY અને NETWORKDAYS કાર્યો

Michael Brown

02-06-2023 એક્સેલ
  • આ શેર કરો
Michael Brown

આ નાનું ટ્યુટોરીયલ એક્સેલ નેટવર્ક ડે અને વર્કડે ફંક્શનનો ઉપયોગ કસ્ટમ વીકએન્ડ પેરામીટર્સ અને રજાઓ સાથે કામકાજના દિવસોની ગણતરી કરવા માટે સમજાવે છે.

માઈક્રોસોફ્ટ એક્સેલ ખાસ કરીને અઠવાડિયાના દિવસોની ગણતરી કરવા માટે રચાયેલ બે કાર્યો પૂરા પાડે છે - WORKDAY અને NETWORKDAYS.

WORKDAY ફંક્શન ભવિષ્યમાં અથવા ભૂતકાળમાં કામકાજના દિવસો N તારીખ આપે છે અને તમે તેનો ઉપયોગ આપેલ તારીખમાં કામકાજના દિવસો ઉમેરવા અથવા બાદ કરવા માટે કરી શકો છો.

<0 NETWORKDAYSફંક્શનનો ઉપયોગ કરીને, તમે ઉલ્લેખિત બે તારીખો વચ્ચેના કામકાજના દિવસોની સંખ્યાની ગણતરી કરી શકો છો.

Excel 2010 અને ઉચ્ચમાં, ઉપરોક્ત કાર્યોના વધુ શક્તિશાળી ફેરફારો ઉપલબ્ધ છે, કામકાજના દિવસો. તમારી એક્સેલ વર્કશીટ્સ.

    એક્સેલ વર્કડે ફંક્શન

    એક્સેલ વર્કડે ફંક્શન એક તારીખ આપે છે જે આપેલ કામકાજના દિવસો છે પ્રારંભ તારીખથી આગળ અથવા પહેલાં. તે સપ્તાહાંત તેમજ તમે ઉલ્લેખિત કોઈપણ રજાઓને બાકાત રાખે છે.

    વર્કડે ફંક્શનનો હેતુ પ્રમાણભૂત કાર્યકારી કેલેન્ડરના આધારે કામકાજના દિવસો, માઇલસ્ટોન્સ અને નિયત તારીખોની ગણતરી કરવા માટે છે, જેમાં શનિવાર અને રવિવાર સપ્તાહાંતના દિવસો છે.

    WORKDAY એ એક્સેલ 2007 - 365 માં બિલ્ટ-ઇન ફંક્શન છે. પહેલાનાં વર્ઝનમાં, તમારે એનાલિસિસને સક્ષમ કરવાની જરૂર છે.જરૂરી વસ્તુઓનો એક નાનો સમૂહ અને બાકીની વસ્તુઓ મેળવો. હું વાંચવા બદલ તમારો આભાર માનું છું અને આગામી અઠવાડિયે અમારા બ્લોગ પર જોવાની આશા રાખું છું!

    ToolPak.

    એક્સેલમાં WORKDAY નો ઉપયોગ કરતી વખતે, તમારે નીચેની દલીલો દાખલ કરવી પડશે:

    WORKDAY(start_date, days, [holidays])

    પ્રથમ 2 દલીલો જરૂરી છે અને છેલ્લી એક વૈકલ્પિક છે :

    • પ્રારંભ_તારીખ - તે તારીખ કે જ્યાંથી અઠવાડિયાના દિવસોની ગણતરી શરૂ કરવી.
    • દિવસો - ઉમેરવા / બાદ કરવા માટેના કામકાજના દિવસોની સંખ્યા start_date થી. સકારાત્મક સંખ્યા ભવિષ્યની તારીખ આપે છે, નકારાત્મક સંખ્યા પાછલી તારીખ પરત કરે છે.
    • રજાઓ - તારીખોની વૈકલ્પિક સૂચિ કે જેને કામકાજના દિવસો તરીકે ગણવી ન જોઈએ. આ ક્યાં તો કોષોની શ્રેણી હોઈ શકે છે જેમાં તમે ગણતરીમાંથી બાકાત રાખવા માંગો છો તે તારીખો હોઈ શકે છે અથવા તારીખોનું પ્રતિનિધિત્વ કરતી સીરીયલ નંબરોની એરે સ્થિરાંક હોઈ શકે છે.

    હવે તમે મૂળભૂત બાબતો જાણો છો, ચાલો જોઈએ કે તમે કેવી રીતે તમારી એક્સેલ વર્કશીટ્સમાં વર્કડે ફંક્શનનો ઉપયોગ કરી શકે છે.

    તારીખમાં કામકાજના દિવસો ઉમેરવા / બાદ કરવા માટે વર્કડેનો ઉપયોગ કેવી રીતે કરવો

    એક્સેલમાં કામકાજના દિવસોની ગણતરી કરવા માટે, આ સરળ નિયમોનું પાલન કરો:

    <6
  • કાર્યદિવસ ઉમેરવા કામકાજના દિવસો, કામકાજના સૂત્રના દિવસો દલીલ તરીકે હકારાત્મક સંખ્યા દાખલ કરો.
  • કામના દિવસોની બાદબાકી કરવા માટે, ઉપયોગ કરો દિવસો દલીલમાં નકારાત્મક સંખ્યા.

    • ધારો કે તમારી પાસે સેલ A2 માં પ્રારંભ તારીખ છે, કોષ B2:B5 માં રજાઓની સૂચિ છે, અને તમે શોધવા માંગો છો તારીખો ભવિષ્ય અને ભૂતકાળમાં 30 કામકાજના દિવસો. તમે નીચેના સૂત્રોનો ઉપયોગ કરીને આ કરી શકો છો:

    પ્રારંભ તારીખમાં 30 કામકાજના દિવસો ઉમેરવા માટે, રજાઓને બાદ કરતાંB2:B5:

    =WORKDAY(A2, 30, B2:B5)

    શરૂઆતની તારીખમાંથી 30 કામકાજના દિવસો બાદ કરવા માટે, B2:B5:

    =WORKDAY(A2, -30, B2:B5)

    આધારિત સપ્તાહના દિવસોની ગણતરી કરવા માટે વર્તમાન તારીખ પર, શરૂઆતની તારીખ તરીકે TODAY() ફંક્શનનો ઉપયોગ કરો:

    આજની તારીખમાં 30 કામકાજના દિવસો ઉમેરવા માટે:

    =WORKDAY(TODAY(), 30)

    પ્રતિ આજની તારીખમાંથી 30 કામકાજના દિવસો બાદ કરો:

    =WORKDAY(TODAY(), -30)

    પ્રારંભની તારીખ સીધી ફોર્મ્યુલામાં આપવા માટે, DATE ફંક્શનનો ઉપયોગ કરો:

    =WORKDAY(DATE(2015,5,6), 30)

    The નીચેના સ્ક્રીનશોટ આ બધા અને થોડા વધુ વર્કડે ફોર્મ્યુલાના પરિણામો દર્શાવે છે:

    અને સ્વાભાવિક રીતે, તમે શરૂઆતની તારીખથી ઉમેરવા/બાદવા માટે કામકાજના દિવસોની સંખ્યા દાખલ કરી શકો છો અમુક કોષ, અને પછી તમારા સૂત્રમાં તે કોષનો સંદર્ભ લો. ઉદાહરણ તરીકે:

    =WORKDAY(A2, C2)

    જ્યાં A2 એ શરૂઆતની તારીખ છે અને C2 એ શરૂઆતની તારીખથી પાછળ (નકારાત્મક સંખ્યાઓ) અથવા આગળ (ધન સંખ્યાઓ) નોન-વીકએન્ડ દિવસોની સંખ્યા છે, રજાઓ નથી બાકાત રાખવા માટે.

    ટીપ. Excel 365 અને 2021 માં, તમે કામકાજના દિવસોની શ્રેણી જનરેટ કરવા માટે SEQUENCE સાથે મળીને WORKDAY નો ઉપયોગ કરી શકો છો.

    Excel WORKDAY.INTL ફંક્શન

    WORKDAY.INTL એ WORKDAY માં વધુ શક્તિશાળી ફેરફાર છે ફંક્શન કે જે કસ્ટમ વીકએન્ડ પેરામીટર્સ સાથે કામ કરે છે. WORKDAY ની સાથે સાથે, તે એવી તારીખ પરત કરે છે જે ભવિષ્યમાં અથવા ભૂતકાળમાં કામના દિવસોની નિર્દિષ્ટ સંખ્યા છે, પરંતુ તમને તે નક્કી કરવા દે છે કે અઠવાડિયાના કયા દિવસોને સપ્તાહના દિવસો ગણવા જોઈએ.

    WORKDAY.INTL કાર્ય માં રજૂ કરવામાં આવ્યું હતુંએક્સેલ 2010 અને તેથી પહેલાના એક્સેલ વર્ઝનમાં ઉપલબ્ધ નથી.

    એક્સેલ WORKDAY.INTL ફંક્શનનું સિન્ટેક્સ નીચે મુજબ છે:

    WORKDAY.INTL(start_date, days, [weekend], [holidays])

    પ્રથમ બે દલીલો જરૂરી છે અને તે વર્કડેની સમાન છે:

    પ્રારંભ_તારીખ - પ્રારંભિક તારીખ.

    દિવસો - ની સંખ્યા કામકાજના દિવસો પહેલા (નકારાત્મક મૂલ્ય) અથવા પછી (હકારાત્મક મૂલ્ય) પ્રારંભ તારીખ. જો days દલીલ દશાંશ સંખ્યા તરીકે પૂરી પાડવામાં આવે છે, તો તે પૂર્ણાંકમાં કાપવામાં આવે છે.

    છેલ્લી બે દલીલો વૈકલ્પિક છે:

    વીકએન્ડ - સ્પષ્ટ કરે છે કે કયા અઠવાડિયાના દિવસો હોવા જોઈએ સપ્તાહના દિવસો તરીકે ગણવામાં આવે છે. નીચે દર્શાવ્યા પ્રમાણે આ કાં તો સંખ્યા અથવા સ્ટ્રિંગ હોઈ શકે છે.

    નંબર વીકએન્ડના દિવસો
    1 અથવા અવગણવામાં આવેલ શનિવાર, રવિવાર
    2 રવિવાર, સોમવાર
    3 સોમવાર, મંગળવાર
    4 મંગળવાર, બુધવાર
    5 બુધવાર, ગુરુવાર
    6 ગુરુવાર, શુક્રવાર
    7 શુક્રવાર, શનિવાર
    11 ફક્ત રવિવાર
    12 માત્ર સોમવારે
    13 ફક્ત મંગળવાર
    14 ફક્ત બુધવાર
    15 ફક્ત ગુરુવારે
    16 ફક્ત શુક્રવાર
    17 ફક્ત શનિવાર

    વીકએન્ડ સ્ટ્રીંગ - સાત 0 અને 1 ની શ્રેણી જે અઠવાડિયાના સાત દિવસનું પ્રતિનિધિત્વ કરે છે,સોમવારથી શરૂ થાય છે. 1 બિન-કાર્યકારી દિવસનું પ્રતિનિધિત્વ કરે છે અને 0 કામના દિવસનું પ્રતિનિધિત્વ કરે છે. ઉદાહરણ તરીકે:

    • "0000011" - શનિવાર અને રવિવાર સપ્તાહાંત છે.
    • "1000001" - સોમવાર અને રવિવાર સપ્તાહાંત છે.

    પ્રથમ નજરે , વીકએન્ડ સ્ટ્રીંગ્સ અનાવશ્યક લાગે છે, પરંતુ મને વ્યક્તિગત રીતે આ પદ્ધતિ વધુ સારી લાગે છે કારણ કે તમે કોઈ પણ નંબર યાદ રાખ્યા વિના ફ્લાય પર સપ્તાહાંતની સ્ટ્રીંગ બનાવી શકો છો.

    રજાઓ - તારીખોની વૈકલ્પિક સૂચિ તમે કાર્યકારી દિવસના કેલેન્ડરમાંથી બાકાત કરવા માંગો છો. આ તારીખો ધરાવતી કોષોની શ્રેણી અથવા તે તારીખોનું પ્રતિનિધિત્વ કરતી સીરીયલ મૂલ્યોની એરે સ્થિરાંક હોઈ શકે છે.

    એક્સેલમાં WORKDAY.INTL નો ઉપયોગ - ફોર્મ્યુલા ઉદાહરણો

    સારું, ઘણું મોટું બલ્ક અમે હમણાં જ ચર્ચા કરેલ સિદ્ધાંતની ખૂબ જ જટિલ અને ગૂંચવણભરી લાગે છે, પરંતુ સૂત્રો પર તમારો હાથ અજમાવવાથી વસ્તુઓ ખરેખર સરળ બની જશે.

    અમારા ડેટાસેટ પર, સેલ A2 માં પ્રારંભ તારીખ અને A5 માં રજાઓની સૂચિ સાથે :A8, ચાલો કસ્ટમ વીકએન્ડ સાથે કામકાજના દિવસોની ગણતરી કરીએ.

    પ્રારંભ તારીખમાં ઉમેરવા 30 કામકાજના દિવસો, શુક્રવાર અને શનિવારની ગણતરી A5:A8 માં શનિ-રવિ અને રજાઓ તરીકે કરવામાં આવે છે:

    =WORKDAY.INTL(A2, 30, 7, A5:A8)

    અથવા

    =WORKDAY.INTL(A2, 30, "0000110", A5:A8)

    શરૂઆતની તારીખથી બાદબાકી 30 કામકાજના દિવસો, રવિવાર અને સોમવાર A5:A8 માં સપ્તાહાંત અને રજાઓ તરીકે ગણવામાં આવે છે બાકાત :

    =WORKDAY.INTL(A2, -30, 2, A5:A8)

    અથવા

    =WORKDAY.INTL(A2, -30, "1000001", A5:A8)

    વર્તમાન તારીખ માં 10 કામકાજના દિવસો ઉમેરવા માટે, રવિવાર એકમાત્ર સપ્તાહાંતનો દિવસ છે, નારજાઓ:

    =WORKDAY.INTL(TODAY(), 10, 11)

    અથવા

    =WORKDAY.INTL(A2, 10, "0000001")

    તમારી એક્સેલ શીટમાં, સૂત્રો આના જેવા દેખાઈ શકે છે:

    <14

    નોંધ. Excel WORKDAY અને WORKDAY.INTL બંને ફંક્શન તારીખો રજૂ કરતા સીરીયલ નંબર આપે છે. તે નંબરોને તારીખો તરીકે દર્શાવવા માટે, નંબરો સાથેના કોષોને પસંદ કરો અને કોષોને ફોર્મેટ કરો સંવાદ ખોલવા માટે Ctrl+1 દબાવો. નંબર ટેબ પર, કેટેગરી સૂચિમાં તારીખ પસંદ કરો અને તમને જોઈતું તારીખ ફોર્મેટ પસંદ કરો. વિગતવાર પગલાંઓ માટે, કૃપા કરીને Excel માં તારીખ ફોર્મેટ કેવી રીતે બદલવું તે જુઓ.

    Excel WORKDAY અને WORKDAY.INTL ભૂલો

    જો તમારું Excel WORKDAY અથવા WORKDAY.INTL ફોર્મ્યુલા ભૂલ આપે છે, તો તેનું કારણ નીચેનામાંથી એક હોઈ શકે છે:

    # NUM! ભૂલ થાય છે જો ક્યાં તો:

    • start_date અને days દલીલોનું સંયોજન અમાન્ય તારીખમાં પરિણમે છે, અથવા
    • WORKDAY.INTL ફંક્શનમાં weekend દલીલ અમાન્ય છે .

    #VALUE! ભૂલ થાય છે જો ક્યાં તો:

    • start_date અથવા holidays માં કોઈપણ મૂલ્ય માન્ય તારીખ નથી, અથવા
    • days દલીલ બિન-સંખ્યાત્મક છે.

    Excel NETWORKDAYS ફંક્શન

    Excel માં NETWORKDAYS ફંક્શન બે તારીખો વચ્ચેના કામકાજના દિવસોની સંખ્યા આપે છે, જેમાં સપ્તાહાંત અને વૈકલ્પિક રીતે, રજાઓ સિવાય તમે સ્પષ્ટ કરો.

    Excel NETWORKDAYS નું વાક્યરચના સાહજિક અને યાદ રાખવામાં સરળ છે:

    NETWORKDAYS(start_date, end_date, [holidays])

    પ્રથમ બે દલીલો ફરજિયાત છે અને ત્રીજી દલીલ છેવૈકલ્પિક:

    • પ્રારંભ_તારીખ - પ્રારંભિક તારીખ જેમાંથી કામકાજના દિવસોની ગણતરી શરૂ કરવાની છે.
    • અંતિમ_તારીખ - જે સમયગાળા માટેનો અંત તમે કામકાજના દિવસોની ગણતરી કરી રહ્યાં છો.

    પ્રારંભ તારીખ અને સમાપ્તિ તારીખ બંનેને કામકાજના પાછલા દિવસોની સંખ્યામાં ગણવામાં આવે છે.

    • રજાઓ - એક વૈકલ્પિક સૂચિ રજાઓ કે જેની ગણતરી કામકાજના દિવસો તરીકે ન કરવી જોઈએ.

    એક્સેલમાં નેટવર્ક ડેઝનો ઉપયોગ કેવી રીતે કરવો - ફોર્મ્યુલા ઉદાહરણ

    ચાલો કહીએ કે તમારી પાસે A2:A5 સેલમાં રજાઓની સૂચિ છે, કૉલમ B માં શરૂઆતની તારીખો, કૉલમ C માં સમાપ્તિ તારીખો, અને તમે જાણવા માંગો છો કે આ તારીખો વચ્ચે કેટલા કામકાજના દિવસો છે. યોગ્ય NETWORKDAYS સૂત્રને આંકવું સરળ છે:

    =NETWORKDAYS(B2, C2, $A$2:$A$5)

    નોંધ લો કે જ્યારે શરૂઆતની તારીખ સમાપ્તિ તારીખ કરતાં ઓછી હોય ત્યારે Excel NETWORKDAYS ફંક્શન હકારાત્મક મૂલ્ય આપે છે અને જો નકારાત્મક મૂલ્ય સમાપ્તિ તારીખ શરૂઆતની તારીખ કરતાં વધુ તાજેતરની છે (પંક્તિ 5માંની જેમ):

    Excel NETWORKDAYS.INTL ફંક્શન

    જેમ કે NETWORKDAYS, Excel ના NETWORKDAYS.INTL ફંક્શન બે તારીખો વચ્ચેના અઠવાડિયાના દિવસોની સંખ્યાની ગણતરી કરે છે, પરંતુ તમને તે સ્પષ્ટ કરવા દે છે કે કયા દિવસોને સપ્તાહના દિવસો તરીકે ગણવા જોઈએ.

    NETWORKDAYS.INTL ફંક્શનનું સિન્ટેક્સ NETWORKDAYS' જેવું જ છે, સિવાય કે તેમાં વધારાના [વીકએન્ડ' હોય ] પરિમાણ જે સૂચવે છે કે અઠવાડિયાના કયા દિવસોને સપ્તાહાંત તરીકે ગણવા જોઈએ.

    NETWORKDAYS.INTL( start_date, end_date, [weekend], [holidays] )

    weekend દલીલ સ્વીકારી શકે છેક્યાં તો સંખ્યા અથવા શબ્દમાળા. WORKDAY.INTL ફંક્શનના weekend પેરામીટરમાં સંખ્યાઓ અને વીકએન્ડ સ્ટ્રિંગ્સ બરાબર સમાન છે.

    NETWORKDAYS.INTL ફંક્શન એક્સેલ 365 - 2010 માં ઉપલબ્ધ છે.

    NETWORKDAYS.INTL નો ઉપયોગ કરીને એક્સેલમાં - ફોર્મ્યુલા ઉદાહરણ

    અગાઉના ઉદાહરણમાંથી તારીખોની સૂચિનો ઉપયોગ કરીને, ચાલો બે તારીખો વચ્ચેના કામકાજના દિવસોની સંખ્યાની ગણતરી કરીએ અને રવિવાર એકમાત્ર સપ્તાહાંતનો દિવસ છે. આ માટે, તમે તમારા NETWORKDAYS.INTL ફોર્મ્યુલાની weekend દલીલમાં નંબર 11 લખો અથવા છ 0 અને એક 1 ("0000001") ની સ્ટ્રિંગ બનાવો:

    =NETWORKDAYS.INTL(B2, C2, 11, $A$2:$A$5)

    અથવા

    =NETWORKDAYS.INTL(B2, C2, "0000001", $A$2:$A$5)

    નીચેનો સ્ક્રીનશોટ સાબિત કરે છે કે બંને ફોર્મ્યુલા એકદમ સરખા પરિણામો આપે છે.

    એક્સેલમાં કામકાજના દિવસોને કેવી રીતે હાઇલાઇટ કરવું

    ઉપયોગ WORKDAY અને WORKDAY.INTL ફંક્શન્સ, તમે તમારી એક્સેલ વર્કશીટ્સમાં માત્ર કામકાજના દિવસોની ગણતરી કરી શકતા નથી પણ તમારા વ્યવસાયના તર્કની જરૂરિયાત મુજબ તેને પ્રકાશિત પણ કરી શકો છો. આ માટે, તમે WORKDAY અથવા WORKDAY.INTL સૂત્ર સાથે શરતી ફોર્મેટિંગ નિયમ બનાવો છો.

    ઉદાહરણ તરીકે, કૉલમ B માં તારીખોની સૂચિમાં, ચાલો ફક્ત ભવિષ્યની તારીખોને જ પ્રકાશિત કરીએ જે આજની તારીખથી 15 કામકાજના દિવસોની અંદર હોય. , A2:A3 કોષોમાં બે રજાઓને બાદ કરતાં. સૌથી સ્પષ્ટ સૂત્ર જે મનમાં આવે છે તે નીચે મુજબ છે:

    =AND($B2>TODAY(), $B2<=WORKDAY(TODAY(), 15, $A$2:$A$3))

    તાર્કિક પરીક્ષણનો પ્રથમ ભાગ ભૂતકાળની તારીખોને કાપી નાખે છે, એટલે કે તમે તપાસો છો કે તારીખ આજની બરાબર છે કે મોટી છે. : $B2>TODAY(). અને બીજા ભાગમાં, તમે ચકાસોસપ્તાહના દિવસો અને ઉલ્લેખિત રજાઓને બાદ કરતાં ભવિષ્યમાં તારીખ 15 અઠવાડિયાના દિવસો કરતાં વધુ ન હોય કે કેમ: $B2<=WORKDAY(TODAY(), 15, $A$2:$A$3)

    સૂત્ર સાચું લાગે છે, પરંતુ એકવાર તમે તેના આધારે નિયમ બનાવશો, તો તમને ખ્યાલ આવશે કે તે ખોટો હાઇલાઇટ કરે છે. તારીખો:

    ચાલો તે શા માટે થાય છે તે શોધવાનો પ્રયાસ કરીએ. સમસ્યા વર્કડે ફંક્શનમાં નથી, કારણ કે કોઈ નિષ્કર્ષ પર આવી શકે છે. કાર્ય યોગ્ય છે, પરંતુ... તે ખરેખર શું કરે છે? તે હવેથી 15 કામકાજના દિવસો પરત કરે છે, જેમાં સપ્તાહાંતના દિવસો (શનિવાર અને રવિવાર) અને કોષ A2:A3 માં રજાઓને બાદ કરતાં.

    ઠીક છે, અને આ સૂત્ર પર આધારિત નિયમ શું કરે છે? તે બધી તારીખોને હાઇલાઇટ કરે છે જે આજની બરાબર અથવા તેનાથી મોટી છે અને WORKDAY ફંક્શન દ્વારા પરત કરવામાં આવેલી તારીખ કરતાં ઓછી છે. તમે જુઓ છો? બધી તારીખો! જો તમે સપ્તાહાંત અને રજાઓને રંગીન કરવા માંગતા નથી, તો તમારે એક્સેલને સ્પષ્ટપણે જણાવવું જરૂરી છે કે તે ન કરવા. તેથી, અમે અમારા ફોર્મ્યુલામાં વધુ બે શરતો ઉમેરી રહ્યા છીએ:

    • સપ્તાહાંતને બાકાત રાખવા માટે WEEKDAY કાર્ય: WEEKDAY($B2, 2)<6
    • રજાને બાકાત રાખવા માટે COUNTIF કાર્ય : COUNTIF($A$2:$A$3, $B2)=0

    નીચેના સ્ક્રીનશોટમાં દર્શાવ્યા પ્રમાણે, સુધારેલ ફોર્મ્યુલા સંપૂર્ણ રીતે કામ કરે છે:

    =AND($B2>TODAY(), $B2<=WORKDAY(TODAY(), 15, $A$2:$A$3), COUNTIF($A$2:$A$3, $B2)=0, WEEKDAY($B2, 2)<6)

    <0

    જેમ તમે જુઓ છો, WORKDAY અને WORKDAY.INTL ફંક્શન્સ એક્સેલમાં કામકાજના દિવસોની ગણતરી ઝડપી અને સરળ બનાવે છે. અલબત્ત, તમારા વાસ્તવિક જીવનના સૂત્રો વધુ સુસંસ્કૃત હોવાની શક્યતા છે, પરંતુ મૂળભૂત બાબતોને જાણવાથી ખૂબ મદદ મળે છે, કારણ કે તમે માત્ર યાદ રાખી શકો છો

    અગાઉની પોસ્ટ ઉદાહરણો સાથે એક્સેલ શરતી ફોર્મેટિંગ ટ્યુટોરીયલ
    આગામી પોસ્ટ એક્સેલ કોષ્ટકોને HTML માં કેવી રીતે કન્વર્ટ કરવું

    માઈકલ બ્રાઉન સોફ્ટવેર ટૂલ્સનો ઉપયોગ કરીને જટિલ પ્રક્રિયાઓને સરળ બનાવવાના જુસ્સા સાથે સમર્પિત ટેકનોલોજી ઉત્સાહી છે. ટેક ઉદ્યોગમાં એક દાયકા કરતાં વધુ અનુભવ સાથે, તેમણે Microsoft Excel અને Outlook, તેમજ Google Sheets અને Docsમાં તેમની કુશળતાને સન્માનિત કરી છે. માઈકલનો બ્લોગ તેના જ્ઞાન અને કુશળતાને અન્ય લોકો સાથે શેર કરવા માટે સમર્પિત છે, ઉત્પાદકતા અને કાર્યક્ષમતામાં સુધારો કરવા માટે અનુસરવામાં સરળ ટીપ્સ અને ટ્યુટોરિયલ્સ પ્રદાન કરે છે. ભલે તમે અનુભવી વ્યાવસાયિક હોવ કે શિખાઉ માણસ, માઈકલનો બ્લોગ આ આવશ્યક સોફ્ટવેર સાધનોમાંથી સૌથી વધુ મેળવવા માટે મૂલ્યવાન આંતરદૃષ્ટિ અને વ્યવહારુ સલાહ આપે છે.