İçindekiler
Eğitimde Excel mantıksal işlevleri AND, OR, XOR ve NOT'un özü açıklanmakta ve bunların yaygın ve yaratıcı kullanımlarını gösteren formül örnekleri verilmektedir.
Geçen hafta, farklı hücrelerdeki verileri karşılaştırmak için kullanılan Excel mantıksal işleçlerinin içgörüsünden yararlandık. Bugün, mantıksal işleçlerin kullanımını nasıl genişleteceğinizi ve daha karmaşık hesaplamalar yapmak için daha ayrıntılı testler oluşturacağınızı göreceksiniz. AND, OR, XOR ve NOT gibi Excel mantıksal işlevleri bunu yapmanıza yardımcı olacaktır.
Excel mantıksal işlevleri - genel bakış
Microsoft Excel, mantıksal değerlerle çalışmak için 4 mantıksal işlev sağlar. İşlevler AND, OR, XOR ve NOT'tur. Bu işlevleri, formülünüzde birden fazla karşılaştırma yapmak veya yalnızca bir yerine birden çok koşulu test etmek istediğinizde kullanırsınız. Mantıksal işleçlerin yanı sıra Excel mantıksal işlevleri, bağımsız değişkenleri değerlendirildiğinde DOĞRU veya YANLIŞ döndürür.
Aşağıdaki tablo, belirli bir görev için doğru formülü seçmenize yardımcı olmak üzere her bir mantıksal işlevin ne yaptığına ilişkin kısa bir özet sunmaktadır.
| Fonksiyon | Açıklama | Formül Örneği | Formül Açıklaması |
| VE | Tüm bağımsız değişkenler TRUE olarak değerlendirilirse TRUE döndürür. | =AND(A2>=10, B2<5) | Formül, A2 hücresindeki bir değer 10'dan büyük veya eşitse ve B2'deki bir değer 5'ten küçükse DOĞRU, aksi takdirde YANLIŞ döndürür. |
| VEYA | Herhangi bir bağımsız değişken TRUE olarak değerlendirilirse TRUE döndürür. | =OR(A2>=10, B2<5) | A2 10'dan büyük veya eşitse ya da B2 5'ten küçükse veya her iki koşul da karşılanırsa formül DOĞRU sonucunu verir. Koşullardan hiçbiri karşılanmazsa formül YANLIŞ sonucunu verir. |
| XOR | Tüm bağımsız değişkenlerin mantıksal Exclusive Or değerini döndürür. | =XOR(A2>=10, B2<5) | A2 10'dan büyük veya eşitse ya da B2 5'ten küçükse formül DOĞRU sonucunu verir. Koşullardan hiçbiri karşılanmazsa veya her iki koşul da karşılanırsa formül YANLIŞ sonucunu verir. |
| DEĞİL | Bağımsız değişkeninin ters mantıksal değerini döndürür. Yani, bağımsız değişken FALSE ise TRUE döndürülür ve bunun tersi de geçerlidir. | =NOT(A2>=10) | A1 hücresindeki bir değer 10'dan büyük veya eşitse formül YANLIŞ döndürür; aksi takdirde DOĞRU döndürür. |
Yukarıda özetlenen dört mantıksal işleve ek olarak, Microsoft Excel 3 "koşullu" işlev sağlar - IF, IFERROR ve IFNA.
Excel mantıksal işlevleri - gerçekler ve rakamlar
- Mantıksal işlevlerin bağımsız değişkenlerinde, hücre başvurularını, sayısal ve metin değerlerini, Boole değerlerini, karşılaştırma işleçlerini ve diğer Excel işlevlerini kullanabilirsiniz. Ancak, tüm bağımsız değişkenler TRUE veya FALSE Boole değerlerine veya mantıksal değerler içeren başvurulara veya dizilere değerlendirilmelidir.
- Mantıksal bir fonksiyonun bir argümanı herhangi bir boş hücreler gibi değerler yoksayılır. Bağımsız değişkenlerin tümü boş hücreler ise, formül #DEĞER! hatası döndürür.
- Mantıksal işlevin bir bağımsız değişkeni sayı içeriyorsa, sıfır YANLIŞ olarak değerlendirilir ve negatif sayılar dahil diğer tüm sayılar DOĞRU olarak değerlendirilir. Örneğin, A1:A5 hücreleri sayı içeriyorsa, =AND(A1:A5) formülü, hücrelerden hiçbiri 0 içermiyorsa DOĞRU, aksi takdirde YANLIŞ döndürür.
- Mantıksal bir fonksiyon, bağımsız değişkenlerden hiçbiri mantıksal değerlere değerlendirilmezse #VALUE! hatası döndürür.
- Mantıksal bir işlev, işlevin adını yanlış yazdıysanız veya işlevi desteklemeyen önceki bir Excel sürümünde kullanmaya çalıştıysanız #ADI? hatası döndürür. Örneğin, XOR işlevi yalnızca Excel 2016 ve 2013'te kullanılabilir.
- Excel 2007 ve sonraki sürümlerde, formülün toplam uzunluğunun 8.192 karakteri aşmaması koşuluyla, mantıksal bir işleve 255 adede kadar bağımsız değişken ekleyebilirsiniz. Excel 2003 ve daha düşük sürümlerde, 30 adede kadar bağımsız değişken sağlayabilirsiniz ve formülünüzün toplam uzunluğu 1.024 karakteri aşmamalıdır.
Excel'de AND işlevini kullanma
AND fonksiyonu mantık fonksiyonları ailesinin en popüler üyesidir. Birkaç koşulu test etmeniz ve hepsinin karşılandığından emin olmanız gerektiğinde kullanışlı olur. Teknik olarak AND fonksiyonu belirttiğiniz koşulları test eder ve tüm koşullar DOĞRU olarak değerlendirilirse DOĞRU, aksi takdirde YANLIŞ döndürür.
Excel AND işlevinin sözdizimi aşağıdaki gibidir:
AND(mantıksal1, [mantıksal2], ...)Burada mantıksal, DOĞRU veya YANLIŞ olarak değerlendirilebilen test etmek istediğiniz koşuldur. İlk koşul (mantıksal1) gereklidir, sonraki koşullar isteğe bağlıdır.
Şimdi de Excel formüllerinde AND işlevlerinin nasıl kullanılacağını gösteren bazı formül örneklerine bakalım.
| Formül | Açıklama |
=AND(A2="Muz", B2>C2) | A2 "Bananas" içeriyorsa ve B2 C2'den büyükse TRUE, aksi takdirde FALSE döndürür. |
=AND(B2>20, B2=C2) | B2 20'den büyükse ve B2 C2'ye eşitse TRUE, aksi takdirde FALSE döndürür. |
=AND(A2="Muz", B2>=30, B2>C2) | A2 "Bananas" içeriyorsa, B2 30'dan büyük veya eşitse ve B2 C2'den büyükse TRUE, aksi takdirde FALSE döndürür. |
Excel AND işlevi - yaygın kullanımlar
Excel AND işlevi tek başına çok heyecan verici değildir ve dar bir kullanışlılığa sahiptir. Ancak diğer Excel işlevleriyle birlikte AND, çalışma sayfalarınızın yeteneklerini önemli ölçüde artırabilir.
Excel AND işlevinin en yaygın kullanımlarından biri, tek bir koşul yerine birkaç koşulu test etmek için IF işlevinin logical_test bağımsız değişkeninde bulunur. Örneğin, yukarıdaki AND işlevlerinden herhangi birini IF işlevinin içine yerleştirebilir ve buna benzer bir sonuç elde edebilirsiniz:
=IF(AND(A2="Muz", B2>C2), "İyi", "Kötü")
Daha fazla EĞER / VE formülü örneği için lütfen şu eğitime göz atın: Birden çok VE koşullu Excel EĞER işlevi.
ARASINDAKİ koşul için bir Excel formülü
Excel'de verilen iki değer arasındaki tüm değerleri seçen bir ara formül oluşturmanız gerekiyorsa, yaygın bir yaklaşım mantıksal testte VE ile EĞER işlevini kullanmaktır.
Örneğin, A, B ve C sütunlarında 3 değeriniz var ve A sütunundaki bir değerin B ve C değerleri arasında olup olmadığını bilmek istiyorsunuz. Böyle bir formül oluşturmak için tek gereken, iç içe AND ve birkaç karşılaştırma işleci içeren IF işlevidir:
X'in Y ile Z arasında olup olmadığını kontrol eden formül:
=IF(AND(A2>=B2,A2<=C2),"Yes", "No")
X'in Y ve Z arasında olup olmadığını kontrol eden formül, dahil değil:
=IF(AND(A2>B2, A2
Yukarıdaki ekran görüntüsünde gösterildiği gibi, formül tüm veri türleri için mükemmel çalışır - sayılar, tarihler ve metin değerleri. Metin değerlerini karşılaştırırken, formül bunları alfabetik sırayla karakter karakter kontrol eder. Örneğin, şunu belirtir Elmalar arasında değil Kayısı ve Muzlar çünkü ikinci "p" Elmalar "r "den önce gelir Kayısı Daha fazla bilgi için lütfen Excel karşılaştırma operatörlerini metin değerleriyle kullanma bölümüne bakın.
Gördüğünüz gibi, EĞER / VE formülü basit, hızlı ve neredeyse evrenseldir. "Neredeyse" diyorum çünkü tek bir senaryoyu kapsamıyor. Yukarıdaki formül, B sütunundaki bir değerin C sütunundan daha küçük olduğunu ima eder, yani B sütunu her zaman alt sınır değerini ve C - üst sınır değerini içerir. Formülün " Hayır " A6'nın 12, B6'nın 15 ve C6'nın 3 olduğu 6. satırın yanı sıra A8'in 24-Kasım, B8'in 26-Aralık ve C8'in 21-Ekim olduğu 8. satır için.
Peki ya between formülünüzün alt sınır ve üst sınır değerlerinin nerede olduğuna bakılmaksızın doğru çalışmasını istiyorsanız? Bu durumda, verilen sayıların medyanını (yani bir sayı kümesinin ortasındaki sayı) döndüren Excel MEDIAN işlevini kullanın.
Dolayısıyla, EĞER işlevinin mantıksal testinde AND yerine MEDIAN yazarsanız, formül şu şekilde olacaktır:
=IF(A2=MEDIAN(A2:C2), "Evet", "Hayır")
Ve aşağıdaki sonuçları alacaksınız:
Gördüğünüz gibi, MEDIAN işlevi sayılar ve tarihler için mükemmel çalışıyor, ancak metin değerleri için #NUM! hatası döndürüyor. Ne yazık ki, kimse mükemmel değil : )
Metin değerlerinin yanı sıra sayılar ve tarihler için de çalışan mükemmel bir Between formülü istiyorsanız, AND / OR işlevlerini kullanarak aşağıdaki gibi daha karmaşık bir mantıksal metin oluşturmanız gerekecektir:
=IF(OR(AND(A2>B2, A2
Excel'de VEYA işlevini kullanma
Excel OR işlevi, AND işlevinin yanı sıra iki değeri veya ifadeyi karşılaştırmak için kullanılan temel bir mantıksal işlevdir. Aradaki fark, OR işlevinin bağımsız değişkenlerden en az biri DOĞRU olarak değerlendirilirse DOĞRU, tüm bağımsız değişkenler YANLIŞ ise YANLIŞ döndürmesidir. OR işlevi, Excel 2016 - 2000'in tüm sürümlerinde mevcuttur.
Excel OR işlevinin sözdizimi AND işlevine çok benzer:
OR(mantıksal1, [mantıksal2], ...)Burada mantıksal, DOĞRU veya YANLIŞ olabilen test etmek istediğiniz bir şeydir. İlk mantıksal gereklidir, ek koşullar (modern Excel sürümlerinde 255'e kadar) isteğe bağlıdır.
Şimdi de Excel'de OR fonksiyonunun nasıl çalıştığını anlamanız için birkaç formül yazalım.
| Formül | Açıklama |
=OR(A2="Bananas", A2="Oranges") | A2 "Bananas" veya "Oranges" içeriyorsa TRUE, aksi takdirde FALSE döndürür. |
=OR(B2>=40, C2>=20) | B2 40'tan büyük veya eşitse ya da C2 20'den büyük veya eşitse TRUE, aksi takdirde FALSE döndürür. |
=OR(B2=" ",) | B2 veya C2'den biri veya her ikisi de boşsa TRUE, aksi takdirde FALSE döndürür. |
Excel AND fonksiyonunun yanı sıra OR, IF fonksiyonu gibi mantıksal testler gerçekleştiren diğer Excel fonksiyonlarının kullanışlılığını genişletmek için yaygın olarak kullanılır. İşte sadece birkaç örnek:
İç içe OR içeren IF fonksiyonu
=IF(OR(B2>30, C2>20), "İyi", "Kötü")
Formül " İyi " B3 hücresindeki bir sayı 30'dan büyükse veya C2'deki sayı 20'den büyükse, " Kötü " aksi takdirde.
Tek bir formülde Excel AND / OR işlevleri
Doğal olarak, iş mantığınız bunu gerektiriyorsa, AND & OR işlevlerinin her ikisini de tek bir formülde kullanmanızı engelleyen hiçbir şey yoktur. Aşağıdaki temel kalıplara indirgenen bu tür formüllerin sonsuz varyasyonu olabilir:
=AND(OR(Cond1, Cond2), Cond3)
=AND(OR(Cond1, Cond2), OR(Cond3, Cond4)
=OR(AND(Cond1, Cond2), Cond3)
=OR(AND(Cond1,Cond2), AND(Cond3,Cond4))
Örneğin, hangi muz ve portakal sevkiyatlarının tükendiğini bilmek istiyorsanız, yani "Stokta var" sayısı (sütun B) "Satıldı" sayısına (sütun C) eşitse, aşağıdaki OR/AND formülü bunu size hızlı bir şekilde gösterebilir:
=OR(AND(A2="muz", B2=C2), AND(A2="portakal", B2=C2))
Excel koşullu biçimlendirmede OR işlevi
=OR($B2="", $C2="")
Yukarıdaki VEYA formülüne sahip kural, B veya C sütununda ya da her ikisinde de boş hücre içeren satırları vurgular.
Koşullu biçimlendirme formülleri hakkında daha fazla bilgi için lütfen aşağıdaki makalelere bakın:
- Excel koşullu biçimlendirme formülleri
- Bir hücrenin değerine göre satır rengini değiştirme
- Bir hücrenin rengini başka bir hücre değerine göre değiştirme
- Excel'de diğer her satırı vurgulama
Excel'de XOR işlevini kullanma
Microsoft, Excel 2013'te mantıksal bir işlem olan XOR işlevini tanıttı Özel VEYA Bu terim, herhangi bir programlama dili veya genel olarak bilgisayar bilimi hakkında biraz bilgi sahibi olanlarınız için kesinlikle tanıdıktır. Olmayanlar için, 'Exclusive Or' kavramını ilk başta kavramak biraz zor olabilir, ancak formül örnekleriyle gösterilen aşağıdaki açıklamanın yardımcı olacağını umuyoruz.
XOR fonksiyonunun sözdizimi OR ile aynıdır:
XOR(mantıksal1, [mantıksal2],...)İlk mantıksal ifade (Mantıksal 1) gereklidir, ek mantıksal değerler isteğe bağlıdır. Bir formülde 254 adede kadar koşulu test edebilirsiniz ve bunlar DOĞRU veya YANLIŞ olarak değerlendirilen mantıksal değerler, diziler veya başvurular olabilir.
En basit versiyonda, bir XOR formülü sadece 2 mantıksal ifade içerir ve geri döner:
- Bağımsız değişkenlerden biri TRUE olarak değerlendirilirse TRUE olur.
- Her iki bağımsız değişken de DOĞRU ise veya hiçbiri DOĞRU değilse FALSE.
Bunu formül örneklerinden anlamak daha kolay olabilir:
| Formül | Sonuç | Açıklama |
=XOR(1>0, 2<1) | DOĞRU | TRUE döndürür çünkü 1. bağımsız değişken TRUE ve 2. bağımsız değişken FALSE'dir. |
=XOR(1<0, 2<1) | YANLIŞ | Her iki bağımsız değişken de FALSE olduğundan FALSE döndürür. |
=XOR(1>0, 2>1) | YANLIŞ | Her iki bağımsız değişken de TRUE olduğundan FALSE döndürür. |
Daha fazla mantıksal ifade eklendiğinde, Excel'deki XOR işlevi şu sonucu verir:
- Tek sayıda bağımsız değişken TRUE olarak değerlendirilirse TRUE olur;
- TRUE ifadelerinin toplam sayısı çift ise veya tüm ifadeler FALSE ise FALSE.
Aşağıdaki ekran görüntüsü konuyu açıklamaktadır:
Excel XOR fonksiyonunun gerçek hayat senaryosuna nasıl uygulanabileceğinden emin değilseniz, aşağıdaki örneği göz önünde bulundurun. Elinizde yarışmacıların ve ilk 2 oyun için sonuçlarının yer aldığı bir tablo olduğunu varsayalım. 3. oyunu aşağıdaki koşullara göre hangi yarışmacının oynayacağını bilmek istiyorsunuz:
- Oyun 1 ve Oyun 2'yi kazanan yarışmacılar otomatik olarak bir sonraki tura geçer ve Oyun 3'ü oynamak zorunda kalmazlar.
- İlk iki oyunu da kaybeden yarışmacılar elenir ve 3. Oyunu da oynamazlar.
- Oyun 1 veya Oyun 2'yi kazanan yarışmacılar, kimin bir sonraki tura geçip kimin geçemeyeceğini belirlemek için Oyun 3 oynayacaklardır.
Basit bir XOR formülü tam olarak istediğimiz gibi çalışır:
=XOR(B2="Kazandı", C2="Kazandı")
Ve bu XOR işlevini IF formülünün mantıksal testine yerleştirirseniz, daha da mantıklı sonuçlar elde edersiniz:
=IF(XOR(B2="Kazandı", C2="Kazandı"), "Evet", "Hayır")
Excel'de DEĞİL işlevini kullanma
NOT işlevi, sözdizimi açısından en basit Excel işlevlerinden biridir:
DEĞİL(mantıksal)Excel'de DEĞİL işlevini, bağımsız değişkeninin değerini tersine çevirmek için kullanırsınız. Başka bir deyişle, mantıksal değerlendirme YANLIŞ ise, DEĞİL işlevi DOĞRU döndürür ve bunun tersi de geçerlidir. Örneğin, aşağıdaki formüllerin her ikisi de YANLIŞ döndürür:
=NOT(TRUE)
=NOT(2*2=4)
Neden bu kadar saçma sonuçlar elde etmek isteyesiniz ki? Bazı durumlarda, belirli bir koşulun ne zaman sağlandığından ziyade ne zaman sağlanmadığını bilmek daha çok ilginizi çekebilir. Örneğin, bir kıyafet listesini incelerken, size uymayan bir rengi hariç tutmak isteyebilirsiniz. Ben özellikle siyahı sevmiyorum, bu yüzden bu formülle devam ediyorum:
=NOT(C2="siyah")
Her zaman olduğu gibi, Microsoft Excel'de bir şeyi yapmanın birden fazla yolu vardır ve aynı sonucu Eşit değil işlecini kullanarak da elde edebilirsiniz: =C2 "siyah".
Tek bir formülde birden fazla koşulu test etmek istiyorsanız, VE veya VEYA işleviyle bağlaçlar içinde DEĞİL kullanabilirsiniz. Örneğin, siyah ve beyaz renkleri hariç tutmak istiyorsanız, formül şu şekilde olacaktır:
=NOT(OR(C2="black", C2="white"))
Siyah bir ceket veya sırt kürkü düşünülebilirken siyah bir paltoya sahip olmayı tercih etmiyorsanız, Excel AND işleviyle birlikte NOT kullanmalısınız:
=NOT(AND(C2="black", B2="coat"))
Excel'de DEĞİL işlevinin bir diğer yaygın kullanımı, başka bir işlevin davranışını tersine çevirmektir. Örneğin, Microsoft Excel'de bulunmayan ISNOTBLANK formülünü oluşturmak için DEĞİL ve ISBLANK işlevlerini birleştirebilirsiniz.
Bildiğiniz gibi, =ISBLANK(A2) formülü A2 hücresi boşsa DOĞRU değerini döndürür. NOT işlevi bu sonucu YANLIŞ olarak tersine çevirebilir: =NOT(ISBLANK(A2))
Ardından, bir adım daha ileri gidebilir ve gerçek hayattaki bir görev için NOT / ISBLANK işlevleriyle iç içe geçmiş bir IF deyimi oluşturabilirsiniz:
=IF(NOT(ISBLANK(C2)), C2*0.15, "İkramiye yok :(")
Düz İngilizceye çevrildiğinde, formül Excel'e aşağıdakileri yapmasını söyler. C2 hücresi boş değilse, C2'deki sayıyı 0,15 ile çarpın, bu da fazladan satış yapan her satıcıya %15 bonus verir. C2 boşsa, "Bonus yok :(" metni görünür.
Özünde, Excel'de mantıksal işlevleri bu şekilde kullanırsınız. Elbette, bu örnekler AND, OR, XOR ve NOT özelliklerinin yalnızca yüzeyini çizdi. Temel bilgileri öğrendikten sonra, artık gerçek görevlerinizi ele alarak ve çalışma sayfalarınız için akıllı ayrıntılı formüller yazarak bilginizi genişletebilirsiniz.
