Այս օրինակները կսովորեցնեն ձեզ, թե ինչպես Vlookup մի քանի չափանիշներ, վերադարձնել որոշակի օրինակ կամ բոլոր համընկնումները, կատարել դինամիկ Vlookup բազմաթիվ թերթերում և ավելին:

Դա երկրորդ մասն է: շարքը, որը կօգնի ձեզ օգտագործել Excel VLOOKUP-ի հզորությունը: Օրինակները ենթադրում են, որ դուք գիտեք, թե ինչպես է աշխատում այս գործառույթը: Եթե ​​ոչ, ապա պետք է սկսել Excel-ում VLOOKUP-ի հիմնական կիրառություններից:

Նախքան հետագա անցնելը, թույլ տվեք հակիրճ հիշեցնել ձեզ շարահյուսությունը.

Այժմ, երբ բոլորը նույն էջում են, եկեք ավելի սերտ նայենք առաջադեմ VLOOKUP բանաձևի օրինակներին. VLOOKUP ֆունկցիան իսկապես օգտակար է, երբ խոսքը վերաբերում է տվյալների բազայում որոշակի արժեքի որոնմանը: Այնուամենայնիվ, այն չունի կարևոր հատկանիշ՝ նրա շարահյուսությունը թույլ է տալիս գտնել ընդամենը մեկ որոնման արժեք: Բայց ի՞նչ, եթե ցանկանում եք փնտրել մի քանի պայմաններով: Կան մի քանի տարբեր լուծումներ, որոնցից կարող եք ընտրել:

Formula 1. VLOOKUP երկու չափանիշներով

Ենթադրենք, որ ունեք պատվերների ցանկ և ցանկանում եք գտնել քանակությունը 2 չափանիշների հիման վրա, Հաճախորդի անուն և Ապրանք : Բարդացնող գործոնն այն է, որ յուրաքանչյուր հաճախորդ պատվիրել է մի քանի ապրանք, ինչպես ցույց է տրված ստորև բերված աղյուսակում. համընկնում հիմնված ատարածաշրջաններ:

Ինչպես նախորդ օրինակում, մենք սկսում ենք մի քանի անուններ սահմանելով.

• A2:B5 միջակայքը CA թերթում կոչվում է CA_Sales .
• A2:B5 միջակայքը FL թերթում կոչվում է FL_Sales :
• A2:B5 միջակայքը KS թերթում կոչվում է KS_Sales .

Ինչպես տեսնում եք, բոլոր անվանված միջակայքերը ունեն ընդհանուր մաս ( Վաճառք ) և եզակի մասեր ( CA , FL , KS ): Խնդրում ենք, համոզվեք, որ անվանեք ձեր միջակայքերը նույն ձևով, քանի որ դա կարևոր է այն բանաձևի համար, որը մենք պատրաստվում ենք ստեղծել:

Բանաձև 1. ԱՆՈՒՂԻՂ VLOOKUP՝ տարբեր թերթերից տվյալները դինամիկ կերպով քաշելու համար

Եթե ձեր առաջադրանքը մի քանի թերթերից տվյալներ ստանալն է, VLOOKUP INDIRECT բանաձևը լավագույն լուծումն է՝ կոմպակտ և հեշտ հասկանալի:

Այս օրինակի համար մենք ամփոփ աղյուսակը կազմակերպում ենք հետևյալ կերպ.

• Մուտքագրեք հետաքրքրող ապրանքները A2 և A3: Սրանք մեր որոնման արժեքներն են:
• Մուտքագրեք նշված ընդգրկույթների եզակի մասերը B1, C1 և D1-ում:

Եվ այժմ մենք միացնում ենք եզակի մասը (B1) պարունակող բջիջը: ընդհանուր մասով ("_Sales") և ստացված տողը սնուցեք INDIRECT:

INDIRECT(B$1&"_Sales")

INDIRECT ֆունկցիան տողը փոխակերպում է Excel-ի համար հասկանալի անվան, և այն դնում եք VLOOKUP-ի table_array արգումենտը.

=VLOOKUP($A2, INDIRECT(B$1&"_Sales"), 2, FALSE)

Վերոնշյալ բանաձևը գնում է B2, այնուհետև պատճենում եք այն ներքև և աջ:

Խնդրում ենք: ուշադրություն դարձրեք, որ որոնման արժեքում ($A2),մենք կողպել ենք սյունակի կոորդինատը բացարձակ բջջային հղումով, որպեսզի սյունակը մնա ֆիքսված, երբ բանաձևը պատճենվում է աջ կողմում: B$1 տեղեկանքում մենք կողպեցինք տողը, քանի որ ցանկանում ենք, որ սյունակի կոորդինատը փոխվի և համապատասխան անվանական մաս մատակարարի INDIRECT-ին, կախված այն սյունակից, որտեղ պատճենված է բանաձևը.

Եթե ձեր հիմնական աղյուսակը այլ կերպ է կազմակերպված, որոնման արժեքները անընդմեջ և տիրույթի անունների եզակի մասերը սյունակում, ապա դուք պետք է կողպեք տողի կոորդինատը որոնման արժեքում (B$1) և սյունակի կոորդինատը անունների մասերում: ($A2):

=VLOOKUP(B$1, INDIRECT($A2&"_Sales"), 2, FALSE)

Բանաձև 2. VLOOKUP և ներկառուցված IF-ներ մի քանի թերթեր փնտրելու համար

Այն իրավիճակում, երբ ունեք Ընդամենը երկու կամ երեք որոնման թերթիկ, դուք կարող եք օգտագործել բավականին պարզ VLOOKUP բանաձև՝ տեղադրված IF գործառույթներով, որպեսզի ընտրեք ճիշտ թերթը՝ հիմնվելով որոշակի բջջի հիմնական արժեքի վրա.

=VLOOKUP($A2, IF(B$1="CA", CA_Sales, IF(B$1="FL", FL_Sales, IF(B$1="KS", KS_Sales,""))), 2, FALSE)

Where $A2 փնտրման արժեքն է (տարրի անվանումը), իսկ B$1-ը հիմնական արժեքն է (վիճակը):

Այս դեպքում պարտադիր չէ, որ անուններ սահմանեք և կարող եք օգտագործել արտաքին: հղումներ՝ մեկ այլ թերթիկ կամ աշխատանքային գրքույկ հղում կատարելու համար:

Լրացուցիչ բանաձևի համար exa mples, խնդրում ենք տե՛ս Ինչպես VLOOKUP-ը կատարել Excel-ում մի քանի թերթերի վրա:

Այսպես կարելի է օգտագործել VLOOKUP-ը Excel-ում: Ես շնորհակալություն եմ հայտնում կարդալու համար և հուսով եմ, որ հաջորդ շաբաթ կտեսնենք ձեզ մեր բլոգում:

Ներբեռնելու համար վարժեցեք աշխատանքային գրքույկը

Ընդլայնված VLOOKUP բանաձևի օրինակներ (.xlsxֆայլ)

Սա հաղթահարելու համար կարող եք ավելացնել օգնական սյունակ և միավորել երկու որոնման սյունակների արժեքները ( Հաճախորդ և Ապրանք ): Կարևոր է, որ օգնական սյունակը լինի ամենաձախ սյունակը աղյուսակի զանգվածում, քանի որ այն այնտեղ է, որտեղ Excel VLOOKUP-ը միշտ փնտրում է որոնման արժեքը: աղյուսակը և պատճենեք ստորև բերված բանաձևը այդ սյունակում: Սա օգնական սյունակը կլցնի B և C սյունակների արժեքներով (ավելի լավ ընթեռնելիության համար տարածության նիշը միացված է միջև):

=B2&" "&C2

Եվ այնուհետև օգտագործեք ստանդարտ VLOOKUP բանաձև և տեղադրեք: երկու չափանիշներն էլ lookup_value արգումենտում` առանձնացված բացատով.

=VLOOKUP("Jeremy Sweets", A2:D11, 4, FALSE)

Կամ մուտքագրեք չափանիշները առանձին բջիջներում (մեր դեպքում G1 և G2) և միացրեք դրանք: բջիջներ՝

=VLOOKUP(G1&" "&G2, A2:D11, 4, FALSE)

Քանի որ մենք ցանկանում ենք վերադարձնել արժեք D սյունակից, որը չորրորդն է աղյուսակի զանգվածում, մենք օգտագործում ենք 4-ը col_index_num -ի համար: range_lookup արգումենտը դրված է FALSE-ի և ճշգրիտ համընկնման համար Vlookup: Ստորև բերված սքրինշոթը ցույց է տալիս արդյունքը.

Եթե ձեր որոնման աղյուսակը գտնվում է այլ թերթում , ներառեք թերթի անունը ձեր VLOOKUP բանաձևում: Օրինակ՝

=VLOOKUP(G1&" "&G2, Orders!A2:D11, 4, FALSE)

Այլընտրանքով, որոնման աղյուսակի համար ստեղծեք անվանված տիրույթ (ասենք, Պատվերներ ), բանաձևն ավելի հեշտ ընթեռնելի դարձնելու համար.

=VLOOKUP(G1&" "&G2, Orders, 4, FALSE)

Լրացուցիչ տեղեկությունների համար տե՛ս Ինչպես անելVlookup մեկ այլ թերթիկից Excel-ում:

Նշում. Որպեսզի բանաձևը ճիշտ աշխատի, օգնական սյունակի արժեքները պետք է միացվեն ճիշտ այնպես, ինչպես lookup_value արգումենտում: Օրինակ՝ մենք օգտագործեցինք բացատ նիշ՝ թե՛ օգնական սյունակում (B2&" "&C2) և "VLOOKUP" բանաձևի (G1&" "&G2" չափորոշիչներն առանձնացնելու համար:

Բանաձև 2. Excel VLOOKUP բազմաթիվ պայմաններով

Տեսականորեն, դուք կարող եք օգտագործել վերը նշված մոտեցումը Vlookup-ի նկատմամբ երկուից ավելի չափանիշներ: Այնուամենայնիվ, կան մի քանի նախազգուշացումներ. Նախ, որոնման արժեքը սահմանափակվում է 255 նիշով, և երկրորդը, աշխատաթերթի դիզայնը կարող է թույլ չտալ ավելացնել օգնական սյունակ:

Բարեբախտաբար, Microsoft Excel-ը հաճախ տրամադրում է նույն բանն անելու մեկից ավելի եղանակներ: Բազմաթիվ չափանիշներ Vlookup-ի համար կարող եք օգտագործել կամ INDEX MATCH համակցությունը կամ XLOOKUP ֆունկցիան, որը վերջերս ներդրվել է Office 365-ում:

Օրինակ՝ փնտրելու համար 3 ​​տարբեր արժեքների հիման վրա ( Date , Հաճախորդի անուն և Ապրանք ), օգտագործեք հետևյալ բանաձևերից մեկը.

=INDEX(D2:D11, MATCH(1, (G1=A2:A11) * (G2=B2:B11) * (G3=C2:C11), 0))

=XLOOKUP(1, (G1=A2:A11) * (G2=B2:B11) * (G3=C2:C11), D2:D11)

Որտեղ:

• G1-ը 1-ին չափանիշն է (ամսաթիվ)
• G2-ը 2-րդ չափանիշն է (հաճախորդի անուն)
• G3-ը 3-րդ չափանիշն է (արտադրանք)
• A2:A11-ը որոնում է միջակայք 1 (ամսաթվեր)
• B2:B11-ը որոնման տիրույթ է 2 (հաճախորդների անուններ)
• C2:C11-ը որոնման տիրույթ 3 (ապրանքներ)
• D2:D11-ը վերադարձն է միջակայք (քանակ)

Ծանոթագրություն. Բոլոր տարբերակներում, բացի Excel 365, INDEXMATCH-ը պետք է մուտքագրվի որպես CSE զանգվածի բանաձև՝ սեղմելով Ctrl + Shift + Enter: Excel 365-ում, որն աջակցում է դինամիկ զանգվածներին, այն նաև աշխատում է որպես սովորական բանաձև:

Բանաձևերի մանրամասն բացատրության համար տե՛ս.

• XLOOKUP բազմաթիվ չափանիշներով
• INDEX MATCH բանաձևը բազմաթիվ չափանիշներով

Ինչպես օգտագործիր VLOOKUP-ը՝ 2-րդ, 3-րդ կամ n-րդ համընկնումը ստանալու համար

Ինչպես արդեն գիտեք, Excel VLOOKUP-ը կարող է ստանալ միայն մեկ համապատասխան արժեք, ավելի ճիշտ՝ վերադարձնում է առաջին գտնված համընկնումը: Բայց ի՞նչ, եթե ձեր որոնման զանգվածում կան մի քանի համընկնումներ, և դուք ցանկանում եք ստանալ 2-րդ կամ 3-րդ օրինակը: Առաջադրանքը բավականին բարդ է թվում, բայց լուծումն իսկապես գոյություն ունի:

Formula 1. Vlookup N-րդ օրինակ

Ենթադրենք, որ դուք ունեք հաճախորդների անունները մի սյունակում, ապրանքները, որոնք նրանք գնել են մեկ այլ սյունակում, և դուք փնտրում եք գտնել տվյալ հաճախորդի կողմից գնված 2-րդ կամ 3-րդ ապրանքը:

Ամենապարզ ձևը աղյուսակի ձախ կողմում օգնական սյունակ ավելացնելն է, ինչպես մենք արեցինք առաջին օրինակում: Բայց այս անգամ մենք այն կհամալրենք հաճախորդների անուններով և դեպքերի համարներով, ինչպիսիք են « John Doe1 », « John Doe2 » և այլն:

Իրադարձությունը ստանալու համար, օգտագործեք COUNTIF ֆունկցիան խառը տիրույթի հղումով (առաջին հղումը բացարձակ է, իսկ երկրորդը հարաբերական է, ինչպես $B$2:B2): Քանի որ հարաբերական հղումը փոխվում է՝ հիմնվելով բանաձևի պատճենված բջիջի դիրքի վրա, 3-րդ տողում այն ​​կդառնա $B$2:B3, 4-րդ շարքում՝$B$2:B4 և այլն:

Կապված հաճախորդի անվան հետ (B2), բանաձևը ստանում է հետևյալ ձևը.

=B2&COUNTIF($B$2:B2, B2)

Վերոնշյալ բանաձևը գնում է A2 , և այնուհետև դուք պատճենում եք այն այնքան բջիջներում, որքան անհրաժեշտ է:

Այնուհետև մուտքագրեք թիրախի անունը և դեպքի համարը առանձին բջիջներում (F1 և F2) և օգտագործեք ստորև բերված բանաձևը հատուկ երևույթը հավաքելու համար.

=VLOOKUP(F1&F2, A2:C11, 3, FALSE)

Բանաձև 2. Vlookup 2-րդ դեպք

Եթե փնտրում եք որոնման արժեքի 2-րդ օրինակը, ապա կարող եք անել առանց օգնական սյունակի: Փոխարենը, ստեղծեք աղյուսակի զանգվածը դինամիկ կերպով՝ օգտագործելով INDIRECT ֆունկցիան MATCH-ի հետ միասին.

=VLOOKUP(E1, INDIRECT("A"&(MATCH(E1, A2:A11, 0)+2)&":B11"), 2, FALSE)

Որտեղ.

• E1-ը որոնման արժեքն է
• A2:A11-ը որոնման տիրույթն է
• B11-ը որոնման աղյուսակի վերջին (ներքևի աջ) բջիջն է

Խնդրում ենք նկատի ունենալ, որ վերը նշված բանաձևը գրված է կոնկրետ դեպքի համար, երբ որոնման աղյուսակի տվյալների բջիջները սկսվում են 2-րդ շարքում: Եթե ձեր աղյուսակը գտնվում է թերթի մեջտեղում, օգտագործեք այս ունիվերսալ բանաձևը, որտեղ A1-ը որոնման աղյուսակի վերևի ձախ բջիջն է, որը պարունակում է. սյունակի վերնագիր.

=VLOOKUP(E1, INDIRECT("A"&(MATCH(E1, A2:A11, 0)+1+ROW(A1))&":B11"), 2, FALSE)

Ինչպես է աշխատում այս բանաձևը

Ահա բանաձևի հիմնական մասը, որը ստեղծում է դինամիկ vlookup միջակայք :

INDIRECT("A"&(MATCH(E1, A2:A11, 0)+2)&":B11")

MATCH ֆունկցիան, որը կազմաձևված է ճշգրիտ համընկնման համար (0-ը վերջին արգումենտում) համեմատում է թիրախի անունը (E1) անունների ցանկի հետ (A2:A11) և վերադարձնում է առաջին գտնվածի դիրքը: համընկնում, որը 3 էմեր դեպքում. Այս թիվը կօգտագործվի որպես մեկնարկային տողի կոորդինատ vlookup միջակայքի համար, ուստի մենք դրան ավելացնում ենք 2 (+1՝ առաջին օրինակը բացառելու համար և +1՝ 1-ին տողը սյունակների վերնագրերով բացառելու համար): Որպես այլընտրանք, դուք կարող եք օգտագործել 1+ROW(A1) անհրաժեշտ ճշգրտումը ավտոմատ կերպով հաշվարկելու համար՝ հիմնվելով վերնագրի տողի դիրքի վրա (մեր դեպքում՝ A1):

Արդյունքում մենք ստանում ենք հետևյալ տեքստային տողը, որը. INDIRECT-ը փոխակերպում է տիրույթի հղման.

INDIRECT("A"&5&":B11") -> A5:B11

Այս տիրույթը գնում է VLOOKUP-ի table_array արգումենտին` ստիպելով այն սկսել որոնումը 5-րդ շարքում` դուրս թողնելով առաջին օրինակը: որոնման արժեքը.

VLOOKUP(E1, A5:B11, 2, FALSE)

Ինչպես կատարել Vlookup և վերադարձնել բազմաթիվ արժեքներ Excel-ում

Excel VLOOKUP ֆունկցիան նախատեսված է միայն մեկ համընկնում վերադարձնելու համար: Արդյո՞ք կա Vlookup բազմաթիվ օրինակներ: Այո, կա, թեև ոչ հեշտ: Սա պահանջում է մի քանի գործառույթների համակցված օգտագործում, ինչպիսիք են INDEX, SMALL և ROW, զանգվածային բանաձև է:

Օրինակ, ստորև կարող եք գտնել F2 որոնման արժեքի բոլոր երևույթները B2:B16 որոնման տիրույթում և վերադարձնել բազմապատիկ: համընկնում է C սյունակից:

{=IFERROR(INDEX($C$2:$C$11, SMALL(IF($F$1=$B$2:$B$11, ROW($C$2:$C$11)-1,""), ROW()-1)),"")}

Ձեր աշխատաթերթում բանաձևը մուտքագրելու 2 եղանակ կա.

1. Մուտքագրեք բանաձևը առաջին բջիջում, սեղմեք Ctrl + Shift + Enter, այնուհետև քաշեք այն դեպի ևս մի քանի բջիջ:
2. Ընտրեք մի քանի հարակից բջիջներ մեկ սյունակում (F1:F11 ստորև ներկայացված էկրանի նկարում), մուտքագրեք բանաձևը և սեղմեք Ctrl +Shift + Enter՝ այն ավարտելու համար:

Ամեն դեպքում, բանաձևը մուտքագրող բջիջների թիվը պետք է հավասար լինի կամ ավելի մեծ, քան հնարավոր համընկնումների առավելագույն քանակը:

Բանաձևի տրամաբանության մանրամասն բացատրության և այլ օրինակների համար տե՛ս Ինչպես կատարել մի քանի արժեքներ Excel-ում:

Ինչպես կատարել Vlookup տողերում և սյունակներում (երկկողմանի որոնում)

Երկկողմանի որոնում (նաև մատրիցային որոնում կամ երկչափ որոնում ) շքեղ բառ է խաչմերուկում արժեք փնտրելու համար։ որոշակի տող և սյունակ: Excel-ում երկչափ որոնում կատարելու մի քանի տարբեր եղանակներ կան, բայց քանի որ այս ձեռնարկի ուշադրության կենտրոնում է VLOOKUP ֆունկցիան, մենք բնականաբար կօգտագործենք այն:

Այս օրինակի համար մենք կվերցնենք ստորև աղյուսակ՝ ամսական վաճառքով և մշակեք VLOOKUP բանաձև՝ տվյալ ամսում որոշակի ապրանքի վաճառքի ցուցանիշը ստանալու համար:

Ապրանքների անունները A2:A9-ում, ամսվա անունները B1:F1, թիրախային ապրանքները՝ I1-ում: և նպատակային ամիսը I2-ում, բանաձևը հետևյալն է. ստանդարտ VLOOKUP ֆունկցիան է, որը փնտրում է I1-ի որոնման արժեքին ճշգրիտ համապատասխանություն: Բայց քանի որ մենք չգիտենք, թե կոնկրետ որ ամսվա վաճառքները կոնկրետ որ սյունակում են, մենք չենք կարող սյունակի համարն ուղղակիորեն տրամադրել col_index_num արգումենտին: Այդ սյունակը գտնելու համար օգտագործում ենք հետևյալ ՄԱՏՉֆունկցիա՝

MATCH(I2, A1:F1, 0)

Անգլերեն թարգմանված բանաձևն ասում է՝ փնտրեք I2 արժեքը A1:F1-ում և վերադարձրեք դրա հարաբերական դիրքը զանգվածում: 3-րդ արգումենտին 0 տրամադրելով՝ դուք MATCH-ին հրահանգում եք գտնել որոնման արժեքին ճիշտ արժեքը (դա նման է VLOOKUP-ի range_lookup արգումենտի համար FALSE-ի օգտագործմանը):

Քանի որ Mar գտնվում է որոնման զանգվածի 4-րդ սյունակում, MATCH ֆունկցիան վերադարձնում է 4, որն ուղղակիորեն անցնում է VLOOKUP-ի col_index_num արգումենտին:

VLOOKUP(I1, A2:F9, 4, FALSE)

Խնդրում եմ: Ուշադրություն դարձրեք, որ չնայած ամիսների անունները սկսվում են B սյունակում, մենք օգտագործում ենք A1:I1 որոնման զանգվածի համար: Դա արվում է, որպեսզի MATCH-ով վերադարձված թիվը համապատասխանի սյունակի դիրքին աղյուսակի_զանգվածում VLOOKUP-ում:

Excel-ում մատրիցային որոնում կատարելու ավելի շատ եղանակներ իմանալու համար տե՛ս INDEX MATCH MATCH: և երկչափ փնտրման այլ բանաձևեր:

Ինչպես կատարել բազմակի Vlookup Excel-ում (ներկառուցված Vlookup)

Երբեմն կարող է պատահել, որ ձեր հիմնական աղյուսակը և որոնման աղյուսակը չունենան մեկ սյունակ ընդհանուր, ինչը խանգարում է ձեզ երկու աղյուսակների միջև Vlookup անել: Այնուամենայնիվ, կա մեկ այլ աղյուսակ, որը չի պարունակում ձեր փնտրած տեղեկատվությունը, բայց ունի մեկ ընդհանուր սյունակ հիմնական աղյուսակի հետ և մեկ այլ ընդհանուր սյունակ՝ որոնման աղյուսակի հետ:

Ստորև նկարում պատկերված է իրավիճակը.

Նպատակն է պատճենել գները հիմնական աղյուսակում՝ հիմնվելով Նյութերի ID-ներ : Խնդիրն այն է, որ գներ պարունակող աղյուսակը չունի Նյութերի ID-ներ , այսինքն՝ մենք պետք է կատարենք երկու Vlookup մեկ բանաձևով:

Հարմարության համար եկեք ստեղծենք մի քանի առաջինը անվանված միջակայքեր.

• Փնտրման աղյուսակ 1-ը կոչվում է Ապրանքներ (D3:E10)
• Փնտրման աղյուսակ 2 կոչվում է Գներ ( G3:H10 )

Աղյուսակները կարող են լինել միևնույն կամ տարբեր աշխատանքային թերթերում:

Եվ այժմ մենք կկատարենք այսպես կոչված կրկնակի Vlookup-ը: , որը կոչվում է nested Vlookup :

Սկզբում ստեղծեք VLOOKUP բանաձև՝ ապրանքի անունը գտնելու աղյուսակ 1-ում (անվանումը՝ Ապրանքներ )՝ հիմնվելով ապրանքի վրա: id (A3):

=VLOOKUP(A3, Products, 2, FALSE)

Այնուհետև, դրեք վերը նշված բանաձևը մեկ այլ VLOOKUP ֆունկցիայի lookup_value արգումենտում, որպեսզի գները հանեք Փնտրման աղյուսակ 2-ից (անունը ): Գները )՝ հիմնված ապրանքի անվան վրա, որը վերադարձվել է տեղադրված VLOOKUP-ի կողմից.

=VLOOKUP(VLOOKUP(A3, Products, 2, FALSE), Prices, 2, FALSE)

Սքրինշոթը ստորև ցույց է տալիս մեր տեղադրված Vlookup բանաձևը գործողության մեջ.

Ինչպես դինամիկ կերպով դիտել բազմաթիվ թերթեր

Երբեմն, y դուք կարող եք ունենալ նույն ձևաչափի տվյալներ՝ բաժանված մի քանի աշխատաթերթերի վրա: Եվ ձեր նպատակն է տվյալներ հանել կոնկրետ թերթիկից՝ կախված տվյալ բջիջի հիմնական արժեքից:

Դա կարող է ավելի հեշտ հասկանալ օրինակից: Ենթադրենք, դուք ունեք մի քանի տարածաշրջանային վաճառքի հաշվետվություններ նույն ձևաչափով, և դուք փնտրում եք որոշակի ապրանքի վաճառքի թվեր ստանալ որոշակի առումով: