Šajā pamācībā tiek iepazīstināta jaunā Excel XMATCH funkcija un parādīts, ar ko tā ir labāka nekā MATCH dažu bieži sastopamu uzdevumu risināšanā.

Programmā Excel 365 tika pievienota funkcija XMATCH, lai aizstātu funkciju MATCH. Taču, pirms sākat atjaunināt esošās formulas, būtu prātīgi izprast visas jaunās funkcijas priekšrocības un to, ar ko tā atšķiras no vecās funkcijas.

Rezumējot, XMATCH funkcija ir tāda pati kā MATCH, bet elastīgāka un robustāka. Tā var meklēt gan vertikālos, gan horizontālos masīvos, meklēt no pirmā līdz pēdējam vai no pēdējā līdz pirmajam, atrast precīzu, aptuvenu un daļēju sakritību, kā arī izmantot ātrāku bināro meklēšanas algoritmu.

Excel XMATCH funkcija

XMATCH funkcija programmā Excel atgriež vērtības relatīvo pozīciju masīvā vai šūnu diapazonā.

Tam ir šāda sintakse:

Kur:

Lookup_value (obligāts) - meklējamā vērtība.

Lookup_array (obligāts) - šūnu masīvs vai diapazons, kurā meklēt.

Match_mode (nav obligāts) - norāda, kuru atbilstības tipu izmantot:

• 0 vai izlaists (noklusējums) - precīza atbilstība
• -1 - precīza atbilstība vai nākamā mazākā vērtība.
• 1 - precīza atbilstība vai nākamā lielākā vērtība
• 2 - aizstājējzīme (*, ?)

Meklēšanas_režīms (nav obligāts) - norāda meklēšanas virzienu un algoritmu:

• 1 vai izlaists (noklusējuma iestatījums) - meklēšana no pirmā līdz pēdējam.
• -1 - meklēšana apgrieztā secībā no pēdējā uz pirmo.
• 2 - bināra meklēšana augošā secībā. Pieprasa lookup_array sakārtot augošā secībā.
• -2 - bināra meklēšana dilstošā secībā. Pieprasa lookup_array sakārtot dilstošā secībā.

Binārā meklēšana ir ātrāks algoritms, kas efektīvi darbojas ar sakārtotiem masīviem. Lai iegūtu vairāk informācijas, skatiet sadaļu Meklēšanas režīms.

Kurā Excel versijā ir XMATCH?

XMATCH funkcija ir pieejama tikai programmā Excel for Microsoft 365 un Excel 2021. Programmā Excel 2019, Excel 2016 un agrākajās versijās šī funkcija nav atbalstīta.

Pamata XMATCH formula programmā Excel

Lai gūtu vispārēju priekšstatu par to, ko šī funkcija spēj, izveidosim XMATCH formulu visvienkāršākajā formā, definējot tikai pirmos divus obligātos argumentus, bet neobligātajiem argumentiem atstājot noklusējuma vērtības.

Pieņemsim, ka jums ir saraksts ar okeāniem, kas sakārtoti pēc to lieluma (C2:C6), un jūs vēlaties atrast konkrēta okeāna rangu. Lai to izdarītu, vienkārši izmantojiet okeāna nosaukumu, piemēram. Indijas , kā meklēšanas vērtību un visu nosaukumu sarakstu kā meklēšanas masīvu:

=XMATCH("Indijas", C2:C6)

Lai padarītu formulu elastīgāku, ievadiet interesējošo okeānu kādā šūnā, piemēram, F1:

=XMATCH(F1, C2:C6)

Rezultātā jūs saņemat XMATCH formulu, kas tiek meklēta vertikālais masīvs . Izvades rezultāts ir meklēšanas vērtības relatīvā pozīcija masīvā, kas mūsu gadījumā atbilst okeāna rangam:

Līdzīga formula lieliski darbojas arī horizontālais masīvs Viss, kas jums jādara, ir tikai jāpielāgo lookup_array atsauce:

=XMATCH(B5, B1:F1)

Excel XMATCH funkcija - kas jāatceras

Lai efektīvi izmantotu XMATCH savās darblapās un novērstu negaidītus rezultātus, atcerieties šos 3 vienkāršus faktus:

• Ja meklēšanas masīvā ir divi vai vairāki meklēšanas vērtības atkārtojumi, atrašanās vieta pirmais mačs tiek atgriezts, ja meklēšanas_režīms arguments ir iestatīts uz 1 vai izlaists. meklēšanas_režīms iestatīts uz -1, funkcija meklē apgrieztā secībā un atgriež pozīciju pēdējais mačs kā parādīts šajā piemērā.
• Ja meklēšanas vērtība nav atrasts , rodas #N/A kļūda.
• XMATCH funkcija ir lielo un mazo burtu un atbilžu Lai atšķirtu mazos un lielos burtus, izmantojiet XMATCH formulu, kas nosaka burtu lielumu.

Kā lietot XMATCH programmā Excel - formulu piemēri

Turpmākie piemēri palīdzēs labāk izprast XMATCH funkciju un tās praktisko pielietojumu.

Precīza atbilstība pret aptuvenu atbilstību

XMATCH saskaņošanas uzvedību kontrolē pēc izvēles match_mode arguments:

• 0 vai izlaists (noklusējums) - formula meklē tikai precīzu atbilstību. Ja precīza atbilstība netiek atrasta, tiek atgriezta #N/A kļūda.
• -1 - formula vispirms meklē precīzu atbilstību un pēc tam nākamo mazāko elementu.
• 1 - formula vispirms meklē precīzu atbilstību un pēc tam nākamo lielāko vienumu.

Un tagad aplūkosim, kā dažādi saskaņošanas režīmi ietekmē formulas rezultātu. Pieņemsim, ka vēlaties noskaidrot, kur starp visiem okeāniem atrodas noteikta platība, piemēram, 80 000 000 km2.

Precīza atbilstība

Ja izmantojat 0 kā match_mode , tiks pieļauta kļūda #N/A, jo formula nevar atrast vērtību, kas būtu precīzi vienāda ar meklēšanas vērtību:

=XMATCH(80000000, C2:C6, 0)

Nākamais mazākais postenis

Ja lietojat -1 kā match_mode , formula atgriezīs 3, jo tuvākā atbilstība, kas ir mazāka par meklēšanas vērtību, ir 70 560 000, un tas ir meklēšanas masīva trešais vienums:

=XMATCH(80000000, C2:C6, -1)

Nākamais lielākais postenis

Ja izmantojat 1 kā match_mode , formulas rezultāts būs 2, jo tuvākā atbilstība, kas ir lielāka par meklēšanas vērtību, ir 85 133 000, kas ir meklēšanas masīva 2. vienība:

=XMATCH(80000000, C2:C6, -1)

Zemāk redzamajā attēlā ir parādīti visi rezultāti:

Kā programmā Excel saskaņot daļēju tekstu ar aizstājējzīmēm

Funkcijai XMATCH ir īpašs saskaņošanas režīms aizstājējzīmēm. match_mode arguments ir iestatīts uz 2.

Aizstājzīmju atbilstības režīmā XMATCH formulā ir pieļaujamas šādas aizstājējzīmes:

• Jautājuma zīme (?), lai atbilstu jebkurai vienai rakstzīmei.
• Zvaigznīte (*), lai saskaņotu jebkuru rakstzīmju virkni.

Lūdzu, ņemiet vērā, ka aizstājējzīmes darbojas tikai ar tekstu, nevis skaitļiem.

Piemēram, lai atrastu pirmā elementa pozīciju, kas sākas ar "dienvidi", formula ir šāda:

=XMATCH("south*", B2:B6, 2)

Vai arī varat ievadīt aizstājējzīmju izteiksmi kādā šūnā, piemēram, F1, un ievadīt šūnas atsauci uz lookup_value arguments:

=XMATCH(F1, B2:B6, 2)

Izmantojot lielāko daļu Excel funkciju, izmantojiet tilde (~), lai zvaigznīti (~*) vai jautājuma zīmi (~?) uzskatītu par burtiskām rakstzīmēm, nevis aizstājējzīmēm. Izmantojot XMATCH, tilde nav nepieciešama. Ja nenoteiksiet aizstājējzīmju atbilstības režīmu, XMATCH pieņems, ka ? un * ir parastās rakstzīmes.

Piemēram, tālāk redzamajā formulā diapazonā A2:A7 tiks meklēta tieši zvaigznītes zīme:

=XMATCH("*", A2:A7)

XMATCH reversā meklēšana, lai atrastu pēdējo atbilstību

Ja meklēšanas masīvā ir vairāki meklējamās vērtības atkārtojumi, dažkārt var būt nepieciešams iegūt atrašanās vietu pēdējais gadījums .

Meklēšanas virziens tiek kontrolēts ar XMATCH 4. argumentu ar nosaukumu meklēšanas_režīms Meklēt apgrieztā secībā, t. i., no apakšas uz augšu vertikālā masīvā un no labās puses uz kreiso horizontālā masīvā, meklēšanas_režīms jābūt iestatītam uz -1.

Šajā piemērā mēs atgriezīsim pēdējā ieraksta pozīciju konkrētai meklēšanas vērtībai (lūdzu, skatiet ekrānšāviņu zemāk). Šim nolūkam argumentus iestatiet šādi:

• Lookup_value - mērķa pārdevējs H1
• Lookup_array - pārdevēju nosaukumi C2:C10
• Match_mode ir 0 vai izlaists (precīza atbilstība)
• Meklēšanas_režīms ir -1 (no pēdējā uz pirmo).

Saliekot kopā četrus argumentus, iegūstam šo formulu:

=XMATCH(H1, C2:C10, 0, -1)

Tiek atgriezts pēdējās Lauras veiktās pārdošanas numurs:

Kā salīdzināt divus kolonnas programmā Excel, lai atrastu atbilstību

Lai salīdzinātu divus sarakstus, meklējot sakritības, varat izmantot funkciju XMATCH kopā ar IF un ISNA:

Piemēram, lai salīdzinātu 2. sarakstu B2:B10 ar 1. sarakstu A2:A10, formula ir šāda:

=IF(ISNA(XMATCH(B2:B10, A2:A9)), "", "Atbilst 1. sarakstā")

Šajā piemērā mēs identificējam tikai sakritības, tāpēc value_if_true funkcijas IF arguments ir tukša virkne ("").

Ievadiet iepriekš minēto formulu augšējā šūnā (mūsu gadījumā C2), nospiediet Enter , un tā automātiski "izplūdīs" pārējās šūnās (to sauc par izplūdes diapazonu):

Kā darbojas šī formula

Formulas pamatā XMATCH funkcija meklē vērtību no 2. saraksta 1. sarakstā. Ja vērtība tiek atrasta, tiek atgriezta tās relatīvā pozīcija, pretējā gadījumā tiek paziņota kļūda #N/A. Mūsu gadījumā XMATCH rezultāts ir šāds masīvs:

{#N/A;#N/A;#N/A;2;#N/A;4;#N/A;#N/A;#N/A;8;#N/A}

Šis masīvs tiek "padots" funkcijai ISNA, lai tā pārbaudītu, vai tajā nav kļūdu #N/A. Katrai kļūdai #N/A ISNA atgriež TRUE, bet jebkurai citai vērtībai - FALSE. Rezultātā tiek iegūts šāds loģisko vērtību masīvs, kurā TRUE apzīmē neatbilstības, bet FALSE - atbilstības:

{TRUE;TRUE;TRUE;FALSE;TRUE;FALSE;TRUE;TRUE;TRUE;TRUE;FALSE;TRUE}

Iepriekš minētais masīvs nonāk funkcijas IF loģiskajā testā. Atkarībā no tā, kā konfigurēti pēdējie divi argumenti, formula izvadīs atbilstošo tekstu. Mūsu gadījumā tā ir tukša virkne (""), ja nesakritības ( value_if_true ) un "Match in List 1" (atbilstība sarakstā 1) ( value_if_false ).

Piezīme. Šī formula darbojas tikai programmās Excel 365 un Excel 2021, kas atbalsta dinamiskos masīvus. Ja izmantojat Excel 2019, Excel 2016 vai agrāku versiju, lūdzu, skatiet citus risinājumus: Kā salīdzināt divus kolonnas programmā Excel.

INDEX XMATCH programmā Excel

XMATCH var izmantot kopā ar INDEX funkciju, lai iegūtu vērtību no citas kolonnas, kas saistīta ar meklēšanas vērtību, tāpat kā INDEX MATCH formula. Vispārīgā pieeja ir šāda:

Loģika ir ļoti vienkārša un viegli saprotama:

XMATCH funkcija aprēķina meklēšanas vērtības relatīvo pozīciju meklēšanas masīvā un nodod to funkcijai rindu_num Pamatojoties uz rindas numuru, funkcija INDEX atgriež vērtību no jebkuras norādītās kolonnas.

Piemēram, lai noskaidrotu okeāna platību E1, varat izmantot šo formulu:

=INDEX(B2:B6, XMATCH(E1, A2:A6))

INDEX XMATCH XMATCH, lai veiktu divdimensiju meklēšanu

Lai meklētu vienlaicīgi kolonnās un rindās, izmantojiet INDEX kopā ar divām XMATCH funkcijām. Pirmā XMATCH iegūs rindas numuru, bet otrā - kolonnas numuru:

Formula ir līdzīga INDEX MATCH MATCH MATCH formulai, izņemot to, ka var izlaist match_mode argumentu, jo pēc noklusējuma ir iestatīta precīza atbilstība.

Piemēram, lai iegūtu pārdošanas apjomu konkrētai precei (G1) konkrētā mēnesī (G2), formula ir šāda:

=INDEX(B2:D8, XMATCH(G1, A2:A8), XMATCH(G2, B1:D1))

Kur B2:D8 ir datu šūnas, izņemot rindu un kolonnu galvenes, A2:A8 ir elementu saraksts un B1:D1 ir mēnešu nosaukumi.

Lietošanai lietoto burtu un lielo burtu sensitīva XMATCH formula

Kā jau minēts iepriekš, Excel XMATCH funkcija pēc savas konstrukcijas neņem vērā mazos un lielos burtus. Lai piespiestu to atšķirt teksta burtus, izmantojiet XMATCH kopā ar EXACT funkciju:

Lai veiktu meklēšanu apgrieztā secībā no pēdējā uz pirmo:

Nākamajā piemērā ir parādīta šī vispārīgā formula darbībā. Pieņemsim, ka jums ir produktu identifikatoru saraksts B2:B11. Jūs meklējat, lai atrastu preces relatīvo pozīciju E1. Lietošanas formulu, kas nosaka burtu un atbilstu burtu un atbilstu burtu pozīcijai E2, ir tikpat vienkārši kā šī:

=XMATCH(TRUE, EXACT(B2:B11, E1))

Kā šī formula darbojas:

EXACT funkcija salīdzina meklēšanas vērtību ar katru elementu meklēšanas masīvā. Ja salīdzinātās vērtības ir precīzi vienādas, ieskaitot rakstzīmju gadījumu, funkcija atgriež TRUE, pretējā gadījumā FALSE. Šis loģisko vērtību masīvs (kur TRUE ir precīza atbilstība) tiek nosūtīts uz funkciju lookup_array Tā kā meklēšanas vērtība ir TRUE, XMATCH funkcija atgriež pirmās atrastās precīzās atbilstības pozīciju vai pēdējās precīzās atbilstības pozīciju atkarībā no tā, kā esat konfigurējis funkciju XMATCH. meklēšanas_režīms arguments.

XMATCH pret MATCH programmā Excel

XMATCH tika izstrādāts kā jaudīgāks un daudzpusīgāks MATCH aizstājējs, tāpēc šīm divām funkcijām ir daudz kopīga. Tomēr ir arī būtiskas atšķirības.

Atšķirīga noklusējuma uzvedība

MATCH funkcija pēc noklusējuma izvēlas precīzu atbilstību vai nākamo mazāko elementu ( match_type iestatīts uz 1 vai izlaists).

XMATCH funkcijas noklusējuma iestatījums ir precīza atbilstība ( match_mode iestatīts uz 0 vai izlaists).

Atšķirīga uzvedība aptuvenai sakritībai

Kad match_mode / match_type arguments ir iestatīts uz 1:

• MATCH meklē precīzu sakritību vai nākamo mazāko. Pieprasa, lai meklēšanas masīvs būtu sakārtots augošā secībā.
• XMATCH meklē precīzu sakritību vai nākamo lielāko. Nav nepieciešama šķirošana.

Kad match_mode / match_type arguments ir iestatīts uz -1:

• MATCH meklē precīzu sakritību vai nākamo lielāko. Nepieciešams sakārtot meklēšanas masīvu dilstošā secībā.
• XMATCH meklē precīzu sakritību vai nākamo mazāko. Nav nepieciešama šķirošana.

Savvaļas karšu meklēšana

Lai ar XMATCH atrastu daļējas sakritības, ir jāiestata match_mode arguments līdz 2.

Funkcijai MATCH nav īpašas aizstājējzīmju atbilstības režīma opcijas. Vairumā gadījumu to konfigurēsiet precīzai atbilstībai ( match_type iestatīts uz 0), kas darbojas arī aizstājējzīmju meklēšanā.

Meklēšanas režīms

Tāpat kā jaunajai funkcijai XLOOKUP, arī funkcijai XMATCH ir īpaša funkcija meklēšanas_režīms arguments, kas ļauj definēt meklēšanas virziens :

• 1 vai izlaists (noklusējuma iestatījums) - meklēšana no pirmā līdz pēdējam.
• -1 - reversā meklēšana no pēdējās uz pirmo.

Un izvēlieties binārās meklēšanas algoritms , kas ir ļoti ātrs un efektīvs sakārtoti dati .

• 2 - bināra datu meklēšana augošā secībā.
• -2 - bināra datu meklēšana dilstošā secībā.

Binārā meklēšana , ko sauc arī par pusintervāla meklēšana vai logaritmiskā meklēšana , ir īpašs algoritms, kas atrod meklējamās vērtības pozīciju masīvā, salīdzinot to ar masīva vidējo elementu. Bināra meklēšana ir daudz ātrāka par parasto meklēšanu, taču tā pareizi darbojas tikai sakārtotos sarakstos. Nesakārtotiem datiem tā var dot nepareizus rezultātus, kas pirmajā brīdī var izskatīties diezgan normāli.

MATCH sintakse vispār neparedz meklēšanas režīma argumentu.

XMATCH dabiski apstrādā masīvus

Atšķirībā no tās priekšgājēja XMATCH funkcija tika izstrādāta dinamiskai Excel un dabiski apstrādā masīvus, bez nepieciešamības nospiest taustiņus Ctrl + Shift + Enter . Tādējādi formulas ir daudz vieglāk veidot un rediģēt, īpaši, ja kopā tiek izmantotas vairākas dažādas funkcijas. Vienkārši salīdziniet šādus risinājumus:

• Formulas, kas atkarīgas no burtu un ciparu burtu lielumiem: XMATCH
• Divu kolonnu vai sarakstu salīdzināšana, meklējot sakritības: XMATCH

XMATCH un MATCH pieejamība

XMATCH ir jauna funkcija, un tā ir pieejama tikai programmā Excel for Microsoft 365 un Excel 2021.

Funkcija MATCH ir pieejama jebkurā Excel 365 versijā līdz pat Excel 2007.

Lūk, kā lietot XMATCH funkciju programmā Excel. Paldies, ka izlasījāt, un ceru, ka nākamnedēļ tiksimies mūsu blogā!

Prakses darba burtnīca lejupielādei

Excel XMATCH formulas piemēri (.xlsx fails)