Mục lục
Trong hướng dẫn này, chúng ta sẽ xem xét cách thay đổi số cột Excel thành các ký tự chữ cái tương ứng.
Khi xây dựng các công thức phức tạp trong Excel, đôi khi bạn có thể cần phải có một ký tự cột của một ô cụ thể hoặc từ một số nhất định. Điều này có thể được thực hiện theo hai cách: bằng cách sử dụng các hàm có sẵn hoặc hàm tùy chỉnh.
Cách chuyển đổi số cột thành bảng chữ cái (cột một chữ cái)
Trong trường hợp tên cột bao gồm một chữ cái duy nhất, từ A đến Z, bạn có thể lấy nó bằng cách sử dụng công thức đơn giản sau:
CHAR(64 + col_number)Ví dụ: để chuyển đổi số 10 thành một ký tự cột, công thức là:
=CHAR(64 + 10)
Bạn cũng có thể nhập một số vào một số ô và tham chiếu đến ô đó trong công thức của bạn:
=CHAR(64 + A2)
Cách thức hoạt động của công thức này:
Hàm CHAR trả về một ký tự dựa trên mã ký tự trong bộ ASCII. Các giá trị ASCII của các chữ hoa của bảng chữ cái tiếng Anh là 65 (A) đến 90 (Z). Vì vậy, để lấy mã ký tự của chữ hoa A, bạn cộng 1 với 64; để lấy mã ký tự của chữ hoa B, bạn cộng 2 với 64, v.v.
Cách chuyển đổi số cột Excel thành chữ cái (cột bất kỳ)
Nếu bạn đang tìm kiếm một công cụ đa năng công thức hoạt động cho bất kỳ cột nào trong Excel (1 chữ cái, 2 chữ cái và 3 chữ cái), thì bạn sẽ cần sử dụng cú pháp phức tạp hơn một chút:
SUBSTITUTE(ADDRESS(1, col_number, 4 ), "1", "")Vớichữ cái cột trong A2, công thức có dạng này:
=SUBSTITUTE(ADDRESS(1, A2, 4), "1", "")
Cách thức hoạt động của công thức này:
Đầu tiên, bạn xây dựng một địa chỉ ô với số cột quan tâm. Đối với điều này, hãy cung cấp các đối số sau cho hàm ADDRESS:
- 1 cho row_num (số hàng không thực sự quan trọng nên bạn có thể sử dụng bất kỳ).
- A2 (ô chứa số cột) cho column_num .
- 4 cho đối số abs_num trả về tham chiếu tương đối.
Với các tham số trên, kết quả là hàm ADDRESS trả về chuỗi văn bản "A1".
Vì chúng tôi chỉ cần một ký tự cột, chúng tôi loại bỏ số hàng với sự trợ giúp của hàm SUBSTITUTE tìm kiếm "1" (hoặc bất kỳ số hàng nào bạn đã mã hóa cứng bên trong hàm ADDRESS) trong văn bản "A1" và thay thế nó bằng một chuỗi trống ("").
Lấy ký tự cột từ số cột bằng hàm tùy chỉnh Hàm tùy chỉnh
Nếu bạn cần thường xuyên chuyển đổi số cột thành các ký tự chữ cái thì một hàm tùy chỉnh do người dùng xác định (UDF) có thể tiết kiệm thời gian của bạn rất nhiều.
Mã của hàm này rất đẹp đơn giản và dễ hiểu:
Public Function ColumnLetter(col_nu m) ColumnLetter = Split(Cells(1, col_num).Address, "$" )(1) End FunctionỞ đây, chúng ta sử dụng thuộc tính Cells để chỉ một ô trong hàng 1 và số cột được chỉ định và thuộc tính Address để trả về mộtchuỗi chứa tham chiếu tuyệt đối đến ô đó (chẳng hạn như $A$1). Sau đó, hàm Split ngắt chuỗi được trả về thành các phần tử riêng lẻ bằng cách sử dụng ký hiệu $ làm dấu phân tách và chúng tôi trả về phần tử (1), là ký tự của cột.
Dán mã vào trình chỉnh sửa VBA và của bạn chức năng ColumnLetter mới đã sẵn sàng để sử dụng. Để biết hướng dẫn chi tiết, vui lòng xem: Cách chèn mã VBA trong Excel.
Từ quan điểm của người dùng cuối, cú pháp của hàm đơn giản như sau:
Chữ cái cột(col_num)Ở đâu col_num là số cột mà bạn muốn chuyển đổi thành một chữ cái.
Công thức thực của bạn có thể trông như sau:
=ColumnLetter(A2)
Và nó sẽ trả về kết quả chính xác giống như các hàm gốc của Excel được thảo luận trong ví dụ trước:
Cách lấy ký tự cột của một ô nhất định
Để xác định ký tự cột của một ô ô cụ thể, hãy sử dụng hàm COLUMN để truy xuất số cột và cung cấp số đó cho hàm ADDRESS. Công thức hoàn chỉnh sẽ có dạng như sau:
SUBSTITUTE(ADDRESS(1, COLUMN( cell_address), 4), "1", "")Ví dụ: hãy tìm một ký tự cột của ô C5:
=SUBSTITUTE(ADDRESS(1, COLUMN(C5), 4), "1", "")
Hiển nhiên kết quả là "C" :)
Cách lấy ký tự cột của ô hiện tại ô
Để tìm ra chữ cái của ô hiện tại, công thức gần giống như trong ví dụ trên. Sự khác biệt duy nhất là hàm COLUMN() làđược sử dụng với một đối số trống để chỉ ô chứa công thức:
=SUBSTITUTE(ADDRESS(1, COLUMN(), 4), "1", "")
Cách tạo tham chiếu phạm vi động từ số cột
Hy vọng rằng các ví dụ trước đã cung cấp cho bạn một số chủ đề mới để suy nghĩ, nhưng bạn có thể thắc mắc về các ứng dụng thực tế.
Trong ví dụ này, chúng tôi sẽ chỉ cho bạn cách sử dụng "số cột thành chữ cái " công thức để giải quyết các nhiệm vụ thực tế. Cụ thể, chúng ta sẽ tạo một công thức XLOOKUP động sẽ lấy các giá trị từ một cột cụ thể dựa trên số của cột đó.
Từ bảng mẫu bên dưới, giả sử bạn muốn nhận được con số lợi nhuận cho một dự án nhất định (H2 ) và tuần (H3).
Để hoàn thành nhiệm vụ, bạn cần cung cấp cho XLOOKUP phạm vi để trả về giá trị. Vì chúng ta chỉ có số tuần tương ứng với số cột, trước tiên, chúng ta sẽ chuyển đổi số đó thành ký tự cột, sau đó xây dựng tham chiếu phạm vi.
Để thuận tiện, hãy chia nhỏ toàn bộ quy trình thành 3 bước dễ thực hiện.
- Chuyển số cột thành chữ cái
Với số cột trong H3, hãy sử dụng công thức đã quen thuộc để chuyển nó thành chữ cái ký tự:
=SUBSTITUTE(ADDRESS(1, H3, 4), "1", "")
Mẹo. Nếu số trong tập dữ liệu của bạn không khớp với số cột, hãy đảm bảo thực hiện chỉnh sửa bắt buộc. Ví dụ: nếu chúng tôi có dữ liệu tuần 1 ở cột B, dữ liệu tuần 2 ở cột C vàv.v., sau đó chúng tôi sẽ sử dụng H3+1 để lấy số cột chính xác.
- Tạo chuỗi đại diện cho tham chiếu dải ô
Để tạo tham chiếu dải ô ở dạng chuỗi, bạn nối ký tự cột được trả về bởi công thức trên với ký tự đầu tiên và số hàng cuối cùng. Trong trường hợp của chúng tôi, các ô dữ liệu nằm trong các hàng từ 3 đến 8, vì vậy chúng tôi đang sử dụng công thức sau:
=SUBSTITUTE(ADDRESS(1, H3, 4), "1", "") & "3:" & SUBSTITUTE(ADDRESS(1, H3, 4), "1", "") & "8"Cho rằng H3 chứa "3", được chuyển đổi thành "C", công thức của chúng tôi trải qua quá trình chuyển đổi sau:
="C"&"3:"&"C"&"8"Và tạo ra chuỗi C3:C8.
- Make tham chiếu phạm vi động
Để chuyển đổi chuỗi văn bản thành tham chiếu hợp lệ mà Excel có thể hiểu được, hãy lồng công thức trên vào hàm INDIRECT rồi chuyển nó vào đối số thứ 3 của XLOOKUP:
=XLOOKUP(H2, E3:E8, INDIRECT(H4), "Not found")
Để loại bỏ một ô thừa chứa chuỗi phạm vi trả về, bạn có thể đặt công thức SUBSTITUTE ADDRESS trong chính hàm INDIRECT:
=XLOOKUP(H2, E3:E8, INDIRECT(SUBSTITUTE(ADDRESS(1, H3, 4), "1", "") & "3:" & SUBSTITUTE(ADDRESS(1, H3, 4), "1", "") & "8"), "Not found")
Với chức năng ColumnLetter tùy chỉnh của chúng tôi, bạn có thể nhận được một giải pháp nhỏ gọn và tinh tế hơn:
=XLOOKUP(H2, E3:E8, INDIRECT(ColumnLetter(H3) & "3:" & ColumnLetter(H3) & "8"), "Not found")
Đó là làm thế nào để tìm một chữ cái cột từ một số trong Excel. Tôi cảm ơn bạn đã đọc và mong được gặp bạn trên blog của chúng tôi vào tuần tới!
Sách bài tập thực hành để tải xuống
Số cột Excel thành chữ cái - ví dụ (tệp .xlsm)
