Spis treści
Ten samouczek pokazuje, jak używać funkcji Excel AVERAGEIFS do obliczania średniej z wieloma warunkami.
Jeśli chodzi o obliczanie średniej arytmetycznej z grupy liczb w Excelu, to najlepszym rozwiązaniem jest AVERAGE. Aby uśrednić komórki spełniające określony warunek, z pomocą przychodzi AVERAGEIF. Aby znaleźć średnią przy wielu kryteriach, należy użyć funkcji AVERAGEIFS. Aby dowiedzieć się, jak działa, czytaj dalej!
Funkcja AVERAGEIFS w programie Excel
Funkcja Excel AVERAGEIFS oblicza średnią arytmetyczną wszystkich komórek w zakresie, które spełniają określone kryteria.
Składnia jest następująca:
AVERAGEIFS(średnia_zakresu, kryteria_zakresu1, kryteria1, [kryteria_zakresu2, kryteria2], ...)Gdzie:
- Średni_zakres - zakres komórek do uśrednienia.
- Kryteria_zakres1, kryteria_zakres2, ... - zakresy, które mają być badane pod kątem odpowiednich kryteriów.
- Kryteria1, kryteria2, ... - kryteria określające, które komórki mają zostać uśrednione. Kryteria mogą być podane w postaci liczby, wyrażenia logicznego, wartości tekstowej lub odwołania do komórki.
Kryteria_zakresu1 / kryteria1 są wymagane, kolejne są opcjonalne. W jednej formule można użyć od 1 do 127 par zakres/kryterium.
Funkcja AVERAGEIFS jest dostępna w programie Excel 2007 - Excel 365. 
Uwaga. Funkcja AVERAGEIFS działa w logice AND, tzn. uśredniane są tylko te komórki, dla których wszystkie warunki są TRUE. Aby obliczyć komórki, dla których jakikolwiek pojedynczy warunek jest TRUE, należy użyć formuły AVERAGE IF OR.
Funkcja AVERAGEIFS - uwagi dotyczące użytkowania
Aby dobrze zrozumieć, jak działa funkcja i uniknąć błędów, zwróć uwagę na następujące fakty:
- W średni_zakres argument, puste komórki , wartości logiczne TRUE/FALSE, oraz wartości tekstowe są ignorowane. Wartości zerowe są uwzględnione.
- Jeśli kryteria jest pustą komórką, jest traktowana jako wartość zerowa.
- Jeśli średni_zakres nie zawiera pojedynczej wartości liczbowej, pojawia się błąd #DIV/0!
- Jeśli żadna komórka nie spełnia wszystkich określonych kryteriów, zwracany jest błąd #DIV/0!
- Kryteria "AVERAGEIFS" mogą dotyczyć tego samego zakresu lub różnych zakresów.
- Każdy kryteria_zakresu musi mieć taką samą wielkość i kształt jak średni_zakres , w przeciwnym razie pojawia się błąd #VALUE!
Teraz, gdy znasz już teorię, zobaczmy jak wykorzystać funkcję AVERAGEIFS w praktyce.
Formuła Excel AVERAGEIFS
Najpierw nakreślmy ogólne podejście. Aby poprawnie skonstruować formułę AVERAGEIFS, należy postępować zgodnie z poniższymi wskazówkami:
- W pierwszym argumencie podaj zakres, który chcesz uśrednić.
- W kolejnych argumentach podaj pary zakres/kryterium. Pary te mogą być ułożone w dowolnej kolejności, ale kryterium zawsze następuje po zakresie, którego dotyczy.
- Formuła AVERAGEIFS powinna zawsze zawierać nieparzysta liczba argumentów : średni_zakres + jeden lub więcej kryteria_zakresu/kryteria par.
AVERAGEIFS z kryteriami tekstowymi
Aby uzyskać średnią liczb w jednej kolumnie, jeśli inna kolumna (kolumny) zawiera pewien tekst, użyj tego tekstu jako kryterium.
Jako przykład znajdźmy średnią ze sprzedaży "Apple" w regionie "Północ". W tym celu wykonujemy formułę AVERAGEIFS z dwoma kryteriami:
- Średni_zakres wynosi C3:C15 (komórki do średniej).
- Kryteria_zakresu1 to A3:A15 (pozycje do sprawdzenia) oraz kryteria1 to "jabłko".
- Kryteria_zakresu2 jest B3:B15 (Regiony do sprawdzenia) oraz kryteria2 jest "północ".
Składając te argumenty w całość, otrzymujemy następujący wzór:
=AVERAGEIFS(C3:C15, A3:A15, "apple", B3:B15, "north")
Przy kryteriach w zdefiniowanych wcześniej komórkach (F3 i F4) formuła przyjmuje taką postać:
=AVERAGEIFS(C3:C15, A3:A15, F3, B3:B15, F4) 
AVERAGEIFS z operatorami logicznymi
Gdy kryteria są domyślnie ustawione na "jest równy", można pominąć znak równości i po prostu umieścić tekst docelowy (ujęty w cudzysłów) lub liczbę (bez cudzysłowu) w odpowiednim argumencie, jak pokazano w poprzednim przykładzie.
Podczas używania innych operatorów logicznych, takich jak "większy niż" (>), "mniejszy niż" (<), nie równy (), i innych z końcówką numer lub data , całą konstrukcję zamykasz w podwójnych cudzysłowach.
Przykładowo, do średniej sprzedaży większej od zera dostarczonej do 1-Oct-2022, wzór wynosi:
=AVERAGEIFS(C3:C15, B3:B15, "0")
Gdy kryteria znajdują się w oddzielnych komórkach, operator logiczny ujmuje się w cudzysłów i łączy z operatorem odniesienie do komórki używając ampersanda (&). Na przykład:
=AVERAGEIFS(C3:C15, B3:B15, ""&F4) 
AVERAGEIFS ze znakami wieloznacznymi
Aby uśrednić komórki na podstawie częściowe dopasowanie tekstu , użyj znaków wieloznacznych w kryteriach - znak zapytania (?), aby dopasować dowolny pojedynczy znak lub gwiazdkę (*), aby dopasować dowolną liczbę znaków.
W poniższej tabeli załóżmy, że chcemy uśrednić sprzedaż "pomarańczowego" we wszystkich regionach "południowych", w tym "południowo-zachodnich" i "południowo-wschodnich". Aby to zrobić, w drugim kryterium umieszczamy gwiazdkę:
=AVERAGEIFS(C3:C15, A3:A15, F3, B3:B15, "south*")
Jeżeli w komórce zostanie wprowadzone kryterium dopasowania tekstu częściowego, to należy dokonać konkatenacji znaku wieloznacznego z odwołaniem do komórki. W naszym przypadku formuła przyjmuje taki kształt:
=AVERAGEIFS(C3:C15, A3:A15, F3, B3:B15, F4& "*") 
Średnia, jeśli między dwoma wartościami
Aby uzyskać średnią wartości, które mieszczą się między dwiema określonymi wartościami, użyj jednego z następujących ogólnych wzorów:
Średnia, jeśli pomiędzy dwoma wartościami, włącznie:
AVERAGEIFS(average_range, criteria_range,">=. wartość1 ", criteria_range,"<=. wartość2 ")Średnia, jeśli pomiędzy dwoma wartościami, wyłączna:
AVERAGEIFS(average_range, criteria_range,"> wartość1 ", criteria_range,"< wartość2 ")W 1. formule używasz większy lub równy (>=) oraz mniejszy lub równy (<=) operatorów logicznych, więc wartości graniczne są uwzględniane w średniej.
W 2. formule. większy niż (>) oraz mniej niż (<) kryteria logiczne wykluczają wartości graniczne ze średniej.
Formuły te działają ładnie lub w obu scenariuszach - gdy komórki do uśredniania i komórki do sprawdzania znajdują się w ta sama kolumna lub w dwóch różne kolumny .
Na przykład, aby obliczyć średnią ze sprzedaży w przedziale od 100 do 130 włącznie, możesz użyć tego wzoru:
=AVERAGEIFS(C3:C15, C3:C15, ">=100", C3:C15, "<=130")
Przy wartościach granicznych w komórkach E3 i F3 formuła przyjmuje taką postać:
=AVERAGEIFS(C3:C15, C3:C15, ">="&E3, C3:C15, "<="&F3)
Proszę zauważyć, że w tym przypadku używamy tego samego odniesienia (C3:C15) dla 3 argumentów zakresu. 
Aby uśrednić komórki w danej kolumnie, jeśli wartości w innej kolumnie mieszczą się pomiędzy dwoma wartościami, należy podać inny zakres dla średni_zakres oraz kryteria_zakresu argumenty.
Na przykład, aby uśrednić sprzedaż w kolumnie C, jeśli data w kolumnie B mieści się w przedziale od 1-września do 30-października, wzór brzmi:
=AVERAGEIFS(C3:C15, B3:B15, ">=9/1/2022", B3:B15, "<=10/30/2022")
Z referencjami do komórek:
=AVERAGEIFS(C3:C15, B3:B15, ">="&E3, B3:B15, "<="&F3) 
Tak oto używasz funkcji AVERAGEIFS w Excelu, aby znaleźć średnią arytmetyczną z wieloma kryteriami. Dziękuję za przeczytanie i mam nadzieję, że zobaczymy się na naszym blogu za tydzień!
Zeszyt ćwiczeń do pobrania
Funkcja Excel AVERAGEIFS - przykłady (plik .xlsx)
