Αυτά τα παραδείγματα θα σας διδάξουν πώς να κάνετε Vlookup με πολλαπλά κριτήρια, να επιστρέφετε μια συγκεκριμένη περίπτωση ή όλες τις αντιστοιχίες, να κάνετε δυναμικό Vlookup σε πολλαπλά φύλλα και πολλά άλλα.

Πρόκειται για το δεύτερο μέρος της σειράς που θα σας βοηθήσει να αξιοποιήσετε τη δύναμη της VLOOKUP του Excel. Τα παραδείγματα προϋποθέτουν ότι γνωρίζετε πώς λειτουργεί αυτή η συνάρτηση. Αν όχι, είναι λογικό να ξεκινήσετε με τις βασικές χρήσεις της VLOOKUP στο Excel.

Πριν προχωρήσετε παρακάτω, επιτρέψτε μου να σας υπενθυμίσω εν συντομία τη σύνταξη:

Τώρα που όλοι είναι στην ίδια σελίδα, ας δούμε αναλυτικότερα τα παραδείγματα των προηγμένων τύπων VLOOKUP:

Πώς να Vlookup πολλαπλά κριτήρια

Η λειτουργία VLOOKUP του Excel είναι πραγματικά χρήσιμη όταν πρόκειται για αναζήτηση σε μια βάση δεδομένων για μια συγκεκριμένη τιμή. Ωστόσο, στερείται ενός σημαντικού χαρακτηριστικού - το συντακτικό της επιτρέπει μόνο μια τιμή αναζήτησης. Τι γίνεται όμως αν θέλετε να κάνετε αναζήτηση με πολλές συνθήκες; Υπάρχουν μερικές διαφορετικές λύσεις για να επιλέξετε.

Τύπος 1. VLOOKUP με δύο κριτήρια

Ας υποθέσουμε ότι έχετε μια λίστα παραγγελιών και θέλετε να βρείτε την ποσότητα με βάση 2 κριτήρια, Όνομα πελάτη και Προϊόν Ένας παράγοντας που περιπλέκει την κατάσταση είναι ότι κάθε πελάτης παρήγγειλε πολλαπλά προϊόντα, όπως φαίνεται στον παρακάτω πίνακα:

Ένας συνηθισμένος τύπος VLOOKUP δεν θα λειτουργήσει σε αυτή την περίπτωση, επειδή επιστρέφει την πρώτη αντιστοιχία που βρέθηκε με βάση μια μοναδική τιμή αναζήτησης που καθορίζετε.

Για να το ξεπεράσετε αυτό, μπορείτε να προσθέσετε μια βοηθητική στήλη και να συνδέσετε τις τιμές από δύο στήλες αναζήτησης ( Πελάτης και Προϊόν ) εκεί. Είναι σημαντικό ότι η βοηθητική στήλη θα πρέπει να είναι η πιο αριστερά στη στήλη του πίνακα, επειδή εκεί αναζητά πάντα το Excel VLOOKUP την τιμή αναζήτησης.

Έτσι, προσθέστε μια στήλη στα αριστερά του πίνακά σας και αντιγράψτε τον παρακάτω τύπο σε όλη τη στήλη. Αυτό θα γεμίσει τη βοηθητική στήλη με τις τιμές από τις στήλες Β και Γ (ο χαρακτήρας του διαστήματος είναι συνδεδεμένος μεταξύ τους για καλύτερη αναγνωσιμότητα):

=B2&" "&C2

Και στη συνέχεια, χρησιμοποιήστε έναν τυπικό τύπο VLOOKUP και τοποθετήστε και τα δύο κριτήρια στο lookup_value όρισμα, διαχωρισμένα με κενό διάστημα:

=VLOOKUP("Jeremy Sweets", A2:D11, 4, FALSE)

Ή, εισάγετε τα κριτήρια σε ξεχωριστά κελιά (G1 και G2 στην περίπτωσή μας) και συνδέστε αυτά τα κελιά:

=VLOOKUP(G1&" "&G2, A2:D11, 4, FALSE)

Καθώς θέλουμε να επιστρέψουμε μια τιμή από τη στήλη D, η οποία είναι η τέταρτη στον πίνακα, χρησιμοποιούμε το 4 για το col_index_num . range_lookup το όρισμα τίθεται σε FALSE για να γίνει Vlookup ακριβής αντιστοίχιση. Το παρακάτω στιγμιότυπο οθόνης δείχνει το αποτέλεσμα:

Σε περίπτωση που ο πίνακας αναζήτησης βρίσκεται στο άλλο φύλλο , συμπεριλάβετε το όνομα του φύλλου στον τύπο VLOOKUP. Για παράδειγμα:

=VLOOKUP(G1&" "&G2, Orders!A2:D11, 4, FALSE)

Εναλλακτικά, δημιουργήστε μια ονομασμένη περιοχή για τον πίνακα αναζήτησης (π.χ, Παραγγελίες ) για να γίνει ο τύπος πιο ευανάγνωστος:

=VLOOKUP(G1&" "&G2, Orders, 4, FALSE)

Για περισσότερες πληροφορίες, ανατρέξτε στην ενότητα Πώς να κάνετε Vlookup από άλλο φύλλο στο Excel.

Σημείωση: Για να λειτουργήσει σωστά ο τύπος, οι τιμές στη βοηθητική στήλη θα πρέπει να συνδεθούν με τον ίδιο ακριβώς τρόπο όπως και στη στήλη lookup_value Για παράδειγμα, χρησιμοποιήσαμε έναν χαρακτήρα διαστήματος για να διαχωρίσουμε τα κριτήρια τόσο στη βοηθητική στήλη (B2&" "&C2) όσο και στον τύπο VLOOKUP (G1&" "&G2).

Τύπος 2. Excel VLOOKUP με πολλαπλές συνθήκες

Θεωρητικά, μπορείτε να χρησιμοποιήσετε την παραπάνω προσέγγιση για να κάνετε Vlookup σε περισσότερα από δύο κριτήρια. Ωστόσο, υπάρχουν ορισμένες επιφυλάξεις. Πρώτον, μια τιμή αναζήτησης περιορίζεται σε 255 χαρακτήρες και, δεύτερον, ο σχεδιασμός του φύλλου εργασίας μπορεί να μην επιτρέπει την προσθήκη βοηθητικής στήλης.

Ευτυχώς, το Microsoft Excel παρέχει συχνά περισσότερους από έναν τρόπους για να κάνετε το ίδιο πράγμα. Για να κάνετε Vlookup με πολλαπλά κριτήρια, μπορείτε να χρησιμοποιήσετε είτε έναν συνδυασμό INDEX MATCH είτε τη λειτουργία XLOOKUP που εισήχθη πρόσφατα στο Office 365.

Για παράδειγμα, για να κάνετε αναζήτηση με βάση 3 διαφορετικές τιμές ( Ημερομηνία , Όνομα πελάτη και Προϊόν ), χρησιμοποιήστε έναν από τους ακόλουθους τύπους:

=INDEX(D2:D11, MATCH(1, (G1=A2:A11) * (G2=B2:B11) * (G3=C2:C11), 0))

=XLOOKUP(1, (G1=A2:A11) * (G2=B2:B11) * (G3=C2:C11), D2:D11)

Πού:

• G1 είναι το κριτήριο 1 (ημερομηνία)
• G2 είναι το κριτήριο 2 (όνομα πελάτη)
• G3 είναι το κριτήριο 3 (προϊόν)
• A2:A11 είναι η περιοχή αναζήτησης 1 (ημερομηνίες)
• B2:B11 είναι η περιοχή αναζήτησης 2 (ονόματα πελατών)
• C2:C11 είναι η σειρά αναζήτησης 3 (προϊόντα)
• D2:D11 είναι το εύρος επιστροφής (ποσότητα)

Σημείωση. Σε όλες τις εκδόσεις εκτός από το Excel 365, η INDEX MATCH πρέπει να εισαχθεί ως τύπος πίνακα CSE πατώντας Ctrl + Shift + Enter. Στο Excel 365 που υποστηρίζει δυναμικούς πίνακες λειτουργεί επίσης ως κανονικός τύπος.

Για τη λεπτομερή εξήγηση των τύπων, ανατρέξτε στην ενότητα:

• XLOOKUP με πολλαπλά κριτήρια
• Τύπος INDEX MATCH με πολλαπλά κριτήρια

Πώς να χρησιμοποιήσετε το VLOOKUP για να βρείτε το 2ο, 3ο ή nth match

Όπως ήδη γνωρίζετε, το VLOOKUP του Excel μπορεί να αντλήσει μόνο μία τιμή που ταιριάζει, ακριβέστερα, επιστρέφει την πρώτη αντιστοιχία που βρέθηκε. Τι γίνεται όμως αν υπάρχουν πολλές αντιστοιχίες στον πίνακα αναζήτησης και θέλετε να πάρετε τη 2η ή την 3η περίπτωση; Η εργασία ακούγεται αρκετά περίπλοκη, αλλά η λύση υπάρχει!

Τύπος 1. Vlookup Nth instance

Ας υποθέσουμε ότι έχετε τα ονόματα των πελατών σε μια στήλη, τα προϊόντα που αγόρασαν σε μια άλλη και θέλετε να βρείτε το 2ο ή 3ο προϊόν που αγόρασε ένας συγκεκριμένος πελάτης.

Ο απλούστερος τρόπος είναι να προσθέσουμε μια βοηθητική στήλη στα αριστερά του πίνακα, όπως κάναμε στο πρώτο παράδειγμα. Αλλά αυτή τη φορά, θα τη γεμίσουμε με ονόματα πελατών και αριθμούς εμφάνισης όπως " John Doe1 ", " John Doe2 ", κ.λπ.

Για να λάβετε την εμφάνιση, χρησιμοποιήστε τη συνάρτηση COUNTIF με μια μικτή αναφορά εύρους (η πρώτη αναφορά είναι απόλυτη και η δεύτερη σχετική όπως $B$2:B2). Δεδομένου ότι η σχετική αναφορά αλλάζει με βάση τη θέση του κελιού όπου αντιγράφεται ο τύπος, στη γραμμή 3 θα γίνει $B$2:B3, στη γραμμή 4 - $B$2:B4, κ.ο.κ.

Σε συνδυασμό με το όνομα του πελάτη (B2), ο τύπος έχει την εξής μορφή:

=B2&COUNTIF($B$2:B2, B2)

Ο παραπάνω τύπος πηγαίνει στο A2 και στη συνέχεια τον αντιγράφετε σε όσα κελιά χρειάζεται.

Στη συνέχεια, εισαγάγετε το όνομα του στόχου και τον αριθμό εμφάνισης σε ξεχωριστά κελιά (F1 και F2) και χρησιμοποιήστε τον παρακάτω τύπο για να κάνετε Vlookup μια συγκεκριμένη εμφάνιση:

=VLOOKUP(F1&F2, A2:C11, 3, FALSE)

Τύπος 2. Vlookup 2η εμφάνιση

Εάν αναζητάτε τη 2η περίπτωση της τιμής αναζήτησης, τότε μπορείτε να μην χρησιμοποιήσετε τη βοηθητική στήλη. Αντ' αυτού, δημιουργήστε δυναμικά τον πίνακα πίνακα χρησιμοποιώντας τη συνάρτηση INDIRECT μαζί με τη συνάρτηση MATCH:

=VLOOKUP(E1, INDIRECT("A"&(MATCH(E1, A2:A11, 0)+2)&":B11"), 2, FALSE)

Πού:

• E1 είναι η τιμή αναζήτησης
• A2:A11 είναι η περιοχή αναζήτησης
• Το B11 είναι το τελευταίο (κάτω δεξιά) κελί του πίνακα αναζήτησης.

Λάβετε υπόψη ότι ο παραπάνω τύπος είναι γραμμένος για μια συγκεκριμένη περίπτωση όπου τα κελιά δεδομένων στον πίνακα αναζήτησης ξεκινούν από τη γραμμή 2. Εάν ο πίνακάς σας βρίσκεται κάπου στη μέση του φύλλου, χρησιμοποιήστε αυτόν τον καθολικό τύπο, όπου A1 είναι το επάνω αριστερό κελί του πίνακα αναζήτησης που περιέχει μια επικεφαλίδα στήλης:

=VLOOKUP(E1, INDIRECT("A"&(MATCH(E1, A2:A11, 0)+1+ROW(A1))&":B11"), 2, FALSE)

Πώς λειτουργεί αυτή η φόρμουλα

Εδώ είναι το βασικό μέρος του τύπου που δημιουργεί ένα δυναμικό εύρος vlookup :

INDIRECT("A"&(MATCH(E1, A2:A11, 0)+2)&":B11")

Η συνάρτηση MATCH που έχει ρυθμιστεί για ακριβή αντιστοίχιση (0 στο τελευταίο όρισμα) συγκρίνει το όνομα-στόχο (E1) με τη λίστα ονομάτων (A2:A11) και επιστρέφει τη θέση της πρώτης αντιστοιχίας που βρέθηκε, η οποία στην περίπτωσή μας είναι 3. Αυτός ο αριθμός θα χρησιμοποιηθεί ως η αρχική συντεταγμένη γραμμής για το εύρος vlookup, οπότε προσθέτουμε 2 σε αυτόν (+1 για να αποκλείσουμε την πρώτη περίπτωση και +1 για να αποκλείσουμε τη γραμμή 1 με τις επικεφαλίδες των στηλών).Εναλλακτικά, μπορείτε να χρησιμοποιήσετε τη χρήση 1+ROW(A1) για να υπολογίσετε αυτόματα την απαραίτητη προσαρμογή με βάση τη θέση της γραμμής κεφαλίδας (A1 στην περίπτωσή μας).

Ως αποτέλεσμα, λαμβάνουμε την ακόλουθη συμβολοσειρά κειμένου, την οποία η INDIRECT μετατρέπει σε αναφορά περιοχής:

INDIRECT("A"&5&":B11") -> A5:B11

Το εύρος αυτό φτάνει μέχρι το table_array όρισμα της VLOOKUP αναγκάζοντάς την να ξεκινήσει την αναζήτηση στη σειρά 5, αφήνοντας έξω την πρώτη περίπτωση της τιμής αναζήτησης:

VLOOKUP(E1, A5:B11, 2, FALSE)

Πώς να Vlookup και να επιστρέψετε πολλαπλές τιμές στο Excel

Η συνάρτηση VLOOKUP του Excel έχει σχεδιαστεί για να επιστρέφει μόνο μία αντιστοιχία. Υπάρχει τρόπος να κάνετε Vlookup σε πολλαπλές περιπτώσεις; Ναι, υπάρχει, αν και όχι εύκολος. Αυτό απαιτεί τη συνδυασμένη χρήση διαφόρων συναρτήσεων όπως οι INDEX, SMALL και ROW είναι ένας τύπος πίνακα.

Για παράδειγμα, το παρακάτω μπορεί να βρει όλες τις εμφανίσεις της τιμής αναζήτησης F2 στην περιοχή αναζήτησης B2:B16 και να επιστρέψει πολλαπλές αντιστοιχίες από τη στήλη C:

{=IFERROR(INDEX($C$2:$C$11, SMALL(IF($F$1=$B$2:$B$11, ROW($C$2:$C$11)-1,""), ROW()-1)),"")}

Υπάρχουν 2 τρόποι για να εισαγάγετε τον τύπο στο φύλλο εργασίας σας:

1. Πληκτρολογήστε τον τύπο στο πρώτο κελί, πατήστε Ctrl + Shift + Enter και, στη συνέχεια, σύρετέ τον προς τα κάτω σε μερικά ακόμη κελιά.
2. Επιλέξτε πολλά γειτονικά κελιά σε μια στήλη (F1:F11 στην παρακάτω εικόνα), πληκτρολογήστε τον τύπο και πατήστε Ctrl + Shift + Enter για να τον ολοκληρώσετε.

Σε κάθε περίπτωση, ο αριθμός των κελιών στα οποία εισάγετε τον τύπο θα πρέπει να είναι ίσος ή μεγαλύτερος από τον μέγιστο αριθμό πιθανών αντιστοιχιών.

Για τη λεπτομερή εξήγηση της λογικής του τύπου και περισσότερα παραδείγματα, ανατρέξτε στην ενότητα Πώς να VLOOKUP πολλαπλές τιμές στο Excel.

Πώς να κάνετε Vlookup σε γραμμές και στήλες (αμφίδρομη αναζήτηση)

Αμφίδρομη αναζήτηση (ή αλλιώς αναζήτηση μήτρας ή 2-dimentional lookup ) είναι μια φανταχτερή λέξη για την αναζήτηση μιας τιμής στο σημείο τομής μιας συγκεκριμένης γραμμής και στήλης. Υπάρχουν μερικοί διαφορετικοί τρόποι για να κάνετε δισδιάστατη αναζήτηση στο Excel, αλλά δεδομένου ότι το επίκεντρο αυτού του σεμιναρίου είναι η συνάρτηση VLOOKUP, θα τη χρησιμοποιήσουμε φυσικά.

Για αυτό το παράδειγμα, θα πάρουμε τον παρακάτω πίνακα με τις μηνιαίες πωλήσεις και θα επεξεργαστούμε έναν τύπο VLOOKUP για να ανακτήσουμε τον αριθμό πωλήσεων για ένα συγκεκριμένο στοιχείο σε έναν συγκεκριμένο μήνα.

Με ονόματα στοιχείων σε A2:A9, ονόματα μηνών σε B1:F1, το στοιχείο-στόχο σε I1 και τον μήνα-στόχο σε I2, ο τύπος έχει ως εξής:

=VLOOKUP(I1, A2:F9, MATCH(I2, A1:F1, 0), FALSE)

Πώς λειτουργεί αυτή η φόρμουλα

Ο πυρήνας του τύπου είναι η τυπική συνάρτηση VLOOKUP που ψάχνει για μια ακριβή αντιστοιχία με την τιμή αναζήτησης στο I1. Αλλά επειδή δεν γνωρίζουμε σε ποια ακριβώς στήλη βρίσκονται οι πωλήσεις για ένα συγκεκριμένο μήνα, δεν μπορούμε να δώσουμε τον αριθμό της στήλης απευθείας στη συνάρτηση col_index_num Για να βρούμε αυτή τη στήλη, χρησιμοποιούμε την ακόλουθη συνάρτηση MATCH:

MATCH(I2, A1:F1, 0)

Μεταφρασμένος στα αγγλικά, ο τύπος λέει: αναζητήστε την τιμή I2 στο A1:F1 και επιστρέψτε τη σχετική θέση της στον πίνακα. Δίνοντας 0 στο 3ο όρισμα, δίνετε εντολή στη MATCH να βρει την τιμή ακριβώς ίση με την τιμή αναζήτησης (είναι σαν να χρησιμοποιείτε FALSE για το range_lookup όρισμα του VLOOKUP).

Από το Μαρ βρίσκεται στην 4η στήλη του πίνακα αναζήτησης, η συνάρτηση MATCH επιστρέφει 4, η οποία πηγαίνει απευθείας στην col_index_num επιχείρημα του VLOOKUP:

VLOOKUP(I1, A2:F9, 4, FALSE)

Προσέξτε ότι παρόλο που τα ονόματα των μηνών ξεκινούν από τη στήλη Β, χρησιμοποιούμε το A1:I1 για τον πίνακα αναζήτησης. Αυτό γίνεται προκειμένου ο αριθμός που επιστρέφει η MATCH να αντιστοιχεί στη θέση της στήλης στο table_array του VLOOKUP.

Για να μάθετε περισσότερους τρόπους εκτέλεσης αναζήτησης πινάκων στο Excel, ανατρέξτε στην ενότητα INDEX MATCH MATCH και άλλες φόρμουλες για δισδιάστατη αναζήτηση.

Πώς να κάνετε πολλαπλές Vlookup στο Excel (εμφωλευμένη Vlookup)

Μερικές φορές μπορεί να συμβεί να μην έχουν ούτε μία κοινή στήλη ο κύριος πίνακας και ο πίνακας αναζήτησης, γεγονός που σας εμποδίζει να κάνετε μια Vlookup μεταξύ των δύο πινάκων. Ωστόσο, υπάρχει ένας άλλος πίνακας, ο οποίος δεν περιέχει τις πληροφορίες που αναζητάτε, αλλά έχει μία κοινή στήλη με τον κύριο πίνακα και μία άλλη κοινή στήλη με τον πίνακα αναζήτησης.

Στην παρακάτω εικόνα απεικονίζεται η κατάσταση:

Ο στόχος είναι να αντιγράψουμε τις τιμές στον κύριο πίνακα με βάση Αναγνωριστικά στοιχείων Το πρόβλημα είναι ότι ο πίνακας που περιέχει τις τιμές δεν έχει το Αναγνωριστικά στοιχείων , πράγμα που σημαίνει ότι θα πρέπει να κάνουμε δύο Vlookups σε έναν τύπο.

Για λόγους ευκολίας, ας δημιουργήσουμε πρώτα μερικές ονομαστικές περιοχές:

• Ο πίνακας αναζήτησης 1 ονομάζεται Προϊόντα (D3:E10)
• Ο πίνακας αναζήτησης 2 ονομάζεται Τιμές ( G3:H10 )

Οι πίνακες μπορούν να βρίσκονται στο ίδιο ή σε διαφορετικά φύλλα εργασίας.

Και τώρα, θα εκτελέσουμε το λεγόμενο διπλό Vlookup , ή αλλιώς εμφωλευμένη Vlookup .

Πρώτον, φτιάξτε έναν τύπο VLOOKUP για να βρείτε το όνομα του προϊόντος στον πίνακα αναζήτησης 1 (με όνομα Προϊόντα ) με βάση το αναγνωριστικό του στοιχείου (A3):

=VLOOKUP(A3, Προϊόντα, 2, FALSE)

Στη συνέχεια, βάλτε τον παραπάνω τύπο στο lookup_value όρισμα μιας άλλης συνάρτησης VLOOKUP για να αντλήσει τιμές από τον πίνακα Lookup 2 (με όνομα Τιμές ) με βάση το όνομα του προϊόντος που επιστρέφεται από το εμφωλευμένο VLOOKUP:

=VLOOKUP(VLOOKUP(A3, Προϊόντα, 2, FALSE), Τιμές, 2, FALSE)

Το παρακάτω στιγμιότυπο οθόνης δείχνει τον ένθετο τύπο Vlookup σε δράση:

Πώς να Vlookup πολλαπλά φύλλα δυναμικά

Μερικές φορές, μπορεί να έχετε δεδομένα στην ίδια μορφή κατανεμημένα σε διάφορα φύλλα εργασίας. Και ο στόχος σας είναι να αντλήσετε δεδομένα από ένα συγκεκριμένο φύλλο ανάλογα με την τιμή κλειδί σε ένα συγκεκριμένο κελί.

Αυτό μπορεί να γίνει ευκολότερα κατανοητό από ένα παράδειγμα. Ας υποθέσουμε ότι έχετε μερικές περιφερειακές εκθέσεις πωλήσεων στην ίδια μορφή και θέλετε να λάβετε τα στοιχεία πωλήσεων για ένα συγκεκριμένο προϊόν σε ορισμένες περιοχές:

Όπως και στο προηγούμενο παράδειγμα, ξεκινάμε με τον ορισμό μερικών ονομάτων:

• Η περιοχή A2:B5 στο φύλλο CA ονομάζεται CA_Πωλήσεις .
• Η περιοχή A2:B5 στο φύλλο FL ονομάζεται FL_Πωλήσεις .
• Η περιοχή A2:B5 στο φύλλο KS ονομάζεται KS_Πωλήσεις .

Όπως μπορείτε να δείτε, όλες οι ονομαστικές σειρές έχουν ένα κοινό μέρος ( Πωλήσεις ) και μοναδικά μέρη ( CA , FL , KS ). Βεβαιωθείτε ότι θα ονομάσετε τις σειρές σας με παρόμοιο τρόπο, καθώς αυτό είναι απαραίτητο για τον τύπο που πρόκειται να δημιουργήσουμε.

Τύπος 1. INDIRECT VLOOKUP για δυναμική άντληση δεδομένων από διαφορετικά φύλλα

Εάν η εργασία σας είναι να ανακτήσετε δεδομένα από πολλά φύλλα, ένας τύπος VLOOKUP INDIRECT είναι η καλύτερη λύση - συμπαγής και εύκολα κατανοητός.

Για το συγκεκριμένο παράδειγμα, οργανώνουμε τον συνοπτικό πίνακα με τον ακόλουθο τρόπο:

• Εισάγετε τα προϊόντα που σας ενδιαφέρουν στα A2 και A3. Αυτές είναι οι τιμές αναζήτησης.
• Εισάγετε τα μοναδικά μέρη των ονομαστικών περιοχών στα B1, C1 και D1.

Και τώρα, συνδέουμε το κελί που περιέχει το μοναδικό μέρος (B1) με το κοινό μέρος ("_Sales") και τροφοδοτούμε την προκύπτουσα συμβολοσειρά στο INDIRECT:

INDIRECT(B$1&"_Πωλήσεις")

Η συνάρτηση INDIRECT μετατρέπει τη συμβολοσειρά σε ένα όνομα που μπορεί να καταλάβει το Excel και το τοποθετείτε στο πεδίο table_array επιχείρημα του VLOOKUP:

=VLOOKUP($A2, INDIRECT(B$1&"_Πωλήσεις"), 2, FALSE)

Ο παραπάνω τύπος πηγαίνει στο Β2 και στη συνέχεια τον αντιγράφετε προς τα κάτω και προς τα δεξιά.

Προσέξτε ότι, στην τιμή αναζήτησης ($A2), έχουμε κλειδώσει τη συντεταγμένη της στήλης με απόλυτη αναφορά κελιού, ώστε η στήλη να παραμένει σταθερή όταν ο τύπος αντιγράφεται προς τα δεξιά. Στην αναφορά B$1, κλειδώσαμε τη γραμμή επειδή θέλουμε η συντεταγμένη της στήλης να αλλάζει και να παρέχει ένα κατάλληλο μέρος ονόματος στο INDIRECT ανάλογα με τη στήλη στην οποία αντιγράφεται ο τύπος:

Εάν ο κύριος πίνακάς σας είναι οργανωμένος διαφορετικά, οι τιμές αναζήτησης σε μια γραμμή και τα μοναδικά μέρη των ονομάτων της περιοχής σε μια στήλη, τότε θα πρέπει να κλειδώσετε τη συντεταγμένη γραμμής στην τιμή αναζήτησης (B$1) και τη συντεταγμένη στήλης στα μέρη των ονομάτων ($A2):

=VLOOKUP(B$1, INDIRECT($A2&"_Πωλήσεις"), 2, FALSE)

Τύπος 2. VLOOKUP και εμφωλευμένα IF για την αναζήτηση πολλαπλών φύλλων

Σε περίπτωση που έχετε μόνο δύο ή τρία φύλλα αναζήτησης, μπορείτε να χρησιμοποιήσετε έναν αρκετά απλό τύπο VLOOKUP με ένθετες συναρτήσεις IF για να επιλέξετε το σωστό φύλλο με βάση την τιμή κλειδί σε ένα συγκεκριμένο κελί:

=VLOOKUP($A2, IF(B$1="CA", CA_Sales, IF(B$1="FL", FL_Sales, IF(B$1="KS", KS_Sales,""))), 2, FALSE)

Όπου $A2 είναι η τιμή αναζήτησης (όνομα στοιχείου) και B$1 είναι η τιμή κλειδί (κατάσταση):

Σε αυτή την περίπτωση, δεν χρειάζεται απαραίτητα να ορίσετε ονόματα και μπορείτε να χρησιμοποιήσετε εξωτερικές αναφορές για να αναφερθείτε σε άλλο φύλλο ή βιβλίο εργασίας.

Για περισσότερα παραδείγματα τύπων, ανατρέξτε στην ενότητα Πώς να κάνετε VLOOKUP σε πολλαπλά φύλλα στο Excel.

Αυτός είναι ο τρόπος χρήσης του VLOOKUP στο Excel. Σας ευχαριστώ για την ανάγνωση και ελπίζω να σας δω στο blog μας την επόμενη εβδομάδα!

Βιβλίο ασκήσεων για κατέβασμα

Παραδείγματα τύπων VLOOKUP για προχωρημένους (.xlsx αρχείο)