Obsah
Tento návod ukazuje, ako používať funkciu Excel AVERAGEIFS na výpočet priemeru s viacerými podmienkami.
Keď ide o výpočet aritmetického priemeru skupiny čísel v programe Excel, je na to určená funkcia AVERAGE. Ak chcete spriemerovať bunky, ktoré spĺňajú určitú podmienku, hodí sa funkcia AVERAGEIF. Ak chcete nájsť priemer s viacerými kritériami, použite funkciu AVERAGEIFS. Ak chcete zistiť, ako funguje, čítajte ďalej!
Funkcia AVERAGEIFS v programe Excel
Funkcia Excel AVERAGEIFS vypočíta aritmetický priemer všetkých buniek v rozsahu, ktoré spĺňajú zadané kritériá.
Syntax je nasledujúca:
AVERAGEIFS(average_range, criteria_range1, criteria1, [criteria_range2, criteria2], ...)Kde:
- Average_range - rozsah buniek, ktoré sa majú spriemerovať.
- Criteria_range1, criteria_range2, ... - rozsahov, ktoré sa majú testovať podľa príslušných kritérií.
- Kritérium1, kritérium2, ... - Kritériá, ktoré určujú, ktoré bunky sa majú spriemerovať. Kritériá možno zadať vo forme čísla, logického výrazu, textovej hodnoty alebo odkazu na bunku.
Kritérium_rozsahu1 / kritériá1 sú povinné, ďalšie sú nepovinné. V jednom vzorci možno použiť 1 až 127 dvojíc rozsah/kritérium.
Funkcia AVERAGEIFS je k dispozícii v aplikáciách Excel 2007 - Excel 365. 
Poznámka: Funkcia AVERAGEIFS pracuje s logikou AND, t. j. spriemerujú sa len tie bunky, pre ktoré sú všetky podmienky PRAVDA. Ak chcete vypočítať bunky, pre ktoré je niektorá z podmienok PRAVDA, použite vzorec AVERAGE IF OR.
Funkcia AVERAGEIFS - poznámky k použitiu
Ak chcete jasne pochopiť, ako funkcia funguje, a vyhnúť sa chybám, všimnite si nasledujúce skutočnosti:
- V average_range argument, prázdne bunky , logické hodnoty TRUE/FALSE a textové hodnoty sú ignorované. Nulové hodnoty sú zahrnuté.
- Ak kritériá je prázdna bunka, považuje sa za nulovú hodnotu.
- Ak average_range neobsahuje jedinú číselnú hodnotu, nastane chyba #DIV/0!.
- Ak žiadne bunky nespĺňajú všetky zadané kritériá, vráti sa chyba #DIV/0!.
- Kritériá AVERAGEIFS sa môžu vzťahovať na rovnaký rozsah alebo na rôzne rozsahy.
- Každá stránka criteria_range musí mať rovnakú veľkosť a tvar ako average_range , inak sa vyskytne chyba #VALUE!.
Teraz, keď už poznáte teóriu, si ukážeme, ako funkciu AVERAGEIFS používať v praxi.
Vzorec Excel AVERAGEIFS
Najprv si načrtneme všeobecný prístup. Ak chcete správne zostaviť vzorec AVERAGEIFS, postupujte podľa týchto pokynov:
- V prvom argumente zadajte rozsah, ktorý chcete spriemerovať.
- V ďalších argumentoch zadajte dvojice rozsah/kritérium. Dvojice môžu byť usporiadané v ľubovoľnom poradí, ale kritérium vždy nasleduje za rozsahom, na ktorý sa vzťahuje.
- Vzorec AVERAGEIFS by mal vždy obsahovať nepárny počet argumentov : average_range + jeden alebo viac kritériá_rozsahu/kritérií dvojice.
AVERAGEIFS s textovými kritériami
Ak chcete získať priemer čísel v jednom stĺpci, ak iný stĺpec (stĺpce) obsahuje určitý text, použite tento text ako kritérium.
Ako príklad si nájdeme priemer predaja spoločnosti "Apple" v regióne "Sever". Na tento účel vytvoríme vzorec AVERAGEIFS s dvoma kritériami:
- Average_range je C3:C15 (bunky k priemeru).
- Kritérium_rozsahu1 je A3:A15 (položky na kontrolu) a kritériá1 je "apple".
- Kritérium_rozsahu2 je B3:B15 (regióny na kontrolu) a kritériá2 je "sever".
Ak tieto argumenty spojíme, dostaneme nasledujúci vzorec:
=AVERAGEIFS(C3:C15, A3:A15, "apple", B3:B15, "north")
Pri kritériách v preddefinovaných bunkách (F3 a F4) má vzorec tento tvar:
=AVERAGEIFS(C3:C15, A3:A15, F3, B3:B15, F4) 
AVERAGEIFS s logickými operátormi
Ak je predvolené kritérium "rovná sa", znak rovnosti môžete vynechať a do príslušného argumentu jednoducho vložíte cieľový text (uzavretý v úvodzovkách) alebo číslo (bez úvodzoviek), ako je uvedené v predchádzajúcom príklade.
Pri použití iných logických operátorov, ako sú "väčší ako" (>), "menší ako" (<), nerovná sa () a iné s číslo alebo dátum , celú konštrukciu uzavriete do dvojitých úvodzoviek.
Napríklad pre priemerný predaj vyšší ako nula dodaný do 1. októbra 2022 je vzorec nasledovný:
=AVERAGEIFS(C3:C15, B3:B15, "0")
Ak sa kritériá nachádzajú v samostatných bunkách, logický operátor uzavriete do úvodzoviek a spojíte ho so znakom odkaz na bunku pomocou ampersandu (&). Napríklad:
=AVERAGEIFS(C3:C15, B3:B15, ""&F4) 
AVERAGEIFS so zástupnými znakmi
Spriemerovanie buniek na základe čiastočná zhoda textu , použite v kritériách zástupné znaky - otáznik (?) na porovnanie s ľubovoľným jedným znakom alebo hviezdičku (*) na porovnanie s ľubovoľným počtom znakov.
Predpokladajme, že v nasledujúcej tabuľke chcete spriemerovať predaj "oranžovej" vo všetkých "južných" regiónoch vrátane "juhozápadného" a "juhovýchodného". Aby sa tak stalo, do druhého kritéria uvedieme hviezdičku:
=AVERAGEIFS(C3:C15, A3:A15, F3, B3:B15, "south*")
Ak je v bunke zadané čiastočné textové kritérium zhody, potom spojte zástupný znak s odkazom na bunku. V našom prípade má vzorec tento tvar:
=AVERAGEIFS(C3:C15, A3:A15, F3, B3:B15, F4& "*") 
Priemer, ak je medzi dvoma hodnotami
Ak chcete získať priemer hodnôt, ktoré spadajú medzi dve konkrétne hodnoty, použite jeden z nasledujúcich všeobecných vzorcov:
Priemer, ak je medzi dvoma hodnotami vrátane:
AVERAGEIFS(average_range, criteria_range,">= hodnota1 ", criteria_range,"<= hodnota2 ")Priemer, ak je medzi dvoma hodnotami, výlučne:
AVERAGEIFS(average_range, criteria_range,"> hodnota1 ", criteria_range,"< hodnota2 ")V prvom vzorci použijete väčšia alebo rovná (>=) a menšia alebo rovná (<=), takže hraničné hodnoty sú zahrnuté do priemeru.
V druhom vzorci sa väčšia ako (>) a menej ako (<) logické kritériá vylučujú hraničné hodnoty z priemeru.
Tieto vzorce fungujú dobre alebo v oboch prípadoch - keď sa bunky, ktoré sa majú spriemerovať, a bunky, ktoré sa majú skontrolovať, nachádzajú v ten istý stĺpec alebo v dvoch rôzne stĺpce .
Ak chcete napríklad vypočítať priemer tržieb medzi 100 a 130 vrátane, môžete použiť tento vzorec:
=AVERAGEIFS(C3:C15, C3:C15, ">=100", C3:C15, "<=130")
S hraničnými hodnotami v bunkách E3 a F3 má vzorec tento tvar:
=AVERAGEIFS(C3:C15, C3:C15, ">="&E3, C3:C15, "<="&F3)
Všimnite si, že v tomto prípade používame rovnaký odkaz (C3:C15) pre 3 argumenty rozsahu. 
Ak chcete spriemerovať bunky v danom stĺpci, ak hodnoty v inom stĺpci spadajú medzi dve hodnoty, zadajte iný rozsah pre average_range a criteria_range argumenty.
Napríklad na spriemerovanie tržieb v stĺpci C, ak je dátum v stĺpci B medzi 1. septembrom a 30. októbrom, sa použije vzorec:
=AVERAGEIFS(C3:C15, B3:B15, ">=9/1/2022", B3:B15, "<=10/30/2022")
S odkazmi na bunky:
=AVERAGEIFS(C3:C15, B3:B15, ">="&E3, B3:B15, "<="&F3) 
Takto sa používa funkcia AVERAGEIFS v programe Excel na nájdenie aritmetického priemeru s viacerými kritériami. Ďakujem vám za prečítanie a dúfam, že sa uvidíme na našom blogu budúci týždeň!
Cvičebnica na stiahnutie
Funkcia Excel AVERAGEIFS - príklady (.xlsx súbor)
