In deze korte handleiding wordt het gebruik uitgelegd van de functies NETWERKDAGEN en WERKDAG in Excel om werkdagen te berekenen met aangepaste weekendparameters en feestdagen.

Microsoft Excel biedt twee functies die speciaal zijn ontworpen voor het berekenen van weekdagen - WERKDAG en NETWERKDAGEN.

De WERKDAG De functie geeft een datum N werkdagen in de toekomst of in het verleden en u kunt deze gebruiken om werkdagen bij een bepaalde datum op te tellen of af te trekken.

Met behulp van de NETWERKDAGEN functie kunt u het aantal werkdagen berekenen tussen twee data die u opgeeft.

In Excel 2010 en hoger zijn krachtigere wijzigingen van bovengenoemde functies beschikbaar, WORKDAY.INTL en NETWORKDAYS.INTL, waarmee u kunt definiëren welke en hoeveel dagen weekenddagen zijn.

Laten we nu elke functie nader bekijken en zien hoe u deze kunt gebruiken om werkdagen te berekenen in uw Excel-werkbladen.

Excel WERKDAG functie

De Excel WORKDAY-functie geeft een datum die een bepaald aantal werkdagen voor of na de begindatum ligt. De weekenden en de door u opgegeven feestdagen worden uitgesloten.

De functie WERKDAG is bedoeld voor het berekenen van werkdagen, mijlpalen en vervaldagen op basis van de standaardwerkkalender, waarbij zaterdag en zondag de weekenddagen zijn.

WERKDAG is een ingebouwde functie in Excel 2007 - 365. In eerdere versies moet u de Analysis ToolPak inschakelen.

Wanneer u WERKDAG in Excel gebruikt, moet u de volgende argumenten invoeren:

De eerste 2 argumenten zijn verplicht en het laatste is optioneel:

• Begin_datum - de datum vanaf wanneer de weekdagen moeten worden geteld.
• Dagen - het aantal werkdagen dat moet worden opgeteld bij / afgetrokken van start_datum. Een positief getal geeft een toekomstige datum, een negatief getal geeft een datum uit het verleden.
• Vakantie - een optionele lijst van data die niet als werkdagen mogen worden geteld. Dit kan een cellenreeks zijn met de data die u wilt uitsluiten van berekeningen, of een arrayconstante van de volgnummers die de data vertegenwoordigen.

Nu u de basis kent, laten we eens kijken hoe u de functie WERKDAG kunt gebruiken in uw Excel-werkbladen.

Hoe WORKDAY gebruiken om werkdagen bij de datum op te tellen of af te trekken

Volg deze eenvoudige regels om werkdagen te berekenen in Excel:

• Naar voeg toe werkdagen, voer een positief getal in als de dagen argument van een WERKDAG-formule.
• Naar trek af werkdagen, gebruik dan een negatief getal in de dagen argument.

Stel, u hebt een begindatum in cel A2, een lijst met feestdagen in de cellen B2:B5, en u wilt de data 30 werkdagen in de toekomst en in het verleden achterhalen. U kunt dit doen met de volgende formules:

30 werkdagen toevoegen aan de begindatum, exclusief vakantiedagen in B2:B5:

=WORKDAY(A2, 30, B2:B5)

Om 30 werkdagen af te trekken van de begindatum, exclusief vakantiedagen in B2:B5:

=WORKDAY(A2, -30, B2:B5)

Om de weekdagen te berekenen op basis van de huidige datum Gebruik de functie TODAY() als begindatum:

Om 30 werkdagen toe te voegen aan de datum van vandaag:

=WORKDAY(TODAY(), 30)

Om 30 werkdagen af te trekken van de datum van vandaag:

=WORKDAY(TODAY(), -30)

Gebruik de functie DATUM om de begindatum rechtstreeks in de formule in te voeren:

=WORKDAY(DATE(2015,5,6), 30)

De volgende schermafbeelding toont de resultaten van al deze en nog enkele andere WERKELIJKE formules:

En natuurlijk kunt u het aantal werkdagen dat u wilt optellen bij / aftrekken van de begindatum invoeren in een of andere cel, en dan in uw formule naar die cel verwijzen. Bijvoorbeeld:

=WERKDAG(A2, C2)

Waarbij A2 de begindatum is en C2 het aantal niet-weekenddagen achter (negatieve getallen) of voor (positieve getallen) de begindatum, zonder feestdagen uit te sluiten.

Tip. In Excel 365 en 2021 kunt u WERKDAG in combinatie met SEQUENCE gebruiken om een reeks werkdagen te genereren.

Excel WERKDAG.INTL functie

WORKDAY.INTL is een krachtigere wijziging van de WORKDAY-functie die werkt met aangepaste weekendparameters Net als WORKDAY geeft het een datum terug die een bepaald aantal werkdagen in de toekomst of in het verleden ligt, maar waarmee u kunt bepalen welke dagen van de week als weekenddagen moeten worden beschouwd.

De functie WORKDAY.INTL werd geïntroduceerd in Excel 2010 en is dus niet beschikbaar in eerdere Excel-versies.

De syntaxis van de Excel WORKDAY.INTL functie is als volgt:

De eerste twee argumenten zijn vereist en lijken op die van WORKDAY:

Begin_datum - de oorspronkelijke datum.

Dagen - het aantal werkdagen vóór (negatieve waarde) of na (positieve waarde) de begindatum. Als de dagen Als het argument een decimaal getal is, wordt het afgekapt tot een geheel getal.

De laatste twee argumenten zijn facultatief:

Weekend - specificeert welke weekdagen moeten worden geteld als weekenddagen. Dit kan zowel een getal als een tekenreeks zijn, zoals hieronder getoond.

Weekend string - een reeks van zeven 0's en 1's die zeven dagen van de week vertegenwoordigen, te beginnen met maandag. 1 staat voor een niet-werkdag en 0 voor een werkdag. Bijvoorbeeld:

• "0000011" - Zaterdag en zondag zijn weekends.
• "1000001" - Maandag en zondag zijn weekends.

Op het eerste gezicht lijken weekend strings overbodig, maar persoonlijk vind ik deze methode beter omdat je on the fly een weekend string kunt maken zonder nummers te hoeven onthouden.

Vakantie - een optionele lijst van data die u wilt uitsluiten van de werkdagkalender. Dit kan een bereik zijn van cellen die de data bevatten, of een arrayconstante van de seriële waarden die deze data vertegenwoordigen.

WERKDAG.INTL gebruiken in Excel - formulevoorbeelden

Welnu, de vrij grote bulk aan theorie die we zojuist hebben besproken lijkt misschien vrij ingewikkeld en verwarrend, maar als je de formules uitprobeert, wordt het echt gemakkelijk.

Op onze dataset, met de begindatum in cel A2 en een lijst van feestdagen in A5:A8, laten we werkdagen berekenen met aangepaste weekends.

Naar voeg toe 30 werkdagen tot de begindatum, vrijdag en zaterdag geteld als weekend en feestdagen in A5:A8 niet meegerekend:

=WORKDAY.INTL(A2, 30, 7, A5:A8)

of

=WORKDAY.INTL(A2, 30, "0000110", A5:A8)

Naar trek af 30 werkdagen vanaf de begindatum, zondag en maandag geteld als weekend en feestdagen in A5:A8 niet meegerekend:

=WORKDAY.INTL(A2, -30, 2, A5:A8)

of

=WORKDAY.INTL(A2, -30, "1000001", A5:A8)

Om 10 werkdagen toe te voegen aan de huidige datum Zondag is de enige weekenddag, geen feestdagen:

=WORKDAY.INTL(TODAY(), 10, 11)

of

=WORKDAY.INTL(A2, 10, "0000001")

In uw Excel-blad kunnen de formules er ongeveer zo uitzien:

Opmerking. Zowel de functies WORKDAY en WORKDAY.INTL van Excel geven seriële getallen die de datums weergeven. Om deze getallen als datums weer te geven, selecteert u de cellen met de getallen en drukt u op Ctrl+1 om de Cellen opmaken dialoog. Op de Nummer tabblad, selecteer Datum in de Categorie en kies het gewenste datumformaat. Voor de gedetailleerde stappen, zie Hoe datumformaat wijzigen in Excel.

Excel WERKDAG en WERKDAG.INTL fouten

Indien uw Excel WORKDAY of WORKDAY.INTL formule een foutmelding geeft, is de reden waarschijnlijk een van de volgende:

#NUM! Er treedt een fout op als

• een combinatie van de begindatum en dagen argumenten resulteert in een ongeldige datum, of
• weekend argument in de WORKDAY.INTL functie is ongeldig.

#WAARDE! Er treedt een fout op als

• begindatum of een willekeurige waarde in vakantie geen geldige datum is, of
• dagen argument niet numeriek is.

Excel NETWERKDAGEN functie

De functie NETWERKDAGEN in Excel geeft het aantal werkdagen tussen twee datums, exclusief weekenden en, optioneel, de door u opgegeven feestdagen.

De syntaxis van Excel NETWERKDAGEN is intuïtief en gemakkelijk te onthouden:

De eerste twee argumenten zijn verplicht en het derde is facultatief:

• Begin_datum - eerste datum vanaf wanneer de telling van de werkdagen begint.
• Einddatum - het einde van de periode waarvoor u werkdagen telt.

Zowel de begindatum als de einddatum worden meegerekend in het geretourneerde aantal werkdagen.

• Vakantie - een facultatieve lijst van feestdagen die niet als werkdagen mogen worden geteld.

Hoe NETWERKDAGEN gebruiken in Excel - formulevoorbeeld

Stel, u hebt een lijst met feestdagen in de cellen A2:A5, begindata in kolom B, einddata in kolom C, en u wilt weten hoeveel werkdagen er tussen deze data liggen. De juiste formule NETWERKDAGEN is gemakkelijk te achterhalen:

=NETWORKDAYS(B2, C2, $A$2:$A$5)

Merk op dat de functie NETWERKDAGEN van Excel een positieve waarde oplevert wanneer de begindatum lager is dan de einddatum, en een negatieve waarde wanneer de einddatum recenter is dan de begindatum (zoals in rij 5):

Excel NETWORKDAYS.INTL functie

De functie NETWORKDAYS.INTL van Excel berekent net als NETWORKDAYS het aantal weekdagen tussen twee datums, maar biedt u de mogelijkheid aan te geven welke dagen als weekenddagen moeten worden geteld.

De syntaxis van de functie NETWORKDAYS.INTL lijkt sterk op die van NETWORKDAYS, behalve dat deze de extra parameter [weekend] heeft, die aangeeft welke dagen van de week als weekend moeten worden geteld.

De weekend kan zowel een getal als een string accepteren. De getallen en weekend strings zijn precies hetzelfde als in de weekend parameter van de functie WORKDAY.INTL.

De functie NETWORKDAYS.INTL is beschikbaar in Excel 365 - 2010.

NETWORKDAYS.INTL gebruiken in Excel - formulevoorbeeld

Laten we met de lijst van data uit het vorige voorbeeld het aantal werkdagen berekenen tussen twee data met zondag als enige weekenddag. Hiervoor typt u nummer 11 in het veld weekend argument van uw NETWORKDAYS.INTL formule of maak een string van zes 0's en één 1 ("0000001"):

=NETWORKDAYS.INTL(B2, C2, 11, $A$2:$A$5)

Of

=NETWORKDAYS.INTL(B2, C2, "0000001", $A$2:$A$5)

Het volgende screenshot bewijst dat beide formules absoluut identieke resultaten opleveren.

Werkdagen markeren in Excel

Met de functies WORKDAY en WORKDAY.INTL kunt u niet alleen werkdagen in uw Excel-werkbladen berekenen, maar deze ook markeren zoals uw bedrijfslogica vereist. Hiervoor maakt u een voorwaardelijke opmaakregel met een WORKDAY- of WORKDAY.INTL-formule.

Laten we bijvoorbeeld in een lijst met data in kolom B alleen toekomstige data markeren die binnen 15 werkdagen vanaf de datum van vandaag liggen, exclusief twee feestdagen in de cellen A2:A3. De meest voor de hand liggende formule die in gedachten komt is de volgende:

=AND($B2>TODAY(), $B2<=WORKDAY(TODAY(), 15, $A$2:$A$3))

In het eerste deel van de logische test worden datums uit het verleden uitgesloten, d.w.z. er wordt gecontroleerd of een datum gelijk is aan of groter is dan vandaag: $B2>TODAY(). En in het tweede deel wordt gecontroleerd of een datum niet meer dan 15 weekdagen in de toekomst ligt, exclusief de weekenddagen en gespecificeerde feestdagen: $B2<=WORKDAY(TODAY(), 15, $A$2:$A$3)

De formule ziet er correct uit, maar zodra u er een regel op baseert, zult u merken dat er verkeerde data in staan:

Laten we proberen uit te zoeken waarom dat gebeurt. Het probleem ligt niet bij de WERKDAG-functie, zoals iemand zou kunnen concluderen. De functie klopt, maar... wat doet hij eigenlijk? Hij geeft een datum 15 werkdagen vanaf nu, exclusief weekenddagen (zaterdag en zondag) en feestdagen in de cellen A2:A3.

Oké, en wat doet de regel op basis van deze formule? Hij markeert ALLE data die gelijk zijn aan of groter zijn dan vandaag en kleiner dan de datum die de WERKDAG-functie oplevert. Ziet u? Alle data! Als u de weekends en feestdagen niet wilt inkleuren, dan moet u Excel expliciet vertellen dat niet te doen. We voegen dus nog twee voorwaarden toe aan onze formule:

• De functie WEEKDAY om weekends uit te sluiten: WEEKDAY($B2, 2)<6
• De COUNTIF-functie om vakanties uit te sluiten: COUNTIF($A$2:$A$3, $B2)=0

Zoals blijkt uit de onderstaande schermafbeelding werkt de verbeterde formule perfect:

=AND($B2>TODAY(), $B2<=WORKDAY(TODAY(), 15, $A$2:$A$3), COUNTIF($A$2:$A$3, $B2)=0, WEEKDAY($B2, 2)<6)

Zoals u ziet, maken de functies WORKDAY en WORKDAY.INTL het berekenen van werkdagen in Excel snel en gemakkelijk. Natuurlijk zullen uw formules in de praktijk waarschijnlijk geavanceerder zijn, maar kennis van de basis helpt enorm, omdat u slechts een klein aantal essentiële zaken kunt onthouden en de rest kunt afleiden. Ik dank u voor het lezen en hoop u volgende week op onze blog te zien!