Dizze tutorial yntroduseart 2 nije funksjes fan ús Add-on Function by Color foar Google Sheets: CELLCOLOR & VALUESBYCOLORALL. Brûk se te sum & amp; telle sellen net allinich troch har kleuren, mar ek troch de mienskiplike ynhâld. Ready-made SUMIFS & amp; COUNTIFS-formules binne opnommen ;)

As jo ​​in protte wurkje mei kleurde sellen yn Google Blêden, hawwe jo wierskynlik ús Add-on Function by Color besocht. Net folle witte jo dat it no noch 2 funksjes hat dy't jo operaasjes mei kleurde sellen noch fierder útwreidzje: CELLCOLOR en VALUESBYCOLORALL . Yn dizze tutorial sil ik beide funksjes oan jo yntrodusearje en jo wat klearmakke formules foarsjen.

Som en tel kleurde sellen mei Funksje op kleur

Foardat wy dûk yn ús 2 nije oanpaste funksjes, ik wol ús Add-on Function by Color koart beskriuwe foar it gefal dat jo der net mei bekend binne.

Dizze add-on foar Google Blêdwizen kontrolearret lettertype en/of folje kleuren yn 'e selekteare sellen en:

• sommet nûmers mei in mienskiplike tint
• telt kleurde sellen en sels blanks
• fynt de gemiddelde/min/max wearden ûnder dy markearre sellen
• en mear

Der binne yn totaal 13 funksjes om jo kleurde sellen te berekkenjen.

Hjir is hoe't it wurket:

1. Jo selektearje it berik dat jo wolle ferwurkje.
2. Selektearje it lettertype en/of de fillkleuren dy't jo beskôgje wolle en kies de funksje neffens jotaak.
3. Kies om records te berekkenjen yn elke rige/kolom of hiele berik.
4. Selektearje sel(en) dêr't jo it resultaat sjen wolle.
5. Klik op Funksje ynfoegje .

Bygelyks, hjir yn elke rige som ik alle items op dy't 'ûnderweis' binne - mei in blauwe eftergrûn:

=SUM(VALUESBYCOLOR("light cornflower blue 3", "", B2:E2))

Tip. D'r is hjir in detaillearre tutorial foar de add-on beskikber en in blogpost mei foarbylden hjir.

Sa't jo sjen kinne, brûkt de add-on de standert SUM-funksje tegearre mei in spesjale funksje binnen: VALUESBYCOLOR.

VALUESBYCOLOR-funksje

VALUESBYCOLOR is ús oanpaste funksje.

Opmerking. Jo sille it net fine yn spreadsheets sûnder de add-on.

It jout dy sellen werom dy't oerienkomme mei de kleuren dy't jo selektearje yn 'e add-on:

=VALUESBYCOLOR("light cornflower blue 3", "", B2:E2)

Sjoch? It krijt allinich dy records foar elk levere item fan boppen dy't binne kleurd neffens myn ynstellingen. En dizze sifers wurde berekkene troch ien fan dy standertfunksjes dy't ik selektearre yn it ark: SUM.

Hiel moai, hè? ;)

No, der wie in ding dat de add-on miste. Dizze formule koe net brûkt wurde yn SUMIFS en COUNTIFS, dus jo koenen noch net telle troch meardere betingsten lykas gewoane kleur en de ynhâld fan sellen tagelyk. En wy binne der in protte oer frege!

Ik bin bliid om jo te fertellen dat wy it mooglik makke hawwe mei de lêste update (oktober 2021)! No befettet Function by Color 2 mear oanpaste funksjesdat sil jo dêrmei helpe :)

Ekstra funksjes fan Function by Color

2 nije funksjes dy't wy ymplementeare wurde neamd VALUESBYCOLORALL en CELLCOLOR. Litte wy sjen hokker arguminten se nedich binne en hoe't jo se brûke kinne mei jo gegevens.

Opmerking. Om't de funksjes oanpast binne, meitsje se diel út fan ús Add-on Function by Color. Jo moatte de add-on ynstalleare hawwe. Oars kinne jo de funksjes net brûke en it resultaat dat se weromjaan sil ferlern gean.

Tip. Besjoch dizze fideo of trochgean mei lêzen. Of doch beide foar in better begryp ;) D'r is sels in oefenblêd beskikber oan 'e ein fan' e blogpost ;)

VALUESBYCOLORALL

Dizze oanpaste funksje fereasket 3 arguminten:

• fill_color - RGB-koade of kleurnamme (per Google Sheets-kleurpalet) foar in eftergrûnkleur.

  Tip. Alhoewol't it argumint fereaske is, kinne jo de funksje folslein meitsje om fillkleur te negearjen troch gewoan in pear dûbele oanhalings yn te fieren: ""

• font_color - RGB-koade of kleurnamme (per Google Sheets kleurenpalet) foar in tekstkleur.

  Tip. It argumint is ek fereaske, mar nimt ek in pear dûbele oanhalingstekens "" as jo de lettertypekleur negearje moatte.

• berik - hjir neat fancy, gewoan in berik fan sellen dy't jo ferwurkje wolle.

Hawwe jo opfallen dat VALUESBYCOLORALL maklik fersin wurde kin foarVALUESBYCOLOR funksje brûkt troch de add-on? Wês foarsichtich, want d'r is in grut ferskil. Sjoch ris op dizze skermprint:

De formules binne skreaun yn B2 & amp; C2 mar jo kinne Peek op hoe't se sjogge yn B8 & amp; C8 oerienkommende:

=VALUESBYCOLOR("light green 3", "", A2:A7)

en

=VALUESBYCOLORALL("light green 3", "", A2:A7)

Tip. De kleurnammen binne nommen út it palet fan Google Blêden:

Dizze twa funksjes hawwe deselde arguminten en sels harren nammen binne sa ferlykber!

Dochs jouwe se ferskate sets werom fan gegevens:

• VALUESBYCOLOR jout de list werom fan allinnich dy records dy't ferskine mei in griene fillkleur yn kolom A. De útkomst fan dizze formule nimt mar 3 sellen: B2:B4.
• VALUESBYCOLORALL jout op syn beurt it berik fan deselde grutte as de oarspronklike (6 sellen) - C2: C7. Mar de sellen yn dit berik befetsje allinich records as de oerienkommende sel yn kolom A de fereaske folkleur hat. Oare sellen bliuwe leech.

Al kin dit jo itselde lykje, it makket in grut ferskil yn kombinaasje mei oare funksjes. En dit is krekt wat jo kleuren kinne kontrolearje tegearre mei de ynhâld fan sellen mei sokke funksjes as COUNTIFS of SUMIFS.

CELLCOLOR

Dizze folgjende funksje is frij maklik: it kontrolearret selkleuren en jout in list mei kleurnammen as RGB-koades (it is jo kar) brûkt yn elke sel. It hjit sels itselde: CELLCOLOR.

Jo kinne dy kleurnammen net direkt nedich hawwe, mar jo kinne gebrûk meitsje fanse yn oare funksjes, bygelyks, as betingst.

Dizze funksje hat ek 3 arguminten nedich:

• berik — dy sellen dy't jo wolle kontrolearje op kleuren.
• color_source — fertelt de funksje wêr't jo nei sjen moatte:
  • brûk it wurd "folje" yn dûbele oanhalingstekens om te kontrolearjen op eftergrûnkleuren
  • "lettertype" — foar tekstkleuren
  • "beide" — foar sawol fol- en tekstkleuren
• color_name - jo manier om te fertellen hokker soarte namme jo moatte weromjaan:
  • TRUE jout jo de nammen dy't jo sjogge yn in palet fan Google Spreadsheets, bgl. read of donkerblau 1
  • FALSE krijt RGB-koades fan de kleuren, bgl. #ff0000 of #3d85c6

Bygelyks jout de formule hjirûnder de list werom mei fol- en lettertypekleuren dy't yn elke sel brûkt wurde fan A2:A7:

=CELLCOLOR(A2:A7, "both", TRUE)

Dus hoe kinne dizze funksjes brûkt wurde mei IF, SUMIFS, COUNTIFS? Hoe kinne jo jo sykkritearia ynstelle op basis fan kleuren?

Sellen optellje op kleur en de ynhâld - formulefoarbylden

Litte wy besykje VALUESBYCOLORALL en CELLCOLOR te brûken yn in pear ienfâldige gefallen.

IF kleur, dan...

Hjir haw ik in koarte list mei learlingen dy't 3 tests passe:

Ik wol de rige mei PASS yn kolom E allinnich as alle sellen yn in rige binne grien (learlingen dy't slagge alle eksamens). Ik sil ús CELLCOLOR brûke yn 'e IF-funksje omkontrolearje de kleuren en jou de fereaske tekenrige werom:

=IF(COUNTIF(CELLCOLOR(B2:D2,"fill",TRUE),"light green 3")=3,"PASS","")

Hjir is wat it docht:

1. CELLCOLOR( B2:D2,"folje",TRUE) jout alle fillkleuren werom dy't yn in rige wurde brûkt.
2. COUNTIF(CELLCOLOR(B2:D2,"fill",TRUE),"ljochtgrien 3 ")=3 nimt dy kleuren en kontrolearret oft 'ljochtgrien 3' (dy't ik yn myn sellen brûk) 3 kear op in rige krekt ferskynt.
3. As dat sa is, jout IF 'PASS' werom, oars , de sel bliuwt leech.

COUNTIFS: telle troch kleuren & amp; wearden mei 1 formule

COUNTIFS is in oare funksje dy't lang om let kin telle troch meardere kritearia sels as ien fan harren kleur is.

Stel ús oannimme dat der records binne fan winsten per skift en per meiwurker:

Gebrûk fan ús twa oanpaste funksjes binnen COUNTIFS, kin ik telle hoefolle kearen elke meiwurker it ferkeapplan ymplementearre (griene sellen).

Foarbyld 1. COUNTIFS + CELLCOLOR

Ik sil alle managers njonken de tabel mei gegevens listje en in aparte formule foar elke meiwurker ynfiere. Ik sil begjinne mei CELLCOLOR:

=COUNTIFS($A$2:$A$10,E2,CELLCOLOR($C$2:$C$10,"fill",TRUE),"light green 3")

1. It earste ding dat de formule kontrolearret is kolom A: as der 'Leela' is (in namme) fan E2), nimt it rekken mei it rekôr.
2. It twadde ding dat ik kontrolearje moat is as sellen yn kolom C ljochtgrien kleurd binne 3.

   Tip. Kontrolearje de selkleur mei it palet fan Google Sheets:

   

Om't COUNTIFS sels net gewoan kleur ophelje kin, brûk ik ús CELLCOLOR as berikfoar betingst.

Tink derom, CELLCOLOR jout in list mei kleuren dy't brûkt wurde yn elke sel. As ik it ynbêde yn COUNTIFS, scant de lêste dy list op syk nei alle foarkommen fan 'ljochtgrien 3'. Dit yn kombinaasje mei in namme út kolom E jout it fereaske resultaat. Easy peasy :)

Foarbyld 2. COUNTIFS + VALUESBYCOLORALL

Itselde bart as jo ynstee VALUESBYCOLORALL kieze. Fier it yn as berik foar de twadde betingst:

=COUNTIFS($A$2:$A$10,E2,VALUESBYCOLORALL("light green 3","",$C$2:C$10),"")

Hinke jo noch wat VALUESBYCOLORALL jout? In list mei wearden dêr't alle sellen dy't foldogge oan jo kleur easken befetsje records. Alle oare sellen bliuwe leech.

Dus as VALUESBYCOLORALL op COUNTIFS set wurdt, telt de formule allinnich dy sellen dy't net leech binne: "" (of, mei oare wurden, oerienkomme mei de fereaske kleur).

SUMIFS: som sellen troch kleuren & amp; wearden mei 1 formule

It ferhaal mei SUMIFS is krekt as mei COUNTIFS:

1. Nim ien fan ús oanpaste funksjes: CELLCOLOR of VALUESBYCOLORALL.
2. Set it as in berik dat op kleuren hifke wurde moat.
3. Fier de betingst yn ôfhinklik fan de funksje dy't jo selektearre hawwe: de namme fan de kleur foar CELLCOLOR en "net leech" ("") foar VALUESBYCOLORALL.

Opmerking. SUMIFS nimt neat oars as in ienfâldich berik as syn alderearste argumint - sum_range . As jo ​​besykje en ynbêde ien fan ús oanpaste funksjes dêr, de formule gewoan net wurkje. Sa hâld dat yn gedachten enwês wis dat jo ynstee CELLCOLOR en VALUESBYCOLORALL as kritearium ynfiere.

Hjir binne in pear foarbylden.

Foarbyld 1. SUMIFS + CELLCOLOR

Sjoch nei dizze formule:

=SUMIFS($C$2:$C$10,A$2:A$10,E2,CELLCOLOR($C$2:$C$10,"fill",TRUE),"light green 3")

1. CELLCOLOR krijt alle folkleuren fan C2:C10 en SUMIFS kontrolearret oft ien fan harren 'ljochtgrien 3' is.
2. SUMIFS scant ek A2:A10 foar in namme fan E2 — Leela .
3. As oan beide betingsten foldien is, wurdt it bedrach fan C2:C10 tafoege oan it totaal.

Foarbyld 2. SUMIFS + VALUESBYCOLORALL

Itselde bart mei VALUESBYCOLORALL:

=SUMIFS($C$2:$C$10,$A$2:$A$10,E2,VALUESBYCOLORALL("light green 3","",$C$2:$C$10),"")

1. VALUESBYCOLORALL jout it berik werom dêr't allinnich sellen fan de fereaske folkleur wearden befetsje. SUMIFS nimt alle net-lege sellen yn oanmerking.
2. SUMIFS scant ek A2:A10 foar 'Leela' fan E2.
3. As oan beide betingsten foldien is, wurdt it oerienkommende bedrach fan C2:C10 totaal.

Hoopje dat dizze tutorial ferklearret hoe't de funksjes wurkje en in hint op mooglike manieren om se te brûken. As jo ​​noch swierrichheden hawwe om se op jo saak ta te passen, moetsje my dan yn 'e opmerkingsdiel ;)

Spreadsheet om mei te oefenjen

Function by Color - oanpaste funksjes - foarbylden (meitsje in kopy fan it spreadsheet )