ٽيوٽوريل ڏيکاري ٿو ته ڪيئن ايڪسل ۾ مختلف ٽيڪسٽ اسٽرنگز مان نمبر ڪڍڻ لاءِ فارمولن ۽ Extract ٽول ذريعي.

جڏهن اها ڳالهه اچي ٿي ته ڏنل ڊگھائي جي ٽيڪسٽ اسٽرنگ جو حصو ڪڍڻ جي. , Excel مهيا ڪري ٿو ٽي سب اسٽرنگ افعال (کاٻي، ساڄي ۽ وچ) جلدي ڪم کي سنڀالڻ لاءِ. جڏهن اها الفانومريڪ اسٽرنگ مان نمبر ڪڍڻ جي ڳالهه اچي ٿي، Microsoft Excel مهيا ڪري ٿو... ڪجھ به نه.

Excel ۾ هڪ اسٽرنگ مان نمبر حاصل ڪرڻ لاءِ، ٿوري سمجهه، ٿورو صبر، ۽ مختلف ڪمن جو هڪ گروپ گهرجي. هڪ ٻئي ۾ جڪڙيل. يا، توھان ھلائي سگھوٿا Extract Tool ۽ ڪم ڪيو آھي مائوس جي ڪلڪ سان. هيٺ توهان کي ٻنهي طريقن تي مڪمل تفصيل ملندا.

ٽيڪسٽ اسٽرنگ جي پڇاڙيءَ مان نمبر ڪيئن ڪڍجي

جڏهن توهان وٽ الفانيمرڪ اسٽرنگ جو ڪالم هجي جتي نمبر بعد ۾ اچي متن، توھان ھيٺ ڏنل فارمولا استعمال ڪري سگھوٿا ان کي حاصل ڪرڻ لاءِ.

اسان ٿوري دير بعد فارمولا جي منطق تي غور ڪنداسين. هاڻي لاءِ، رڳو سيل کي سيل جي حوالي سان تبديل ڪريو جنهن ۾ اصل اسٽرنگ هجي (اسان جي صورت ۾ A2)، ۽ ساڳي قطار ۾ ڪنهن به خالي سيل ۾ فارمولا داخل ڪريو، B2 ۾ چئو:

=RIGHT(A2, LEN(A2) - MAX(IF(ISNUMBER(MID(A2, ROW(INDIRECT("1:"&LEN(A2))), 1) *1)=FALSE, ROW(INDIRECT("1:"&LEN(A2))), 0)))

هي فارمولا صرف آخر کان نمبر حاصل ڪري ٿو. جيڪڏهن هڪ اسٽرنگ جي شروعات يا وچ ۾ انگ به آهن، اهي آهننظر انداز ڪيو ويو:

ايڪسٽريشن RIGHT فنڪشن سان ڪيو ويندو آهي جيڪو ٽيڪسٽ افعال جي درجي سان تعلق رکي ٿو. ھن فنڪشن جو ٻاھر ھميشه text آھي. اسان جي صورت ۾، نتيجو هڪ عددي سبسٽرنگ آهي، جيڪو ايڪسل جي لحاظ کان پڻ متن آهي، نمبر نه.

جيڪڏهن توهان کي نتيجو گهرجي نمبر (جيڪو توهان وڌيڪ حسابن ۾ استعمال ڪري سگهو ٿا)، پوءِ فارمولا کي VALUE فنڪشن ۾ لپايو يا اهڙو رياضي وارو عمل انجام ڏيو جيڪو نتيجو تبديل نه ڪري، چئو، 1 سان ضرب ڪريو يا 0 شامل ڪريو. انهن تارن ۾ غلطيون پڪڙڻ لاءِ جن ۾ الف شامل نه آهي. واحد نمبر، IFERROR فنڪشن استعمال ڪريو. مثال طور:

=IFERROR(VALUE(RIGHT(A2, LEN(A2) - MAX(IF(ISNUMBER(MID(A2, ROW(INDIRECT("1:"&LEN(A2))), 1)*1)=FALSE, ROW(INDIRECT("1:"&LEN(A2))), 0)))), "")

يا

=IFERROR(RIGHT(A2, LEN(A2) - MAX(IF(ISNUMBER(MID(A2, ROW(INDIRECT("1:"&LEN(A2))), 1) *1)=FALSE, ROW(INDIRECT("1:"&LEN(A2))), 0))) +0, "")

11>

نوٽ. Dynamic Array Excel (Office 365 ۽ 2021) ۾، توهان فارمولا داخل ڪريو عام طريقي سان Enter key سان. Excel 2019 ۽ اڳ ۾، اهو صرف هڪ صف فارمولا طور ڪم ڪري ٿو، تنهنڪري ان کي مڪمل ڪرڻ لاءِ Ctrl + Shift + Enter کي دٻائڻ ياد رکو.

هي فارمولا ڪيئن ڪم ڪندو آهي:

الفانومريڪ اسٽرنگ مان نمبر ڪڍڻ لاءِ، پهرين شيءِ جيڪا توهان کي ڄاڻڻ جي ضرورت آهي اها آهي ته استخراج ڪٿي شروع ڪجي. هڪ تار ۾ آخري غير عددي ڪردار جي پوزيشن هن مشڪل فارمولي جي مدد سان طئي ڪئي وئي آهي:

MAX(IF(ISNUMBER(MID(A2, ROW(INDIRECT("1:"&LEN( A2)))، 1)*1)=FALSE، ROW(INDIRECT("1:"&LEN(A2)))، 0))

منطق کي سمجھڻ لاءِ، اچو ته ان جي اندر کان جاچ ڪريون :

The ROW(Indirect("1:"&LEN(A2))) ميلاپسورس اسٽرنگ (A2) ۾ اکرن جي ڪل سان ملندڙ انگن جو هڪ سلسلو ٺاهي ٿو، ۽ اسان انهن ترتيب وار نمبرن کي MID کي شروعاتي نمبرن طور پيش ڪريون ٿا:

MID(A2, {1;2;3;4) ;5;6;7;8}, 1)

MID فنڪشن هر فرد کي A2 مان ڪڍندو آهي ۽ انهن کي هڪ صف طور واپس ڪري ٿو:

{"0"؛"5"؛" -"؛"اي"؛"سي"؛"-"؛"0"؛"1"

جيئن ته MID هڪ ٽيڪسٽ فنڪشن آهي، ان جو آئوٽ پٽ هميشه ٽيڪسٽ هوندو آهي (جيئن توهان نوٽيس ڪري سگهو ٿا، سڀ اکر اقتباس جي نشانين ۾ بند ٿيل آهن). انگن اکرن کي انگن ۾ تبديل ڪرڻ لاء، اسان صف کي 1 سان ضرب ڪريون ٿا (ڊبل منفي --MID () ساڳيو اثر ٿيندو). ھن آپريشن جو نتيجو آھي انگن جي ھڪڙي صف ۽ #VALUE! غلطيون جيڪي غير عددي اکرن جي نمائندگي ڪن ٿيون:

ISNUMBER({0;5;#VALUE!;#VALUE!;#VALUE!;#VALUE!;0;1})

The ISNUMBER فنڪشن صف جي هر عنصر جو اندازو لڳائي ٿو ۽ ان جو فيصلو بولين ويلز جي صورت ۾ ڏئي ٿو - انگن لاءِ صحيح، ڪنهن به شيءِ لاءِ غلط:

{TRUE;TRUE;FALSE;FALSE;FALSE;FALSE;TRUE;TRUE}

هي صف IF فنڪشن جي منطقي امتحان ڏانهن وڃي ٿي، جتي صف جي هر عنصر جو مقابلو FALSE سان ڪيو وڃي ٿو:

IF({TRUE;TRUE;FALSE;FALSE;FALSE;FALSE;TRUE ؛TRUE}=FALSE، ROW(INDIRECT("1:"&LEN(A2)))، 0)

هر غلط (غير عددي قدر) لاءِ، ٻيو ROW(INDIRECT()) فنڪشن موٽائي ٿو تار ۾ ان جي نسبتي پوزيشن. هر TRUE (عددي قدر) لاءِ، هڪ صفر موٽايو ويندو آهي. نتيجي ۾ صفا ڏسجي ٿوھيٺ ڏنل آھي:

{0;0;3;4;5;6;0;0}

باقي آسان آھي. MAX فنڪشن مٿي ڏنل صف ۾ سڀ کان وڌيڪ نمبر ڳولي ٿو، جيڪو اسٽرنگ ۾ آخري غير عددي قدر جي پوزيشن آهي (اسان جي صورت ۾ 6). بس، LEN پاران واپس ڪيل اسٽرنگ جي ڪل ڊگھائي مان ان پوزيشن کي گھٽايو، ۽ نتيجو کي ساڄي طرف پاس ڪريو ته جيئن ان کي خبر پوي ته اسٽرنگ جي ساڄي پاسي کان ڪيترا اکر ڪڍڻا آھن:

Right(A2, LEN) (A2) - 6)

Done!

Text string جي شروعات کان نمبر ڪيئن ڪڍجي

جيڪڏهن توهان رڪارڊ سان ڪم ڪري رهيا آهيو جتي متن نمبر کان پوءِ ظاهر ٿئي ٿو، توهان ڪري سگهو ٿا هن عام فارمولا کي استعمال ڪندي اسٽرنگ جي شروعات کان نمبر ڪڍو:

A2 ۾ اصل اسٽرنگ سان، نمبر حاصل ڪرڻ لاءِ ھيٺ ڏنل فارمولا استعمال ڪريو:

=LEFT(A2, MATCH(FALSE, ISNUMBER(MID(A2, ROW(INDIRECT("1:"&LEN(A2)+1)), 1) *1), 0) -1)

ڪو به فرق نه پوي ته وچين يا آخر ۾ ڪيترا عدد هجن، صرف شروعاتي نمبر ڪڍيو ويندو آهي:

نوٽ. ايڪسل 365 ۽ ايڪسل 2021 ۾، متحرڪ صفن جي حمايت جي ڪري، هڪ باقاعده فارمولا ٺيڪ ڪم ڪري ٿو. Excel 2019 ۽ اڳ ۾، توهان کي Ctrl + Shift + Enter کي دٻائڻ گهرجي واضح طور تي ان کي هڪ اري فارمولا .

هي فارمولا ڪيئن ڪم ڪري ٿو:

هتي، اسان ٻيهر استعمال ڪريون ٿا ROW، INDIRECT ۽ LEN افعال جي ميلاپ کي ترتيب ڏيڻ لاءِ انگن جو هڪ تسلسل ٺاهيو جيڪو ماخذ اسٽرنگ پلس 1 ۾ ڪردارن جي ڪل جي برابر آهي (ان جو ڪرداراضافي ڪردار ٿوري دير بعد واضح ٿي ويندا.

ROW(INDIRECT("1:"&LEN(A2)+1))

MID ۽ ISNUMBER ساڳيو ڪم ڪن ٿا پويون مثال - MID انفرادي اکرن کي ڇڪي ٿو ۽ ISNUMBER انهن کي منطقي قدرن ۾ تبديل ڪري ٿو. TRUE's and FALSE's جي نتيجي ۾ نڪرندڙ صف MATCH فنڪشن ڏانهن وڃي ٿي ڏسندڙ صف جي طور تي:

MATCH(FALSE, {TRUE;TRUE;FALSE;FALSE;FALSE;FALSE;TRUE;TRUE;FALSE},0)

MATCH پھرين FALSE جي ھڪ لاڳاپي واري پوزيشن کي شمار ڪري ٿو، اسان کي اسٽرنگ ۾ پھرين غير عددي ڪردار جي پوزيشن ڏئي ٿو (3 ۾ A2). اڳئين انگن کي ڪڍڻ لاءِ، اسان 1 کي پھرئين ٽيڪسٽ اکر جي پوزيشن مان گھٽائيندا آھيون ۽ فرق ڏيون ٿا num_chars LEFT فنڪشن جي دليل:

LEFT(A2, 3-1)

هاڻي، واپس وڃو هڪ "اضافي" ڪردار ڏانهن جيڪو ترتيب ڏنل ترتيب ۾ ROW(INDIRECT()+1)). جئين توهان اڳ ۾ ئي ڄاڻو ٿا، هي سلسلو MID فنڪشن لاء شروعاتي پوائنٽ مهيا ڪري ٿو. +1 کان سواءِ، MID بلڪل اکر ڪڍندو جيترو اکر اصل اسٽرنگ ۾ آهن. جيڪڏهن اسٽرنگ صرف انگن تي مشتمل آهي، ISNUMBER صرف TRUE جي موٽ ڏيندو جڏهن ته MATCH کي گهٽ ۾ گهٽ هڪ FALSE جي ضرورت آهي. انهي کي يقيني بڻائڻ لاءِ، اسان اسٽرنگ جي ڪل ڊگھائي ۾ هڪ وڌيڪ ڪردار شامل ڪندا آهيون، جنهن کي MID فنڪشن هڪ خالي اسٽرنگ ۾ تبديل ڪندو. مثال طور، B7 ۾، MID ھن صف کي موٽائي ٿو:

{"1"؛"2"؛"3"؛"4"؛""

نوٽ. جيئن ته RIGHT فنڪشن سان معاملو آهي، LEFT پڻ هڪ عددي موٽائي ٿوsubstring ، جيڪو ٽيڪنيڪل طور تي متن آهي، نمبر نه. نتيجو حاصل ڪرڻ لاءِ عددي اسٽرنگ جي بجاءِ انگ جي طور تي، فارمولا کي VALUE فنڪشن ۾ نسٽ ڪريو يا نتيجي کي 1 سان ضرب ڪريو جيئن پھرين مثال ۾ ڏيکاريل آھي.

اسٽرنگ ۾ ڪنھن به پوزيشن مان نمبر ڪيئن حاصل ڪجي

جيڪڏهن توهان جو ڪم ڪنهن سٽرنگ ۾ ڪٿي به نمبر ڪڍڻ جو مطلب آهي، ته توهان MrExcel فورم تي شايع ٿيل هيٺين ذهن کي ڇڪائڻ وارو فارمولا استعمال ڪري سگهو ٿا:

=SUMPRODUCT(MID(0&A2, LARGE(INDEX(ISNUMBER(--MID(A2, ROW(INDIRECT("1:"&LEN(A2))), 1)) * ROW(INDIRECT("1:"&LEN(A2))), 0), ROW(INDIRECT("1:"&LEN(A2))))+1, 1) * 10^ROW(INDIRECT("1:"&LEN(A2)))/10)

جتي A2 آهي اصل ٽيڪسٽ اسٽرنگ.

هن فارمولا کي ٽوڙڻ لاءِ هڪ الڳ مضمون جي ضرورت پوندي، تنهنڪري توهان ان کي پنهنجي ورڪ شيٽ ۾ ڪاپي ڪري سگهو ٿا ته جيئن اهو يقيني بڻائي سگهجي ته اهو واقعي ڪم ڪري ٿو :)

نتيجن کي جانچڻ تي، تنهن هوندي به، توهان شايد هڪ اهم خرابي محسوس ڪري سگهون ٿا - جيڪڏهن ماخذ اسٽرنگ نمبر تي مشتمل نه آهي، فارمولا صفر ڏي ٿو، جيئن مٿي ڏنل اسڪرين شاٽ ۾ قطار 6 ۾. ھن کي درست ڪرڻ لاءِ، توھان IF بيان ۾ فارمولا لپائي سگھو ٿا، جنھن جو منطقي امتحان چيڪ ڪري ٿو ته ڇا ماخذ اسٽرنگ ۾ ڪو نمبر آھي. جيڪڏهن ائين ٿئي ٿو، فارمولا نمبر ڪڍي ٿو، ٻي صورت ۾ هڪ خالي اسٽرنگ موٽائي ٿو:

=IF(SUM(LEN(A2)-LEN(SUBSTITUTE(A2, {"0","1","2","3","4","5","6","7","8","9"}, "")))>0, SUMPRODUCT(MID(0&A2, LARGE(INDEX(ISNUMBER(--MID(A2,ROW(INDIRECT("$1:$"&LEN(A2))),1))* ROW(INDIRECT("$1:$"&LEN(A2))),0), ROW(INDIRECT("$1:$"&LEN(A2))))+1,1) * 10^ROW(INDIRECT("$1:$"&LEN(A2)))/10),"")

جيئن هيٺ ڏنل اسڪرين شاٽ ۾ ڏيکاريل آهي، بهتر فارمولا سهڻي طريقي سان ڪم ڪري ٿو (الڪس کي ساراهيو، اسان جي ايڪسل گرو، ھن سڌاري لاءِ):

سڀني اڳئين مثالن جي برعڪس، ھن فارمولا جو نتيجو آھي نمبر . انهي کي يقيني بڻائڻ لاءِ، صرف ڪالمن B ۾ ساڄي طرف سان ترتيب ڏنل قدرن کي ڏسو ۽ اڳئين زيرو کي ٽوڙيو.

ٽپ. Excel 365 ۾ -Excel 2019، TEXTJOIN فنڪشن جي مدد سان هڪ تمام آسان حل آهي. مھرباني ڪري ڏسو ته ٽيڪسٽ ڪيئن ختم ڪجي ۽ نمبر ڪيئن رکيا وڃن.

الٽيميٽ سوٽ سان ٽيڪسٽ اسٽرنگ مان نمبر ڪڍو

جيئن توھان ڏٺو آھي، ٽيڪسٽ اسٽرنگ مان نمبر ڪڍڻ لاءِ ڪو معمولي Excel فارمولا نه آھي. جيڪڏھن توھان کي پنھنجي ڊيٽا سيٽن لاءِ فارمولين کي سمجھڻ يا انھن کي ٽوڪ ڪرڻ ۾ ڏکيائي پيش اچي ٿي، ته توھان کي پسند ڪري سگھوٿا ھي آسان طريقو Excel ۾ اسٽرنگ مان نمبر حاصل ڪرڻ لاءِ.

اسان جي الٽيميٽ سوٽ سان توھان جي Excel ربن ۾ شامل ڪيو ويو آھي، ھي آھي توھان ڪنهن به الفانمري اسٽرنگ مان جلدي نمبر ٻيهر حاصل ڪري سگهو ٿا:

1. وڃو Ablebits Data ٽئب > Text گروپ، ۽ ڪلڪ ڪريو Extract :

   

2. سڀني سيلن کي منتخب ڪريو ماخذ اسٽرنگ سان.
3. Extract Tool جي پين تي، منتخب ڪريو Extract numbers radio button.
4. ان تي منحصر ڪري ٿو ته ڇا توھان چاھيو ٿا نتيجا فارمولا ھجن يا قدر، منتخب ڪريو Insert as formula باڪس يا ان کي غير منتخب ٿيل ڇڏي ڏيو (ڊفالٽ).

   منهنجو مشورو آهي ته هن باڪس کي چونڊيو جيڪڏهن توهان چاهيو ٿا ته ڪڍيا ويا نمبر پاڻمرادو اپڊيٽ ٿين جيئن ئي سورس اسٽرنگ ۾ ڪا به تبديلي ٿيندي. جيڪڏھن توھان چاھيو ٿا ته نتيجا اصل اسٽرنگ تي آزاد ھجن (مثال طور جيڪڏھن توھان رٿابندي ڪري رھيا آھيو ماخذ ڊيٽا کي ختم ڪرڻ جو بعد ۾)، پوءِ ھن دٻي کي نه چونڊيو.

5. ڪلڪ ڪريو نتيجا داخل ڪريو بٽڻ. ٿي ويو!

اڳئين مثال وانگر، نتيجن جا نتيجاڪڍڻ نمبر آهن ، مطلب ته توهان انهن سان ڳڻڻ، رقم، اوسط، يا ٻيو ڪو به حساب ڪرڻ لاءِ آزاد آهيو.

هن مثال ۾، اسان نتيجن کي <9 طور داخل ڪرڻ لاءِ چونڊيو آهي>values ، ۽ add-in بلڪل ائين ڪيو جيڪو پڇيو ويو:

جيڪڏهن Insert as formula چيڪ باڪس چونڊيو ويو، توهان ' d هڪ فارمولا فارمولا بار ۾ ڏسو. ڄاڻڻ جو شوق آهي ته ڪهڙو؟ بس الٽيميٽ سوٽ جي آزمائش کي ڊائون لوڊ ڪريو ۽ پاڻ لاءِ ڏسو :)

دستياب ڊائون لوڊ

Excel Extract نمبر - نموني ورڪ بڪ (.xlsx فائل)

الٽيميٽ سوٽ - آزمائشي ورزن (.exe فائل)