Šioje pamokoje rodoma, kaip "Google" skaičiuoklėse naudoti funkciją SUMIF, kad būtų galima sąlyginai sumuoti langelius. Rasite teksto, skaičių ir datų formulių pavyzdžių ir sužinosite, kaip sumuoti pagal kelis kriterijus.

Vienos iš geriausių "Google Sheets" funkcijų yra tos, kurios padeda apibendrinti ir suskirstyti duomenis į kategorijas. Šiandien atidžiau apžvelgsime vieną iš tokių funkcijų - SUMIF - galingą sąlyginę ląstelių sumavimo priemonę. Prieš nagrinėdami sintaksę ir formulių pavyzdžius, pradėsime nuo kelių svarbių pastabų.

"Google" žiniaraščiuose yra dvi funkcijos, kuriomis galima sudėti skaičius pagal sąlygas: SUMIF ir SUMIFS . Pirmoji įvertina tik vieną sąlygą, o antroji gali tikrinti kelias sąlygas vienu metu. Šioje pamokoje daugiausia dėmesio skirsime tik SUMIF funkcijai, SUMIFS naudojimas bus aptartas kitame straipsnyje.

Jei žinote, kaip naudoti SUMIF "Excel" darbalaukyje arba "Excel" internete, SUMIF "Google Sheets" jums bus paprasta, nes abi formulės iš esmės yra tokios pačios. Tačiau dar neskubėkite uždaryti šio puslapio - galbūt rasite keletą neakivaizdžių, bet labai naudingų SUMIF formulių, kurių nežinojote!

SUMIF "Google Sheets" - sintaksė ir pagrindiniai naudojimo būdai

Funkcija SUMIF "Google Sheets" skirta skaitmeniniams duomenims sumuoti pagal vieną sąlygą. Jos sintaksė tokia:

Kur:

• Diapazonas (privaloma) - ląstelių, kurios turėtų būti vertinamos pagal kriterijus .
• Kriterijus (būtina) - sąlyga, kurią reikia įvykdyti.
• Sum_range (neprivaloma) - intervalas, kuriame turi būti sumuojami skaičiai. diapazonas sumuojama.

Pavyzdžiui, sukurkime paprastą formulę, kuri sudės B stulpelio skaičius, jei A stulpelyje yra elementas, lygus "pavyzdžio elementui".

Šiuo tikslu apibrėžiame šiuos argumentus:

• Diapazonas - daiktų sąrašas - A5:A13.
• Kriterijus - ląstelę, kurioje yra dominantis elementas - B1.
• Sum_range - sumuojamos sumos - B5:B13.

Sudėję visus argumentus gauname šią formulę:

=SUMIF(A5:A13,B1,B5:B13)

Jis veikia tiksliai taip, kaip ir turėtų veikti:

"Google Sheets" SUMIF pavyzdžiai

Iš pateikto pavyzdžio jums gali susidaryti įspūdis, kad naudoti SUMIF formules "Google" skaičiuoklėse yra taip paprasta, kad galėtumėte tai daryti užmerktomis akimis. Daugeliu atvejų taip ir yra :) Tačiau vis dėlto yra keletas gudrybių ir netrivialių naudojimo būdų, dėl kurių jūsų formulės gali būti veiksmingesnės. Toliau pateiktuose pavyzdžiuose demonstruojami keli tipiški naudojimo atvejai. Kad pavyzdžius būtų lengviau suprasti, kviečiu jusatidarykite mūsų pavyzdinę SUMIF "Google" lentelę.

SUMIF formulės su teksto kriterijais (tiksli atitiktis)

Jei norite sudėti skaičius, kurių tam tikras tekstas yra kitame tos pačios eilutės stulpelyje, paprasčiausiai pateikite norimą tekstą eilutėje kriterijus SUMIF formulės argumentas. Kaip įprasta, bet koks bet kurios formulės argumento tekstas turi būti pateiktas dvigubose kabutėse.

Pavyzdžiui, norėdami gauti iš viso bananai , naudokite šią formulę:

=SUMIF(A5:A13,"bananas",B5:B13)

Arba galite įrašyti kriterijų į kurį nors langelį ir pateikti nuorodą į tą langelį:

=SUMIF(A5:A13,B1,B5:B13)

Ši formulė yra visiškai aiški, ar ne? Kaip gauti bendrą visų elementų sumą? išskyrus bananai? nelygus operatorius:

=SUMIF(A5:A13,"bananas",B5:B13)

Jei ląstelėje įvestas "išimties elementas", operatorių "nelygu" įtraukite į dvigubas kabutes (""), o operatorių ir ląstelės nuorodą sutraukite naudodami ampersandą (&). Pavyzdžiui:

=SUMIF (A5:A13,""&B1, B5:B13)

Toliau pateiktoje ekrano nuotraukoje demonstruojamos formulės "Suma, jei lygu" ir "Suma, jei nelygu":

Atkreipkite dėmesį, kad "Google Sheets" SUMIF ieško nurodyto teksto tiksliai Šiame pavyzdyje tik Bananai sumos sumuojamos, Žali bananai ir Goldfinger bananai neįtraukiami. Jei norite, kad suma iš dalies sutaptų, naudokite pakaitinius simbolius, kaip parodyta kitame pavyzdyje.

SUMIF formulės su pakaitiniais simboliais (dalinis atitikimas)

Tais atvejais, kai norite sumuoti vieno stulpelio langelius, jei kito stulpelio langelyje yra tam tikras tekstas ar simbolis, kaip ląstelės turinio dalis , į savo kriterijus įtraukite vieną iš šių pakaitinių simbolių:

• Klausimo ženklas (?) atitinka bet kurį vieną simbolį.
• Žvaigždutė (*) atitinka bet kokią simbolių seką.

Pavyzdžiui, norėdami susumuoti visų rūšių bananų kiekius, naudokite šią formulę:

=SUMIF(A5:A13,"*bananas*",B5:B13)

Taip pat galite naudoti pakaitinius simbolius kartu su ląstelių nuorodomis. Šiuo atveju pakaitinį simbolį uždėkite kabutėse ir sujungkite jį su langelio nuoroda:

=SUMIF(A5:A13, "*"&B1& "*", B5:B13)

Bet kokiu atveju mūsų SUMIF formulė sumuoja visų bananų kiekius:

Jei norite sutapatinti tikrąjį klausimo ženklą arba žvaigždutę, prieš jį įrašykite simbolį tilde (~), pvz., "~?" arba "~*".

Pavyzdžiui, norėdami sudėti B stulpelio skaičius, kurie toje pačioje eilutėje turi žvaigždutę A stulpelyje, naudokite šią formulę:

=SUMIF(A5:A13, "~*", B5:B13)

Galite net įvesti žvaigždutę į kurį nors langelį, pavyzdžiui, B1, ir sujungti tą langelį su tilde simboliu:

=SUMIF(A5:A13, "~"&B1, B5:B13)

Didžiosios raidės jautrus SUMIF "Google" lentelėse

Pagal numatytuosius nustatymus "Google Sheets" SUMIF nemato skirtumo tarp mažųjų ir didžiųjų raidžių. Norėdami priversti ją skirtingai vertinti didžiąsias ir mažąsias raides, naudokite SUMIF kartu su funkcijomis FIND ir ARRAYFORMULA:

Tarkime, kad turite užsakymų numerių sąrašą A5:A13 ir atitinkamas sumas C5:C13, kur tas pats užsakymo numeris yra keliose eilutėse. Tam tikroje ląstelėje, tarkime, B1, įvedate tikslinį užsakymo ID ir naudojate šią formulę užsakymo sumai grąžinti:

=SUMIF(ARRAYFORMULA(FIND(B1, A5:A13)),1, C5:C13)

Kaip veikia ši formulė

Kad geriau suprastume formulės logiką, suskirstykime ją į reikšmingas dalis:

Sudėtingiausia yra diapazonas argumentas: ARRAYFORMULA(FIND(B1, A5:A13))

Norėdami rasti tikslų užsakymo ID, naudojate raidžių skirtumo funkciją FIND. Problema yra ta, kad įprasta FIND formulė gali atlikti paiešką tik vienoje ląstelėje. Norint atlikti paiešką diapazone, reikia masyvo formulės, todėl FIND įterpiama į ARRAYFORMULA.

Kai pirmiau pateikta kombinacija randa tikslų atitikmenį, ji grąžina 1 (pirmojo rasto simbolio poziciją), priešingu atveju - #VALUE klaidą. Taigi, belieka tik susumuoti sumas, atitinkančias 1. Šiuo tikslu 1 įrašykite į kriterijus argumentas, o C5:C13 sum_range argumentas. Atlikta!

SUMIF formulės skaičiams

Norėdami sudėti tam tikrą sąlygą atitinkančius skaičius, SUMIF formulėje naudokite vieną iš palyginimo operatorių. Daugeliu atvejų tinkamo operatoriaus pasirinkimas nėra problema. Sudėtinga gali būti jį tinkamai įterpti į kriterijų.

Suma, jei didesnė arba mažesnė už

Norėdami palyginti pradinius skaičius su konkrečiu skaičiumi, naudokite vieną iš šių loginių operatorių:

• didesnis nei (>)
• mažiau nei (<)
• didesnis arba lygus (>=)
• mažesnis arba lygus (<=)

Pavyzdžiui, norėdami sudėti B5:B13 numerius, didesnius nei 200, naudokite šią formulę:

=SUMIF(B5:B13, ">200")

Atkreipkite dėmesį į teisingą kriterijaus sintaksę: skaičius, prieš kurį įrašytas palyginimo operatorius, ir visa konstrukcija pateikiama kabutėse.

Arba galite įvesti skaičių į kurį nors langelį ir sujungti palyginimo operatorių su langelio nuoroda:

=SUMIF(B5:B13, ">"&B1, B5:B13)

Palyginimo operatorių ir skaičių galite įvesti atskirose ląstelėse ir jas sujungti:

Panašiai galite naudoti ir kitus loginius operatorius, pvz:

Suma, jei ji didesnė arba lygi 200:

=SUMIF(B5:B13, ">=200")

Suma, jei ji mažesnė nei 200:

=SUMIF(B5:B13, "<200")

Suma, jei ji mažesnė arba lygi 200:

=SUMIF(B5:B13, "<=200")

Suma, jei ji lygi

Norėdami sudėti skaičius, kurie yra lygūs tam tikram skaičiui, galite naudoti lygybės ženklą (=) kartu su skaičiumi arba praleisti lygybės ženklą, o į formulę įtraukti tik skaičių. kriterijus argumentas.

Pavyzdžiui, norėdami sudėti B stulpelyje esančias sumas, kurių kiekis C stulpelyje yra lygus 10, naudokite bet kurią iš toliau pateiktų formulių:

=SUMIF(C5:C13, 10, B5:B13)

arba

=SUMIF(C5:C13, "=10", B5:B13)

arba

=SUMIF(C5:C13, B1, B5:B13)

Kai B1 yra ląstelė su reikiamu kiekiu.

Suma, jei ji nelygi

Jei norite sumuoti kitus nei nurodytas skaičius, naudokite nelygus operatorius ().

Mūsų pavyzdyje, norėdami sudėti B stulpelyje esančias sumas, kurių C stulpelyje yra bet koks kiekis, išskyrus 10, naudokite vieną iš šių formulių:

=SUMIF(C5:C13, "10", B5:B13)

=SUMIF(C5:C13, ""&B1, B5:B13)

Toliau pateiktoje ekrano nuotraukoje matomas rezultatas:

"Google Sheets" SUMIF formulės datoms

Norėdami sąlyginai sumuoti reikšmes pagal datos kriterijus, taip pat galite naudoti palyginimo operatorius, kaip parodyta pirmiau pateiktuose pavyzdžiuose. Svarbiausia, kad data būtų pateikta "Google Sheets" suprantamu formatu.

Pavyzdžiui, norėdami sumuoti B5:B13 sumas, susijusias su pristatymo datomis iki 2018 m. kovo 11 d., sudarykite kriterijų vienu iš šių būdų:

=SUMIF(C5:C13, "<3/11/2018", B5:B13)

=SUMIF(C5:C13, "<"&DATE(2018,3,11), B5:B13)

=SUMIF(C5:C13, "<"&B1, B5:B13)

Kai B1 yra tikslinė data:

Jei norite sąlyginai sumuoti langelius pagal šiandienos data , įtraukite funkciją TODAY() į kriterijus argumentas.

Kaip pavyzdį sukurkime formulę, pagal kurią susumuojamos šiandienos pristatymų sumos:

=SUMIF(C5:C13, TODAY(), B5:B13)

Tęsiant pavyzdį, galime rasti bendrą buvusių ir būsimų pristatymų sumą:

Prieš šiandien: =SUMIF(C5:C13, "<"&TODAY(), B5:B13)

Po šiandienos: =SUMIF(C5:C13, ">"&TODAY(), B5:B13)

Suma pagal tuščius arba ne tuščius langelius

Daugeliu atvejų gali tekti sumuoti tam tikro stulpelio reikšmes, jei atitinkamas kito stulpelio langelis yra arba nėra tuščias.

Šiuo tikslu "Google Sheets" SUMIF formulėse naudokite vieną iš šių kriterijų:

Suma, jei tuščia:

• "=" sumuoti visiškai tuščius langelius.
• "" sumuoti tuščius langelius, įskaitant tuos, kuriuose yra nulinio ilgio eilutės.

Suma, jei nėra tuščia:

• "", kad sudėtumėte langelius, kuriuose yra bet kokia reikšmė, įskaitant nulinio ilgio eilutes.

Pavyzdžiui, norint susumuoti sumas, kurioms nustatyta pristatymo data (C stulpelio langelis yra ne tuščias ), naudokite šią formulę:

=SUMIF(C5:C13, "", B5:B13)

Norint gauti bendrą sumų sumą, kai nėra pristatymo datos (C stulpelio langelis yra tuščias ), naudokite šį:

=SUMIF(C5:C13, "", B5:B13)

"Google Sheets" SUMIF su keliais kriterijais (OR logika)

Funkcija SUMIF "Google Sheets" skirta sudėti vertes pagal vieną kriterijų. Norėdami sudėti pagal kelis kriterijus, galite sudėti dvi ar daugiau SUMIF funkcijų.

Pavyzdžiui, norėdami susumuoti Obuoliai ir Apelsinai sumas, naudokite šią formulę:

=SUMIF(A6:A14, "obuoliai", B6:B14)+SUMIF(A6:A14, "apelsinai", B6:B14)

Arba elementų pavadinimus įrašykite į dvi atskiras langeles, tarkime, B1 ir B2, ir kiekvieną iš šių langelių naudokite kaip kriterijų:

=SUMIF(A6:A14, B1, B6:B14)+SUMIF(A6:A14, B2, B6:B14)

Atkreipkite dėmesį, kad ši formulė veikia kaip SUMIF su ARBA loginis - jis sumuoja reikšmes, jei tenkinamas bent vienas iš nurodytų kriterijų.

Šiame pavyzdyje B stulpelio reikšmes pridedame, jei A stulpelis lygus "obuoliams" arba "apelsinams". Kitaip tariant, SUMIF() + SUMIF() veikia taip, kaip ši pseudoprograma (ne tikroji, ji tik parodo logiką!): Sumif(A:A, "obuoliai" arba "apelsinai", B:B).

Jei norite sąlyginai sumuoti su IR loginis , t. y. sudėti reikšmes, kai tenkinami visi nurodyti kriterijai, naudokite "Google Sheets" funkciją SUMIFS.

"Google Sheets" SUMIF - ką reikia prisiminti

Dabar, kai jau žinote "Google Sheets" funkcijos SUMIF veržles ir varžtus, pravartu trumpai apibendrinti tai, ką jau išmokote.

1. SUMIF gali įvertinti tik vieną sąlygą

Funkcijos SUMIF sintaksė leidžia naudoti tik vieną diapazonas , vienas kriterijus ir vienas sum_range ... suma su keliais kriterijais , sudėkite kelias SUMIF funkcijas (OR logika) arba naudokite SUMIFS formules (AND logika).

2. Funkcija SUMIF neatsižvelgia į mažąsias ir didžiąsias raides

Jei ieškote SUMIF formulės, kuri atskirtų didžiąsias ir mažąsias raides, naudokite SUMIF kartu su ARRAYFORMULA ir FIND, kaip parodyta šiame pavyzdyje.

3. Tiekti vienodo dydžio range ir sum_range

Iš tiesų, sum_range argumentas nurodo tik viršutinį kairįjį sumuojamo intervalo langelį, o likusią sritį apibrėžia intervalo matmenys. diapazonas argumentas.

Kitaip tariant, SUMIF(A1:A10, "obuoliai", B1:B10) ir SUMIF(A1:A10, "obuoliai", B1:B100) sumuos B1:B10 intervalo reikšmes, nes jis yra tokio paties dydžio kaip diapazonas (A1:A10).

Taigi, net jei klaidingai nurodysite neteisingą sumų intervalą, "Google Sheets" vis tiek teisingai apskaičiuos jūsų formulę, jei viršutinė kairė ląstelė sum_range yra teisingas.

Tačiau vis tiek rekomenduojama numatyti vienodo dydžio diapazonas ir sum_range kad išvengtumėte klaidų ir išvengtumėte nenuoseklumo problemų.

4. Atminkite SUMIF kriterijų sintaksę

Kad "Google Sheets" SUMIF formulė veiktų teisingai, kriterijus išreikškite tinkamai:

• Jei kriterijus apima tekstas , pakaitinis simbolis arba loginis operatorius po kurio eina skaičius, tekstas arba data, kriterijų įrašykite kabutėse. Pavyzdžiui:

  =SUMIF(A2:A10, "obuoliai", B2:B10)

  =SUMIF(A2:A10, "*", B2:B10)

  =SUMIF(A2:A10, ">5")

  =SUMIF(A5:A10, "obuoliai", B5:B10)

• Jei kriterijus apima loginis operatorius ir ląstelės nuoroda arba kitą funkcija , kabutėmis pradėkite teksto eilutę, o ampersandu (&) - sujungkite ir užbaigkite eilutę. Pvz:

  =SUMIF(A2:A10, ">"&B2)

  =SUMIF(A2:A10, ">"&TODAY(), B2:B10)

5. Jei reikia, užblokuokite diapazonus su absoliučiomis ląstelių nuorodomis

Jei vėliau planuojate kopijuoti arba perkelti SUMIF formulę, nustatykite intervalus naudodami absoliučias ląstelių nuorodas (su ženklu $), kaip nurodyta formulėje SUMIF($A$2:$A$10, "apples", $B$2:$B$10).

Taip "Google" lapuose naudojama funkcija SUMIF. Norėdami atidžiau susipažinti su šioje pamokoje aptartomis formulėmis, kviečiame atidaryti mūsų pavyzdinę SUMIF "Google" lentelę. Dėkoju, kad perskaitėte, ir tikiuosi, kad kitą savaitę susitiksime mūsų tinklaraštyje!