Výukový kurz se zabývá tím, jak získat jedinečné hodnoty v aplikaci Excel pomocí funkce UNIQUE a dynamických polí. Naučíte se jednoduchý vzorec pro vyhledání jedinečných hodnot ve sloupci nebo řádku, ve více sloupcích, na základě podmínek a mnoho dalšího.

V předchozích verzích Excelu bylo získání seznamu jedinečných hodnot náročným úkolem. Máme pro vás speciální článek, který ukazuje, jak najít jedinečné hodnoty, které se vyskytují právě jednou, získat všechny odlišné položky v seznamu, ignorovat prázdná místa a další. Každý úkol vyžadoval kombinované použití několika funkcí a víceřádkového vzorce pole, kterému plně porozumí pouze guru Excelu.

Zavedení funkce UNIKÁTNÍ v aplikaci Excel 365 vše změnilo! To, co dříve bylo raketovou vědou, se stává snadným jako abeceda. Nyní nemusíte být expertem na vzorce, abyste získali unikátní hodnoty z rozsahu na základě jednoho nebo více kritérií a seřadili výsledky podle abecedy. Vše se provádí pomocí jednoduchých vzorců, které si každý může přečíst a upravit podle vlastních potřeb.

Funkce Excel UNIQUE

Funkce UNIKÁTNÍ v aplikaci Excel vrací seznam jedinečných hodnot z rozsahu nebo pole. Funguje s jakýmkoli typem dat: textem, čísly, daty, časy atd.

Funkce je zařazena do kategorie funkcí dynamických polí. Výsledkem je dynamické pole, které se automaticky přelévá do sousedních buněk vertikálně nebo horizontálně.

Syntaxe funkce UNIQUE aplikace Excel je následující:

Kde:

Pole (povinné) - rozsah nebo pole, ze kterého se mají vracet jedinečné hodnoty.

By_col (nepovinné) - logická hodnota určující způsob porovnání dat:

• TRUE - porovnává data napříč sloupci.
• FALSE nebo vynecháno (výchozí) - porovnává data napříč řádky.

Exactly_once (nepovinné) - logická hodnota, která určuje, které hodnoty jsou považovány za jedinečné:

• TRUE - vrací hodnoty, které se vyskytují pouze jednou, což je databázový pojem unikátní.
• FALSE nebo vynecháno (výchozí) - vrátí všechny odlišné (různé) hodnoty v rozsahu nebo poli.

Poznámka: V současné době je funkce UNIQUE k dispozici pouze v aplikaci Excel pro Microsoft 365 a Excel 2021. Aplikace Excel 2019, 2016 a starší nepodporují vzorce dynamických polí, takže funkce UNIQUE není v těchto verzích k dispozici.

Základní vzorec UNIQUE v aplikaci Excel

Níže je uveden vzorec pro jedinečné hodnoty aplikace Excel v nejjednodušší podobě.

Cílem je získat seznam jedinečných jmen z rozsahu B2:B10. Za tímto účelem zadáme do D2 následující vzorec:

=UNIKÁTNÍ(B2:B10)

Všimněte si, že 2. a 3. argument jsou vynechány, protože výchozí hodnoty v našem případě fungují perfektně - porovnáváme řádky mezi sebou a chceme vrátit všechny různé názvy v rozsahu.

Po dokončení vzorce stisknutím klávesy Enter vypíše Excel první nalezený název v D2 a ostatní názvy se přelijí do buněk pod ním. Výsledkem je, že máte všechny jedinečné hodnoty ve sloupci:

V případě, že jsou vaše data napříč sloupci od B2 do I2, nastavte 2. argument na TRUE, aby se sloupce porovnaly mezi sebou:

=UNIQUE(B2:I2,TRUE)

Zadejte výše uvedený vzorec do pole B4, stiskněte klávesu Enter , a výsledky se vodorovně přelijí do buněk vpravo. Získáte tak jedinečné hodnoty v řádku:

Tip: Chcete-li vyhledat jedinečné hodnoty ve vícesloupcových polích a vrátit je v jednom sloupci nebo řádku, použijte funkci UNIQUE spolu s funkcí TOCOL nebo TOROW, jak je uvedeno v následujících příkladech:

• Výpis jedinečných hodnot z rozsahu více sloupců do sloupce
• Vytáhnout jedinečné hodnoty z rozsahu více sloupců do řádku

Funkce Excel UNIQUE - tipy a poznámky

UNIQUE je nová funkce a stejně jako ostatní dynamické funkce pole má několik specifik, která byste měli znát:

• Pokud je pole vrácené funkcí UNIQUE konečným výsledkem (tj. není předáno jiné funkci), Excel dynamicky vytvoří vhodně velký rozsah a naplní jej výsledky. Vzorec je třeba zadat pouze v položce jedna buňka . Je důležité, aby byl dole a/nebo vpravo od buňky, do které zadáváte vzorec, dostatek prázdných buněk, jinak dojde k chybě #SPILL.
• Výsledky automaticky aktualizovat při změně zdrojových dat. Nové položky přidané mimo odkazované pole však nejsou do vzorce zahrnuty, pokud nezměníte pole pole odkaz. Pokud chcete pole automaticky reagovat na změnu velikosti zdrojového rozsahu, pak převést rozsah na tabulku aplikace Excel a použít strukturované odkazy nebo vytvořit dynamický pojmenovaný rozsah.
• Dynamická pole mezi různými soubory aplikace Excel fungují pouze tehdy. oba sešity jsou otevřené . Pokud je zdrojový sešit uzavřen, vrátí propojený vzorec UNIQUE chybu #REF!.
• Stejně jako ostatní funkce dynamického pole lze UNIQUE použít pouze v rámci normálního pole. rozsah Při vložení do tabulek Excelu se vrátí chyba #SPILL!.

Jak najít jedinečné hodnoty v aplikaci Excel - příklady vzorců

Níže uvedené příklady ukazují několik praktických použití funkce UNIQUE v aplikaci Excel. Hlavní myšlenkou je získat jedinečné hodnoty nebo odstranit duplicity, v závislosti na vašem pohledu, co nejjednodušším způsobem.

Výběr jedinečných hodnot, které se vyskytují pouze jednou

Chcete-li získat seznam hodnot, které se v zadaném rozsahu vyskytují přesně jednou, nastavte třetí argument UNIQUE na hodnotu TRUE.

Chcete-li například jednorázově vytáhnout jména, která jsou na seznamu výherců, použijte tento vzorec:

=UNIQUE(B2:B10,,TRUE)

Kde B2:B10 je zdrojový rozsah a 2. argument ( by_col ) je FALSE nebo je vynechána, protože naše data jsou uspořádána do řádků.

Vyhledání různých hodnot, které se vyskytují více než jednou

Pokud sledujete opačný cíl, tj. chcete získat seznam hodnot, které se v daném rozsahu vyskytují vícekrát, použijte funkci UNIQUE spolu s funkcemi FILTER a COUNTIF:

Chcete-li například extrahovat různé názvy, které se v B2:B10 vyskytují více než jednou, můžete použít tento vzorec:

=UNIQUE(FILTER(B2:B10, COUNTIF(B2:B10, B2:B10)>1))

Jak tento vzorec funguje:

Jádrem vzorce je funkce FILTER, která filtruje duplicitní záznamy na základě počtu výskytů vráceného funkcí COUNTIF. V našem případě je výsledkem funkce COUNTIF toto pole počtů:

{4;1;3;4;4;1;3;4;3}

Operace porovnání (>1) změní výše uvedené pole na hodnoty TRUE a FALSE, kde TRUE představuje položky, které se objeví více než jednou:

{PRAVDA;NEPRAVDA;PRAVDA;PRAVDA;PRAVDA;PRAVDA;NEPRAVDA;PRAVDA;PRAVDA;PRAVDA}

Toto pole je předáno filtru FILTER jako pole zahrnout argument, který funkci říká, které hodnoty má zahrnout do výsledného pole:

{"Andrew"; "David"; "Andrew"; "Andrew"; "David"; "Andrew"; "David"}

Jak si můžete všimnout, přežijí pouze hodnoty odpovídající hodnotě TRUE.

Výše uvedené pole přechází do pole argumentu UNIQUE a po odstranění duplicit vypíše konečný výsledek:

{"Andrew"; "David"}

Tip: Podobným způsobem můžete filtrovat jedinečné hodnoty, které se vyskytují více než dvakrát (>2), více než třikrát (>3) atd. K tomu stačí změnit číslo v logickém porovnání.

Vyhledání jedinečných hodnot ve více sloupcích (jedinečných řádcích)

V případě, že chcete porovnat dva nebo více sloupců a vrátit jedinečné hodnoty mezi nimi, zahrňte všechny cílové sloupce do příkazu pole argument.

Chceme-li například vrátit jedinečné Křestní jméno (sloupec A) a Příjmení (sloupec B) výherců, zadáme do pole E2 tento vzorec:

=UNIQUE(A2:B10)

Po stisknutí klávesy Enter se zobrazí následující výsledky:

Chcete-li získat jedinečné řádky , tj. záznamy s jedinečnou kombinací hodnot ve sloupcích A, B a C, je třeba použít tento vzorec:

=UNIQUE(A2:C10)

Úžasně jednoduché, že? :)

Získání seznamu jedinečných hodnot seřazených podle abecedy

Jak obvykle v aplikaci Excel řadíte podle abecedy? Správně, pomocí vestavěné funkce Seřadit nebo Filtrovat. Problémem je, že při každé změně zdrojových dat je třeba znovu řadit, protože na rozdíl od vzorců aplikace Excel, které se automaticky přepočítávají při každé změně v pracovním listu, je třeba tyto funkce znovu použít ručně.

Se zavedením dynamických funkcí pole tento problém zmizel! Stačí, když funkci SORT jednoduše překroutíte kolem běžného vzorce UNIQUE, například takto:

Chcete-li například získat jedinečné hodnoty ve sloupcích A až C a seřadit výsledky od A do Z, použijte tento vzorec:

=SORT(UNIQUE(A2:C10))

V porovnání s výše uvedeným příkladem je výstup mnohem srozumitelnější a lépe se s ním pracuje. Například jasně vidíme, že Andrew a David byli vítězi ve dvou různých sportech.

Tip. V tomto příkladu jsme seřadili hodnoty v 1. sloupci od A do Z. Jedná se o výchozí hodnoty funkce SORT, proto je volitelná položka sort_index a sort_order Pokud chcete seřadit výsledky podle jiného sloupce nebo v jiném pořadí (od Z po A nebo od největšího po nejmenší), nastavte 2. a 3. argument, jak je vysvětleno v návodu k funkci SORT.

Vyhledání jedinečných hodnot ve více sloupcích a jejich spojení do jedné buňky

Při vyhledávání ve více sloupcích funkce Excel UNIQUE ve výchozím nastavení vypíše každou hodnotu do samostatné buňky. Možná vám bude vyhovovat, když budou výsledky v jedné buňce?

Chcete-li toho dosáhnout, místo odkazu na celý rozsah použijte ampersand (&) ke spojení sloupců a mezi ně vložte požadovaný oddělovač.

Jako příklad uvádíme spojení křestních jmen v A2:A10 a příjmení v B2:B10, přičemž hodnoty oddělujeme znakem mezery (" "):

=UNIQUE(A2:A10&" "&B2:B10)

Výsledkem je seznam celých jmen v jednom sloupci:

Získání seznamu jedinečných hodnot na základě kritérií

Chcete-li získat jedinečné hodnoty s podmínkou, použijte společně funkce UNIQUE a FILTER aplikace Excel:

• Funkce FILTR omezuje data pouze na hodnoty, které splňují danou podmínku.
• Funkce UNIQUE odstraní z filtrovaného seznamu duplikáty.

Zde je obecná verze vzorce pro filtrování jedinečných hodnot:

Pro tento příklad získáme seznam vítězů v určitém sportu. Pro začátek zadáme do některé buňky sport, který nás zajímá, například F1. A poté pomocí níže uvedeného vzorce získáme jedinečná jména:

=UNIQUE(FILTER(A2:B10, C2:C10=F1))

Kde A2:B10 je rozsah pro hledání jedinečných hodnot a C2:C10 je rozsah pro kontrolu kritérií.

Filtrování jedinečných hodnot na základě více kritérií

Chcete-li filtrovat jedinečné hodnoty se dvěma nebo více podmínkami, použijte výrazy, jak je uvedeno níže, pro sestavení požadovaných kritérií pro funkci FILTER:

Výsledkem vzorce je seznam jedinečných položek, pro které jsou všechny zadané podmínky TRUE. V terminologii Excelu se tento postup nazývá logika AND.

Abychom viděli vzorec v akci, získáme seznam jedinečných vítězů pro sport v G1 (kritérium 1) a pod věkovou hranicí v G2 (kritérium 2).

Při zdrojovém rozsahu v A2:B10, sportech v C2:C10 (kritérium_rozsah 1) a věku v D2:D10 (kritérium_rozsah 2) má vzorec tento tvar:

=UNIQUE(FILTER(A2:B10, (C2:C10=G1) * (D2:D10

A vrací přesně ty výsledky, které hledáme:

Jak tento vzorec funguje:

Zde je stručné vysvětlení logiky vzorce:

V zahrnout argumentu funkce FILTER zadáte dvě nebo více dvojic rozsah/kritérium. Výsledkem každého logického výrazu je pole hodnot TRUE a FALSE. Násobením polí se logické hodnoty převedou na čísla a vznikne pole 1 a 0. Protože násobení nulou dává vždy nulu, mají ve výsledném poli 1 pouze položky, které splňují všechny podmínky. Funkce FILTERfunkce odfiltruje položky odpovídající 0 a předá výsledky funkci UNIQUE.

Další informace naleznete v části FILTROVÁNÍ s více kritérii pomocí logiky AND.

Filtrování jedinečných hodnot pomocí více kritérií OR

Chcete-li získat seznam jedinečných hodnot na základě více kritérií OR, tj. když je toto kritérium TRUE, místo násobení logických výrazů je sečtěte:

Chcete-li například zobrazit vítěze v jedné z následujících kategorií. Fotbal nebo Hokej , můžete použít tento vzorec:

=UNIQUE(FILTER(A2:B10, (C2:C10="Fotbal") + (C2:C10="Hokej")))

V případě potřeby můžete samozřejmě zadat kritéria do samostatných buněk a odkazovat na ně, jak je uvedeno níže:

=UNIQUE(FILTER(A2:B10, (C2:C10=G1) + (C2:C10=G2)))

Jak tento vzorec funguje:

Stejně jako při testování více kritérií AND umístíte několik logických výrazů do pole zahrnout argumentu funkce FILTER, z nichž každá vrací pole hodnot TRUE a FALSE. Po sečtení těchto polí budou mít položky, pro které je jedno nebo více kritérií TRUE, hodnotu 1 a položky, pro které jsou všechna kritéria FALSE, hodnotu 0. Výsledkem je, že každá položka, která splňuje jakoukoli podmínku, se dostane do pole, které je předáno funkci UNIQUE.

Další informace naleznete v části FILTROVÁNÍ s více kritérii pomocí logiky OR.

Získání jedinečných hodnot v aplikaci Excel bez ohledu na prázdná místa

Pokud pracujete se souborem dat, který obsahuje mezery, je pravděpodobné, že seznam unikátů získaný pomocí běžného vzorce bude obsahovat prázdnou buňku a/nebo nulovou hodnotu. K tomu dochází proto, že funkce UNIQUE aplikace Excel je navržena tak, aby vracela všechny odlišné hodnoty v rozsahu, včetně prázdných buněk. Pokud tedy váš zdrojový rozsah obsahuje jak nuly, tak prázdné buňky, bude seznam unikátů obsahovat 2 nuly, z nichž jedna bude představovat prázdnou buňku.Navíc pokud zdrojová data obsahují prázdné řetězce vrácené nějakým vzorcem, bude seznam uique obsahovat také prázdný řetězec (""), který vizuálně vypadá jako prázdná buňka:

Chcete-li získat seznam jedinečných hodnot bez prázdných míst, musíte provést následující kroky:

• Pomocí funkce FILTER odfiltrujte prázdné buňky a prázdné řetězce.
• Použijte funkci UNIQUE k omezení výsledků pouze na jedinečné hodnoty.

V obecné podobě vypadá vzorec takto:

V tomto příkladu je vzorec v D2 následující:

=UNIQUE(FILTER(B2:B12, B2:B12""))

Výsledkem je, že Excel vrátí seznam jedinečných názvů bez prázdných buněk:

Poznámka: Pokud původní data obsahují nuly , bude do jedinečného seznamu zahrnuta jedna nulová hodnota.

Vyhledání jedinečných hodnot v konkrétních sloupcích

Někdy můžete chtít získat jedinečné hodnoty ze dvou nebo více sloupců, které spolu nesousedí. Někdy také můžete chtít změnit pořadí sloupců ve výsledném seznamu. Oba úkoly lze splnit pomocí funkce CHOOSE.

Předpokládejme, že z naší vzorové tabulky chceme získat seznam výherců na základě hodnot ve sloupcích A a C a seřadit výsledky v tomto pořadí: nejprve sport (sloupec C) a poté jméno sportovce (sloupec A). Abychom to mohli provést, sestavíme tento vzorec:

=UNIQUE(CHOOSE({1,2}, C2:C10, A2:A10))

A získáte následující výsledek:

Jak tento vzorec funguje:

Funkce CHOOSE vrací dvourozměrné pole hodnot ze zadaných sloupců. V našem případě také prohodí pořadí sloupců.

{"Basketbal", "Andrew"; "Basketbal", "Betty"; "Volejbal", "David"; "Basketbal", "Andrew"; "Hokej", "Andrew"; "Fotbal", "Robert"; "Volejbal", "David"; "Hokej", "Andrew"; "Basketbal", "David"}

Funkce UNIQUE vrátí z výše uvedeného pole seznam jedinečných záznamů.

Vyhledávání jedinečných hodnot a zpracování chyb

Vzorce UNIQUE, které jsme probrali v tomto návodu, fungují perfektně... pokud existuje alespoň jedna hodnota, která splňuje zadaná kritéria. Pokud vzorec nic nenajde, dojde k chybě #CALC!:

Chcete-li tomu zabránit, jednoduše obalte vzorec funkcí IFERROR.

Pokud například nebyly nalezeny žádné jedinečné hodnoty splňující kritéria, můžete nezobrazit nic, tj. prázdný řetězec (""):

=IFERROR(UNIQUE(FILTER(A2:B10, (C2:C10=G1) * (D2:D10

Nebo můžete uživatele jasně informovat, že nebyly nalezeny žádné výsledky:

=IFERROR(UNIQUE(FILTER(A2:B10, (C2:C10=G1) * (D2:D10

Nefunkčnost funkce UNIQUE aplikace Excel

Jak jste se přesvědčili, vznik funkce UNIQUE neuvěřitelně usnadnil hledání jedinečných hodnot v aplikaci Excel. Pokud váš vzorec z ničeho nic vykazuje chybu, bude to s největší pravděpodobností jedna z následujících příčin.

#NAME?

Nastane, pokud použijete vzorec UNIQUE ve verzi aplikace Excel, kde tato funkce není podporována.

V současné době je funkce UNIKÁTNÍ k dispozici pouze v aplikaci Excel 365 a 2021. Pokud máte jinou verzi, můžete najít vhodné řešení v tomto návodu: Jak získat unikátní hodnoty v aplikaci Excel 2019, Excel 2016 a starší.

Chyba #NAME? v podporovaných verzích znamená, že název funkce je napsán chybně.

Chyba #SPILL

Vyskytne se, pokud jedna nebo více buněk v rozsahu vysypání není zcela prázdná.

Chcete-li chybu opravit, stačí vymazat nebo odstranit neprázdné buňky. Chcete-li přesně zjistit, které buňky překážejí, klikněte na indikátor chyby a poté na tlačítko Vyberte překážející buňky . Další informace naleznete v části Chyba #SPILL! v aplikaci Excel - příčiny a opravy.

Takto se v Excelu vyhledávají jedinečné hodnoty. Děkuji vám za přečtení a doufám, že se příští týden uvidíme na našem blogu!

Cvičebnice ke stažení

Příklady vzorců pro jedinečné hodnoty aplikace Excel (.xlsx soubor)