Mafunzo haya yanaonyesha jinsi ya kutumia INDEX na MATCH katika Excel na jinsi ilivyo bora kuliko VLOOKUP.

Katika baadhi ya makala ya hivi majuzi, tulijitahidi kufafanua misingi ya chaguo la kukokotoa la VLOOKUP kwa wanaoanza na kutoa mifano changamano zaidi ya fomula ya VLOOKUP kwa watumiaji wa nishati. Na sasa, nitajaribu ikiwa sitakuongelea kuacha kutumia VLOOKUP, kisha angalau nikuonyeshe njia mbadala ya kuangalia wima katika Excel.

"Ninahitaji hiyo kwa ajili ya nini?" unaweza kujiuliza. Kwa sababu VLOOKUP ina vikwazo vingi ambavyo vinaweza kukuzuia kupata matokeo unayotaka katika hali nyingi. Kwa upande mwingine, mchanganyiko wa INDEX MATCH ni rahisi kunyumbulika zaidi na una vipengele vingi vya kupendeza vinavyoifanya kuwa bora kuliko VLOOKUP katika mambo mengi.

Excel INDEX na vitendaji vya MATCH - misingi

Kwa vile lengo la somo hili ni kuonyesha njia mbadala ya kufanya vlookup katika Excel kwa kutumia mchanganyiko wa vitendaji vya INDEX na MATCH, hatutazingatia sana sintaksia zao na matumizi. Tutashughulikia kima cha chini kabisa kinachohitajika ili kuelewa wazo la jumla kisha tuangalie kwa kina mifano ya fomula inayofichua faida zote za kutumia INDEX MATCH badala ya VLOOKUP.

kitendaji cha INDEX - sintaksia na matumizi

Kitendakazi cha Excel INDEX hurejesha thamani katika safu kulingana na nambari za safu mlalo na safu ulizobainisha. Sintaksia ya chaguo za kukokotoa INDEX ni moja kwa moja:

Kumbuka. Hii ni fomula ya mkusanyiko ambayo lazima ikamilike kwa njia ya mkato ya Ctrl + Shift + Enter.

Katika sampuli ya jedwali lililo hapa chini, ikizingatiwa kuwa unataka kupata kiasi hicho kulingana na vigezo 2, Mteja na Bidhaa .

Fomula ifuatayo ya INDEX MATCH inafanya kazi vizuri:

=INDEX(C2:C10, MATCH(1, (F1=A2:A10) * (F2=B2:B10), 0))

Ambapo C2:C10 ni masafa ya kurejesha thamani kutoka, F1 ni kigezo1, A2:A10 ni safu ya kulinganisha dhidi ya kigezo1, F2 ni kigezo cha 2, na B2:B10 ni safu ya kulinganisha dhidi ya vigezo2.

Kumbuka kuingiza fomula kwa usahihi kwa kubofya Ctrl + Shift + Enter , na Excel itaifunga kiotomati mabano yaliyojipinda kama inavyoonyeshwa kwenye picha ya skrini:

Ikiwa ungependa kutotumia fomula za safu katika laha zako za kazi, ongeza kitendakazi kimoja zaidi cha INDEX kwenye fomula na ukamilishe kwa mguso wa kawaida wa Enter:

Jinsi fomula hizi zinavyofanya kazi

Mbinu hutumia mbinu sawa na chaguo za msingi za INDEX MATCH inayoangalia safu moja. Ili kutathmini vigezo vingi, unaunda safu mbili au zaidi za thamani za TRUE na FALSE ambazo zinawakilisha zinazolingana na zisizolingana kwa kila kigezo mahususi, na kisha kuzidisha vipengele vinavyolingana vya safu hizi. Operesheni ya kuzidisha inabadilisha TRUE na FALSE kuwa 1 na 0, mtawalia, na kutoa mkusanyiko ambapo 1 inalingana na safu mlalo zinazolingana na vigezo vyote.Chaguo za kukokotoa za MATCH zenye thamani ya kuangalia 1 hupata "1" ya kwanza katika safu na kupitisha nafasi yake hadi INDEX, ambayo hurejesha thamani katika safu mlalo hii kutoka kwa safu iliyobainishwa.

Fomula isiyo ya safu hutegemea. uwezo wa chaguo za kukokotoa INDEX kushughulikia safu asili. INDEX ya pili imesanidiwa kwa 0 safu_num ili ipitishe safu wima nzima hadi MATCH.

Hayo ni maelezo ya hali ya juu ya mantiki ya fomula. Kwa maelezo kamili, tafadhali angalia Excel INDEX MATCH yenye vigezo vingi.

Excel INDEX MATCH yenye AVERAGE, MAX, MIN

Microsoft Excel ina vitendaji maalum vya kupata thamani ya chini, ya juu na ya wastani katika mbalimbali. Lakini vipi ikiwa unahitaji kupata thamani kutoka kwa seli nyingine ambayo inahusishwa na maadili hayo? Katika hali hii, tumia chaguo za kukokotoa MAX, MIN au AVERAGE pamoja na INDEX MATCH.

INDEX MATCH na MAX

Ili kupata thamani kubwa zaidi katika safu wima D na kurudisha thamani kutoka safuwima C katika safu mlalo sawa, tumia fomula hii:

=INDEX(C2:C10, MATCH(MAX(D2:D10), D2:D10, 0))

INDEX MATCH na MIN

Ili kupata thamani ndogo zaidi katika safu wima D na kuvuta thamani inayohusishwa kutoka safu C, tumia hii. :

=INDEX(C2:C10, MATCH(MIN(D2:D10), D2:D10, 0))

INDEX MATCH with AVERAGE

Ili kuhesabu thamani iliyo karibu na wastani katika D2:D10 na kupata thamani inayolingana kutoka safuwima C, hii ndiyo fomula. kutumia:

=INDEX(C2:C10, MATCH(AVERAGE(D2:D10), D2:D10, -1 ))

Kulingana na jinsi data yako imepangwa, toa ama 1 au -1 kwa hoja ya tatu (match_type) yakitendakazi cha MATCH:

• Ikiwa safu yako ya utafutaji (safu wima D kwa upande wetu) imepangwa kupanda , weka 1. Fomula itakokotoa thamani kubwa zaidi ambayo ni chini kuliko au sawa na thamani ya wastani.
• Ikiwa safu yako ya utafutaji imepangwa kushuka , weka -1. Fomula itajumuisha thamani ndogo zaidi ambayo ni kubwa kuliko au sawa na thamani ya wastani.
• Ikiwa safu yako ya utafutaji ina thamani sawa kabisa na wastani, wewe inaweza kuingiza 0 kwa mechi halisi. Hakuna upangaji unaohitajika.

Katika mfano wetu, idadi ya watu katika safu wima D imepangwa kwa mpangilio wa kushuka, kwa hivyo tunatumia -1 kwa aina inayolingana. Kwa hivyo, tunapata "Tokyo" kwa kuwa idadi yake (13,189,000) ndiyo inayokaribiana zaidi kuliko wastani (12,269,006).

Unaweza kuwa na hamu ya kujua hilo. VLOOKUP inaweza kufanya hesabu kama hizo pia, lakini kama fomula ya mkusanyiko: VLOOKUP yenye WASTANI, MAX, MIN.

Kwa kutumia INDEX MATCH na IFNA / IFERROR

Kama ambavyo pengine umeona, ikiwa INDEX MATCH formula katika Excel haiwezi kupata thamani ya kuangalia, inatoa hitilafu ya #N/A. Ikiwa ungependa kubadilisha nukuu ya kawaida ya hitilafu kwa kitu cha maana zaidi, funga fomula yako ya INDEX MATCH katika chaguo za kukokotoa za IFNA. Kwa mfano:

=IFNA(INDEX(C2:C10, MATCH(F1,A2:A10,0)), "No match is found")

Na sasa, mtu akiweka jedwali la utafutaji ambalo halipo katika safu ya utafutaji, fomula itamjulisha mtumiaji kwamba hakuna inayolingana.imepatikana:

Iwapo ungependa kupata hitilafu zote, si #N/A pekee, tumia chaguo la kukokotoa la IFERROR badala ya IFNA:

=IFERROR(INDEX(C2:C10, MATCH(F1,A2:A10,0)), "Oops, something went wrong!")

Tafadhali kumbuka kuwa katika hali nyingi huenda isiwe busara kuficha makosa yote kwa sababu yanakuonya kuhusu hitilafu zinazoweza kutokea katika fomula yako.

Hiyo ndivyo jinsi ya kutumia INDEX na MATCH katika Excel. Natumai mifano yetu ya fomula itakuwa muhimu kwako na ninatarajia kukuona kwenye blogu yetu wiki ijayo!

Jifunze kitabu cha mazoezi cha kupakua

mifano ya Excel INDEX MATCH (faili.xlsx)

Hapa kuna maelezo rahisi sana ya kila kigezo:

• safu - safu ya visanduku ambavyo ungependa kurudisha thamani kutoka.
• row_num - nambari ya safu mlalo katika safu ambayo ungependa kurudisha thamani kutoka kwayo. Ikiwa imeachwa, safu_ya_idadi inahitajika.
• safu_nambari - nambari ya safu wima katika safu ambayo ungependa kurejesha thamani. Ikiwa imeachwa, nambari_mlalo inahitajika.

Kwa maelezo zaidi, tafadhali angalia kitendakazi cha Excel INDEX.

Na hapa kuna mfano wa fomula ya INDEX katika umbo lake rahisi zaidi:

0> =INDEX(A1:C10,2,3)

Mfumo huu hutafuta katika visanduku A1 hadi C10 na kurejesha thamani ya kisanduku katika safu mlalo ya 2 na safu wima ya 3, yaani, kisanduku C2.

Rahisi sana, sivyo? Walakini, unapofanya kazi na data halisi hungewahi kujua ni safu mlalo na safu ipi unayotaka, hapo ndipo kitendakazi cha MATCH kinafaa.

Kitendaji cha MATCH - sintaksia na matumizi

Kitendaji cha Excel MATCH hutafuta thamani ya uchunguzi katika safu ya visanduku na kurudisha nafasi inayohusiana ya thamani hiyo katika masafa.

Sintaksia ya chaguo za kukokotoa za MATCH ni kama ifuatavyo:

• lookup_value - nambari au thamani ya maandishi unayotafuta.
• lookup_array - safu ya visanduku kuwa imetafutwa.
• match_type - inabainisha iwapo itarejesha inayolingana kabisa au inayolingana zaidi:
  • 1 au imeachwa - hupata thamani kubwa ambayo ni chini ya au sawa na thamani ya utafutaji. Inahitaji kupanga safu ya utafutaji kwa mpangilio wa kupanda.
  • 0 - hupata thamani ya kwanza ambayo ni sawa kabisa na thamani ya utafutaji. Katika mchanganyiko wa INDEX / MATCH, karibu kila wakati unahitaji inayolingana kabisa, kwa hivyo unaweka hoja ya tatu ya chaguo lako la kukokotoa MATCH kuwa 0.
  • -1 - hupata thamani ndogo ambayo ni kubwa kuliko au sawa na lookup_value. Inahitaji kupanga safu ya utafutaji kwa mpangilio wa kushuka.

Kwa mfano, ikiwa masafa B1:B3 yana thamani "New-York", "Paris", "London", fomula iliyo hapa chini inarejesha nambari 3, kwa sababu "London" ni ingizo la tatu katika safu:

=MATCH("London",B1:B3,0)

Kwa maelezo zaidi, tafadhali angalia kitendakazi cha Excel MATCH.

Katika kwanza, manufaa ya kitendakazi cha MATCH inaweza kuonekana kuwa ya kutiliwa shaka. Ni nani anayejali kuhusu nafasi ya thamani katika safu? Tunachotaka kujua ni thamani yenyewe.

Acha nikukumbushe kwamba nafasi ya jamaa ya thamani ya kuangalia (yaani, nambari za safu mlalo na safu wima) ndiyo hasa unahitaji kusambaza kwa safu_num na safu_num hoja za chaguo za kukokotoa INDEX. Kama unavyokumbuka, Excel INDEX inaweza kupata thamani katika muunganisho wa safu mlalo na safu wima fulani, lakini haiwezi kubainisha ni safu mlalo na safu wima gani hasa unayotaka.

Jinsi ya kutumia kitendakazi cha INDEX MATCH katika Excel

Sasa kwa kuwa unajua mambo ya msingi, naamini inatayari imeanza kuleta maana jinsi MATCH na INDEX zinavyofanya kazi pamoja. Kwa kifupi, INDEX hupata thamani ya utafutaji kwa safu wima na nambari za safu mlalo, na MATCH hutoa nambari hizo. Ni hivyo!

Kwa kuangalia kwa wima, unatumia chaguo la kukokotoa MATCH kubainisha nambari ya safu mlalo na kusambaza safu wima moja kwa moja kwa INDEX:

Bado una ugumu wa kubaini hilo? Inaweza kuwa rahisi kuelewa kutoka kwa mfano. Tuseme una orodha ya miji mikuu ya kitaifa na idadi yao:

Ili kupata idadi ya watu wa mji mkuu fulani, sema mji mkuu wa Japani, tumia fomula ifuatayo INDEX MATCH:

=INDEX(C2:C10, MATCH("Japan", A2:A10, 0))

Sasa, hebu tuchambue kile ambacho kila kijenzi cha fomula hii hufanya:

• Kitendo cha kukokotoa cha MATCH hutafuta thamani ya utafutaji "Japani" katika safu A2: A10, na kurejesha nambari 3, kwa sababu "Japani" ni ya tatu katika safu ya utafutaji.
• Nambari ya safu mlalo huenda moja kwa moja kwenye safu_ya_nambari hoja ya INDEX ikiiagiza kurudisha thamani kutoka kwa hiyo. safu mlalo.

Kwa hivyo, fomula iliyo hapo juu inabadilika kuwa INDEX(C2:C,3) rahisi inayosema kutafuta katika visanduku C2 hadi C10 na kuvuta thamani kutoka kwa kisanduku cha 3 katika safu hiyo, i.e. C4 kwa sababu tunaanza kuhesabu kuanzia safu mlalo ya pili.

Je, hutaki kuweka jiji katika fomula ngumu? Ingiza kwenye seli fulani, sema F1, toa selirejelea MATCH, na utapata fomula inayobadilika ya kuangalia:

=INDEX(C2:C10, MATCH(F1,A2:A10,0))

Dokezo muhimu! Idadi ya safu mlalo katika safu hoja ya INDEX inapaswa kufanana na idadi ya safu mlalo katika safu_ya_safu ya hoja ya MATCH, vinginevyo fomula itatoa matokeo yasiyo sahihi.

Subiri, subiri… kwa nini usifanye hivyo. Je, hatutumii tu fomula ifuatayo ya Vlookup? Kuna haja gani ya kupoteza muda kujaribu kubaini mizunguko ya Excel MATCH INDEX?

=VLOOKUP(F1, A2:C10, 3, FALSE)

Katika kesi hii, hakuna maana hata kidogo :) Mfano huu rahisi ni kwa madhumuni ya onyesho pekee, ili upate hisia ya jinsi vipengele vya INDEX na MATCH zinavyofanya kazi pamoja. Mifano mingine inayofuata hapa chini itakuonyesha uwezo halisi wa mseto huu ambao unakabiliana kwa urahisi na matukio mengi changamano wakati VLOOKUP inakwama.

Vidokezo:

• Katika Excel 365 na Excel 2021, wewe inaweza kutumia fomula ya kisasa zaidi ya INDEX XMATCH.
• Kwa Majedwali ya Google, angalia mifano ya fomula iliyo na INDEX MATCH katika makala haya.

INDEX MATCH dhidi ya VLOOKUP

Lini kuamua ni chaguo la kukokotoa la kutumia kwa utafutaji wima, wataalamu wengi wa Excel wanakubali kwamba INDEX MATCH ni bora zaidi kuliko VLOOKUP. Hata hivyo, watu wengi bado wanabaki na VLOOKUP, kwanza, kwa sababu ni rahisi na, pili, kwa sababu hawaelewi kikamilifu manufaa yote ya kutumia fomula ya INDEX MATCH katika Excel. Bila ufahamu huo hakuna aliye tayari kuwekeza muda wake kujifunzasintaksia changamano zaidi.

Hapo chini, nitataja faida muhimu za MATCH INDEX juu ya VLOOKUP, na utaamua kama ni nyongeza inayofaa kwenye safu yako ya uokoaji ya Excel.

sababu 4 kuu za kutumia INDEX MATCH badala ya VLOOKUP

1. tafuta kulia kwenda kushoto. Kama mtumiaji yeyote aliyeelimika anavyojua, VLOOKUP haiwezi kuangalia upande wake wa kushoto, kumaanisha kwamba thamani yako ya utafutaji inapaswa kuwa katika safu wima ya kushoto kabisa ya meza. INDEX MATCH inaweza kuangalia kushoto kwa urahisi! Mfano ufuatao unaionyesha inavyofanyika: Jinsi ya Kutafutia thamani upande wa kushoto katika Excel.
2. Ingiza au ufute safu wima kwa usalama. Fomula za VLOOKUP huvunjwa au kutoa matokeo yasiyo sahihi safu wima mpya inapowekwa. imefutwa kutoka au kuongezwa kwenye jedwali la uchunguzi kwa sababu sintaksia ya VLOOKUP inahitaji kubainisha nambari ya faharasa ya safu wima unayotaka kuvuta data kutoka. Kwa kawaida, unapoongeza au kufuta nguzo, nambari ya index inabadilika.

   Kwa INDEX MATCH, unabainisha safu wima ya urejeshaji, si nambari ya faharasa. Kwa hivyo, uko huru kuingiza na kuondoa safu wima nyingi unavyotaka bila kuwa na wasiwasi kuhusu kusasisha kila fomula inayohusishwa.

3. Hakuna kikomo cha ukubwa wa thamani ya kuangalia. Unapotumia chaguo za kukokotoa za VLOOKUP, urefu wa kigezo chako cha kuangalia hauwezi kuzidi vibambo 255, vinginevyo utakuwa na #VALUE ! kosa. Kwa hivyo, ikiwa hifadhidata yako ina mifuatano mirefu, INDEX MATCH ndiyo inayofanya kazi pekeesuluhisho.
4. Kasi ya juu ya uchakataji. Ikiwa majedwali yako ni madogo kwa kiasi, hakutakuwa na tofauti yoyote kubwa katika utendakazi wa Excel. Lakini ikiwa laha zako za kazi zina mamia au maelfu ya safu mlalo, na hivyo basi mamia au maelfu ya fomula, MATCH INDEX itafanya kazi haraka zaidi kuliko VLOOKUP kwa sababu Excel italazimika kuchakata safu wima za kuangalia na kurejesha pekee badala ya safu nzima ya jedwali.

   Athari za VLOOKUP kwenye utendakazi wa Excel zinaweza kuonekana hasa ikiwa kitabu chako cha kazi kina fomula changamano kama vile VLOOKUP na SUM. Jambo ni kwamba kuangalia kila thamani katika safu kunahitaji simu tofauti ya chaguo za kukokotoa za VLOOKUP. Kwa hivyo, kadri safu yako inavyokuwa na thamani nyingi na jinsi unavyokuwa na fomula nyingi zaidi kwenye kitabu cha kazi, ndivyo Excel inavyofanya kazi polepole zaidi.

Excel INDEX MATCH - mifano ya fomula

Kujua sababu za kujifunza kitendakazi cha MATCH INDEX, hebu tufikie sehemu ya kuvutia zaidi na tuone jinsi unavyoweza kutumia maarifa ya kinadharia katika mazoezi.

INDEX MATCH formula ya kuangalia kutoka kulia kwenda kushoto

Kama tayari imetajwa, VLOOKUP haiwezi kuangalia upande wake wa kushoto. Kwa hivyo, isipokuwa thamani zako za utafutaji ni safu wima iliyo kushoto kabisa, hakuna uwezekano kwamba fomula ya Vlookup itakuletea matokeo unayotaka. Chaguo za kukokotoa za INDEX MATCH katika Excel ni nyingi zaidi na haijali kabisa safu wima za kuangalia na kurejesha ziko wapi.

Kwa mfano huu,tutaongeza safu wima ya Cheo upande wa kushoto wa jedwali letu la sampuli na kujaribu kufahamu jinsi mji mkuu wa Urusi, Moscow, unavyoorodheshwa kulingana na idadi ya watu.

Kwa thamani ya utafutaji katika G1, tumia fomula ifuatayo kutafuta katika C2:C10 na urudishe thamani inayolingana kutoka kwa A2:A10:

=INDEX(A2:A10,MATCH(G1,C2:C10,0))

Kidokezo. Ikiwa unapanga kutumia fomula yako ya INDEX MATCH kwa zaidi ya seli moja, hakikisha kuwa umefunga safu zote mbili kwa marejeleo kamili ya seli (kama $A$2:$A$10 na $C$2:4C$10) ili zisipotoshwe wakati. kunakili fomula.

INDEX MATCH MATCH ili kutafuta katika safu mlalo na safuwima

Katika mifano iliyo hapo juu, tulitumia INDEX MATCH kama badala ya VLOOKUP ya kawaida kurudisha thamani kutoka safu wima moja iliyobainishwa awali. mbalimbali. Lakini vipi ikiwa unahitaji kuangalia juu katika safu na safu nyingi? Kwa maneno mengine, vipi ikiwa unataka kutekeleza kinachojulikana kama matrix au njia mbili ?

Hii inaweza kuonekana kuwa ngumu, lakini fomula inafanana sana kwa kitendakazi cha kimsingi cha Excel INDEX MATCH, chenye tofauti moja tu. Unadhani nini?

Kwa urahisi, tumia vitendakazi viwili vya MATCH - moja kupata nambari ya safu mlalo na nyingine kupata nambari ya safu wima. Na ninawapongeza wale ambao mmekisia sawa :)

Na sasa, tafadhali angalia jedwali lililo hapa chini na tutengeneze INDEX MATCH MATCHfomula ya kupata idadi ya watu (katika mamilioni) katika nchi fulani kwa mwaka fulani.

Na nchi inayolengwa katika G1 (thamani ya utazamaji) na mwaka unaolengwa katika G2 (thamani ya kuangalia), fomula inachukua sura hii. :

=INDEX(B2:D11, MATCH(G1,A2:A11,0), MATCH(G2,B1:D1,0))

Jinsi fomula hii inavyofanya kazi

Wakati wowote unapohitaji kuelewa fomula changamano ya Excel, igawanye katika sehemu ndogo na tazama kila kitendakazi mahususi hufanya nini:

MATCH(G1,A2:A11,0) – hutafuta A2:A11 thamani katika kisanduku G1 ("Uchina") na kurudisha nafasi yake, ambayo ni 2.

MATCH(G2,B1:D1,0)) - hutafuta B1:D1 ili kupata nafasi ya thamani katika kisanduku G2 ("2015"), ambayo ni 3.

Nambari za safu mlalo na safu zilizo hapo juu huenda kwenye hoja zinazolingana za chaguo la kukokotoa la INDEX:

INDEX(B2:D11, 2, 3)

Kwa matokeo, unapata thamani katika makutano ya safu mlalo ya 2 na safu wima ya 3 katika masafa B2:D11, ambayo ni thamani katika kisanduku D3. Rahisi? Ndiyo!

Excel INDEX MATCH ili kutafuta vigezo vingi

Kama ungepata nafasi ya kusoma mafunzo yetu ya VLOOKUP ya Excel, pengine tayari umejaribu fomula ya Vlookup yenye vigezo vingi. Walakini, kizuizi kikubwa cha njia hiyo ni hitaji la kuongeza safu ya msaidizi. Habari njema ni kwamba chaguo za kukokotoa za INDEX MATCH za Excel zinaweza kutafuta kwa kutumia vigezo viwili au zaidi pia, bila kurekebisha au kupanga upya data yako ya chanzo!

Hii hapa ni fomula ya jumla ya INDEX MATCH yenye vigezo vingi: