এই সূত্ৰটোৱে শেষৰ পৰাহে সংখ্যা পায়। যদি এটা ষ্ট্ৰিংৰ আৰম্ভণি বা মাজতো সংখ্যা থাকে, তেন্তে সেইবোৰ আছেignored:

এক্সট্ৰেকচন RIGHT ফাংচনৰ সৈতে কৰা হয় যি টেক্সট ফাংচনৰ শ্ৰেণীৰ অন্তৰ্গত। এই ফাংচনৰ আউটপুট সদায় text । আমাৰ ক্ষেত্ৰত ফলাফলটো হ'ল সংখ্যাগত উপষ্ট্ৰিং , যিটো এক্সেলৰ ক্ষেত্ৰতো টেক্সট, সংখ্যা নহয়।

যদি আপুনি ফলাফলটো সংখ্যা হ'ব লাগে (যি আপুনি অধিক গণনাত ব্যৱহাৰ কৰিব পাৰে), তাৰ পিছত সূত্ৰটো VALUE ফাংচনত ৰেপ কৰক বা এটা গাণিতিক কাৰ্য্য সম্পাদন কৰক যি ফলাফল সলনি নকৰে, ধৰক, 1 ৰে গুণ কৰক বা 0 যোগ কৰক একক সংখ্যা, IFERROR ফাংচন ব্যৱহাৰ কৰক। যেনে:

=IFERROR(VALUE(RIGHT(A2, LEN(A2) - MAX(IF(ISNUMBER(MID(A2, ROW(INDIRECT("1:"&LEN(A2))), 1)*1)=FALSE, ROW(INDIRECT("1:"&LEN(A2))), 0)))), "")

বা

=IFERROR(RIGHT(A2, LEN(A2) - MAX(IF(ISNUMBER(MID(A2, ROW(INDIRECT("1:"&LEN(A2))), 1) *1)=FALSE, ROW(INDIRECT("1:"&LEN(A2))), 0))) +0, "")

টোকা। ডাইনামিক এৰে এক্সেল (Office 365 আৰু 2021) ত, আপুনি Enter কি'ৰ সৈতে সাধাৰণ ধৰণে সূত্ৰটো প্ৰৱেশ কৰে। Excel 2019 আৰু ইয়াৰ আগৰ, ই কেৱল এটা এৰে সূত্ৰ হিচাপে কাম কৰে, গতিকে ইয়াক সম্পূৰ্ণ কৰিবলৈ Ctrl + Shift + Enter টিপিবলৈ মনত ৰাখিব।

এই সূত্ৰটোৱে কেনেকৈ কাম কৰে:

এটা আলফানিউমেৰিক ষ্ট্ৰিঙৰ পৰা সংখ্যা এক্সট্ৰেক্ট কৰিবলৈ, আপুনি প্ৰথমে জানিব লাগিব যে এক্সট্ৰেকচন ক'ৰ পৰা আৰম্ভ কৰিব লাগে। এই কৌশলী সূত্ৰৰ সহায়ত এটা ষ্ট্ৰিংত শেষৰ অসংখ্যাগত আখৰৰ অৱস্থান নিৰ্ধাৰণ কৰা হয়:

MAX(IF(ISNUMBER(MID(A2, ROW(INDIRECT("1:"&LEN() A2))), 1)*1)=FALSE, ROW(INDIRECT("1:"&LEN(A2))), 0))

যুক্তি বুজিবলৈ ভিতৰৰ পৰা অনুসন্ধান কৰা যাওক :

ROW(INDIRECT("1:"&LEN(A2))) সংমিশ্ৰণউৎস ষ্ট্ৰিং (A2) ৰ মুঠ আখৰৰ সৈতে সংগতি ৰাখি সংখ্যাৰ এটা ক্ৰম সৃষ্টি কৰে, আৰু আমি এই ক্ৰমিক সংখ্যাসমূহক MID লৈ আৰম্ভণি সংখ্যা হিচাপে সেৱা আগবঢ়াওঁ:

MID(A2, {1;2;3;4 ;5;6;7;8}, 1)

MID ফাংচনে A2 ৰ পৰা প্ৰতিটো ব্যক্তিগত আখৰ টানে আৰু সিহতক এটা এৰে হিচাপে ঘূৰাই দিয়ে:

{"0";"5";" -";"E";"C";"-";"0";"1"}

যেনেকৈ MID এটা লিখনী ফলন, ইয়াৰ আউটপুট সদায় লিখনী (আপুনি লক্ষ্য কৰিব পৰাৰ দৰে, সকলো আখৰ উদ্ধৃতি চিহ্নত আবদ্ধ কৰা হৈছে)। সংখ্যাগতবোৰক সংখ্যালৈ ৰূপান্তৰিত কৰিবলৈ আমি এৰেটোক ১ ৰে গুণ কৰিম (ডাবল নেগেচন --MID()ৰ একে প্ৰভাৱ পৰিব)। এই কাৰ্য্যৰ ফলাফল হৈছে সংখ্যাৰ এটা এৰে আৰু #VALUE! অসংখ্যাগত আখৰসমূহক প্ৰতিনিধিত্ব কৰা ভুলসমূহ:

ISNUMBER({0;5;#VALUE!;#VALUE!;#VALUE!;#VALUE!;0;1})

ISNUMBER ফাংচন এৰেৰ প্ৰতিটো উপাদানৰ মূল্যায়ন কৰে আৰু ইয়াৰ ৰায়দান বুলিয়ান মানসমূহৰ আকাৰত দিয়ে - সংখ্যাৰ বাবে TRUE, অন্য যিকোনো বস্তুৰ বাবে FALSE:

{TRUE;TRUE;FALSE;FALSE;FALSE;FALSE;TRUE;TRUE}

এই এৰে IF ফাংচনৰ লজিকেল পৰীক্ষালৈ যায়, য'ত এৰেৰ প্ৰতিটো উপাদানক FALSE ৰ সৈতে তুলনা কৰা হয়:

IF({TRUE;TRUE;FALSE;FALSE;FALSE;FALSE;TRUE ;TRUE}=FALSE, ROW(INDIRECT("1:"&LEN(A2))), 0)

প্ৰতিটো FALSE (অসংখ্যাগত মানৰ বাবে), আন এটা ROW(INDIRECT()) ফাংচন ঘূৰাই দিয়ে ষ্ট্ৰিংত ইয়াৰ আপেক্ষিক অৱস্থান। প্ৰতিটো TRUE (সংখ্যাগত মান)ৰ বাবে, এটা শূন্য ঘূৰাই দিয়া হয়। ফলস্বৰূপে পোৱা এৰেটো এনেকুৱা দেখা যায়তলত দিয়া হৈছে:

{0;0;3;4;5;6;0;0}

বাকীবোৰ সহজ। MAX ফাংচনে ওপৰৰ এৰেত সৰ্বোচ্চ সংখ্যা বিচাৰি পায়, যিটো হৈছে ষ্ট্ৰিংটোৰ শেষৰ অ-সংখ্যাগত মানৰ অৱস্থান (আমাৰ ক্ষেত্ৰত ৬)। সৰলভাৱে, সেই অৱস্থানটো LEN দ্বাৰা ঘূৰাই দিয়া ষ্ট্ৰিংৰ মুঠ দৈৰ্ঘ্যৰ পৰা বিয়োগ কৰক, আৰু ফলাফলটো RIGHT লৈ পাছ কৰক যাতে ইয়াক জনা যায় যে ষ্ট্ৰিঙৰ সোঁফালৰ পৰা কিমান আখৰ উলিয়াব লাগে:

RIGHT(A2, LEN (A2) - 6)

Done!

টেক্সট ষ্ট্ৰিংৰ আৰম্ভণিৰ পৰা সংখ্যা কেনেকৈ উলিয়াব পাৰি

যদি আপুনি ৰেকৰ্ডৰ সৈতে কাম কৰি আছে য'ত সংখ্যাৰ পিছত লিখনী ওলায়, তেন্তে আপুনি কৰিব পাৰে এই সাধাৰণ সূত্ৰ ব্যৱহাৰ কৰি এটা ষ্ট্ৰিংৰ আৰম্ভণিৰ পৰা সংখ্যা উলিয়াওক:

A2 ত মূল স্ট্ৰিঙৰ সৈতে, সংখ্যা পাবলৈ নিম্নলিখিত সূত্ৰ ব্যৱহাৰ কৰক:

=LEFT(A2, MATCH(FALSE, ISNUMBER(MID(A2, ROW(INDIRECT("1:"&LEN(A2)+1)), 1) *1), 0) -1)

মাজ বা শেষত যিমানেই সংখ্যা নাথাকক কিয়, কেৱল আৰম্ভণিৰ সংখ্যাটোহে উলিওৱা হয়:

টোকা। Excel 365 আৰু Excel 2021 ত, ডাইনামিক এৰেৰ বাবে সমৰ্থনৰ বাবে, এটা নিয়মীয়া সূত্ৰই ভালদৰে কাম কৰে। Excel 2019 আৰু ইয়াৰ আগৰ, আপুনি ইয়াক এটা এৰে সূত্ৰ কৰিবলৈ স্পষ্টভাৱে Ctrl + Shift + Enter টিপিব লাগে।

এই সূত্ৰই কেনেকৈ কাম কৰে:

ইয়াত, আমি আকৌ ROW, INDIRECT আৰু LEN ফাংচনৰ সংমিশ্ৰণ ব্যৱহাৰ কৰি উৎস ষ্ট্ৰিংত থকা মুঠ আখৰৰ সমান সংখ্যাৰ ক্ৰম এটা যোগ কৰি 1 (তাৰ ভূমিকা) সৃষ্টি কৰোঁঅতিৰিক্ত আখৰ অলপ পিছত স্পষ্ট হ'ব)।

ROW(INDIRECT("1:"&LEN(A2)+1))

MID আৰু ISNUMBER এ ৰ দৰে একে কাম কৰে পূৰ্বৰ উদাহৰণ - MID এ ব্যক্তিগত আখৰসমূহ টানে আৰু ISNUMBER এ সিহতক লজিকেল মানসমূহলে ৰূপান্তৰ কৰে। TRUE আৰু FALSE ৰ ফলাফল এৰে এটা লুকআপ এৰে হিচাপে MATCH ফাংচনলৈ যায়:

MATCH(FALSE, {TRUE;TRUE;FALSE;FALSE;FALSE;FALSE;TRUE;TRUE;FALSE}, 0)

MATCH এ প্ৰথম FALSE ৰ এটা আপেক্ষিক অৱস্থান গণনা কৰে, আমাক ষ্ট্ৰিংটোৰ প্ৰথম অসংখ্যাগত আখৰৰ অৱস্থান দিয়ে (A2 ত 3)। পূৰ্বৰ সংখ্যাবোৰ উলিয়াবলৈ আমি প্ৰথম লিখনী আখৰৰ স্থানৰ পৰা 1 বিয়োগ কৰো আৰু পাৰ্থক্যটো LEFT ফাংচনৰ num_chars আৰ্গুমেণ্টলৈ পৰিবেশন কৰো:

LEFT(A2, 3-1)

এতিয়া, ROW(INDIRECT()+1) দ্বাৰা সৃষ্টি কৰা ক্ৰমত এটা "অতিৰিক্ত" আখৰলৈ উভতি যাওক। আপুনি ইতিমধ্যে জানে যে, এই ক্ৰমে MID ফাংচনৰ বাবে আৰম্ভণি বিন্দুসমূহ প্ৰদান কৰে। +1 অবিহনে, MID এ মূল ষ্ট্ৰিংত থকা আখৰবোৰ হুবহু সিমানেই এক্সট্ৰেক্ট কৰিব। যদি ষ্ট্ৰিংত কেৱল সংখ্যা থাকে, ISNUMBER এ কেৱল TRUE সমূহ ঘূৰাই দিব যেতিয়া MATCH ৰ অন্ততঃ এটা FALSE ৰ প্ৰয়োজন। সেইটো নিশ্চিত কৰিবলৈ আমি ষ্ট্ৰিঙৰ মুঠ দৈৰ্ঘ্যত আৰু এটা আখৰ যোগ কৰো, যিটো MID ফাংচনে এটা খালী ষ্ট্ৰিংলৈ ৰূপান্তৰ কৰিব। উদাহৰণস্বৰূপ, B7 ত, MID এ এই এৰে ঘূৰাই দিয়ে:

{"1";"2";"3";"4";""}

টোকা। RIGHT ফাংচনৰ দৰে, LEFT এ এটা সংখ্যাও ঘূৰাই দিয়েsubstring , যি কাৰিকৰীভাৱে লিখনী, সংখ্যা নহয়। ফলাফলটো সংখ্যাগত ষ্ট্ৰিঙৰ পৰিৱৰ্তে এটা সংখ্যা হিচাপে পাবলৈ, VALUE ফাংচনত সূত্ৰটো নেষ্ট কৰক বা প্ৰথম উদাহৰণত দেখুওৱাৰ দৰে ফলাফলটোক 1 ৰে গুণ কৰক।

এটা ষ্ট্ৰিংৰ যিকোনো স্থানৰ পৰা সংখ্যা কেনেকৈ পাব

যদি আপোনাৰ কামে এটা ষ্ট্ৰিংৰ যিকোনো ঠাইৰ পৰা সংখ্যা উলিওৱাটো বুজায়, আপুনি MrExcel ফ'ৰামত প্ৰকাশিত নিম্নলিখিত মন-বিমূৰ্ত সূত্ৰ ব্যৱহাৰ কৰিব পাৰে:

=SUMPRODUCT(MID(0&A2, LARGE(INDEX(ISNUMBER(--MID(A2, ROW(INDIRECT("1:"&LEN(A2))), 1)) * ROW(INDIRECT("1:"&LEN(A2))), 0), ROW(INDIRECT("1:"&LEN(A2))))+1, 1) * 10^ROW(INDIRECT("1:"&LEN(A2)))/10)

য'ত A2 হৈছে এই সূত্ৰটো ভাঙিবলৈ এটা পৃথক প্ৰবন্ধৰ প্ৰয়োজন হ'ব, গতিকে আপুনি ইয়াক আপোনাৰ কাৰ্য্যপত্ৰিকালৈ কপি কৰিব পাৰে যাতে ই সঁচাকৈয়ে কাম কৰে :)

ফলাফল পৰীক্ষা কৰাৰ পিছত, অৱশ্যে, আপুনি এটা গুৰুত্বহীন অসুবিধা লক্ষ্য কৰিব পাৰে - যদি উৎস ষ্ট্ৰিংত এটা সংখ্যা নাথাকে, সূত্ৰটোৱে শূন্য ঘূৰাই দিয়ে, ওপৰৰ স্ক্ৰীণশ্বটত 6 নং শাৰীত দেখুওৱাৰ দৰে। ইয়াক সমাধান কৰিবলে, আপুনি সূত্ৰটো IF বিবৃতিত ৰেপ কৰিব পাৰে, যাৰ লজিকেল পৰীক্ষাই উৎস ষ্ট্ৰিংত কোনো সংখ্যা আছে নে নাই পৰীক্ষা কৰে। যদি হয়, সূত্ৰটোৱে সংখ্যাটো এক্সট্ৰেক্ট কৰে, অন্যথা এটা খালী ষ্ট্ৰিং ঘূৰাই দিয়ে:

=IF(SUM(LEN(A2)-LEN(SUBSTITUTE(A2, {"0","1","2","3","4","5","6","7","8","9"}, "")))>0, SUMPRODUCT(MID(0&A2, LARGE(INDEX(ISNUMBER(--MID(A2,ROW(INDIRECT("$1:$"&LEN(A2))),1))* ROW(INDIRECT("$1:$"&LEN(A2))),0), ROW(INDIRECT("$1:$"&LEN(A2))))+1,1) * 10^ROW(INDIRECT("$1:$"&LEN(A2)))/10),"")

তলৰ স্ক্ৰীণশ্বটত দেখুওৱাৰ দৰে উন্নত সূত্ৰটোৱে সুন্দৰভাৱে কাম কৰে (আমাৰ এক্সেল গুৰু এলেক্সলৈ কুডোছ, এই উন্নতিৰ বাবে):

পূৰ্বৰ সকলো উদাহৰণৰ দৰে নহয়, এই সূত্ৰৰ ফলাফল হ'ল সংখ্যা । এইটো নিশ্চিত কৰিবলে, মাত্ৰ স্তম্ভ B ত সোঁ-প্ৰান্তিককৃত মানসমূহ আৰু ছেদ কৰা আগৰ শূন্যসমূহ লক্ষ্য কৰক।

পৰামৰ্শ। এক্সেল ৩৬৫ - ৩৬৫ ত।Excel 2019, TEXTJOIN ফাংচনৰ সহায়ত বহুত সহজ সমাধান আছে। অনুগ্ৰহ কৰি চাওক লিখনী কেনেকৈ আঁতৰাব আৰু সংখ্যা ৰাখিব।

আলটিমেট ছুইটৰ সৈতে লিখনী ষ্ট্ৰিঙৰ পৰা সংখ্যা উলিয়াওক

আপুনি মাত্ৰ দেখাৰ দৰে, এটা লিখনী ষ্ট্ৰিঙৰ পৰা সংখ্যা টানিবলৈ কোনো তুচ্ছ Excel সূত্ৰ নাই। যদি আপুনি সূত্ৰসমূহ বুজিবলৈ বা আপোনাৰ ডাটা ছেটসমূহৰ বাবে সিহতক টুইক কৰাত অসুবিধা পায়, আপুনি এক্সেলত ষ্ট্ৰিঙৰ পৰা সংখ্যা পাবলৈ এই সহজ উপায়টো ভাল পাব পাৰে।

আমাৰ আলটিমেট ছুইট আপোনাৰ এক্সেল ৰিবনত যোগ কৰাৰ সৈতে, আপুনি এইদৰেই যিকোনো আলফানিউমেৰিক ষ্ট্ৰিঙৰ পৰা সংখ্যা দ্ৰুতভাৱে উদ্ধাৰ কৰিব পাৰে:

1. Ablebits Data টেব > পাঠ গোটলৈ যাওক, আৰু Extract ক্লিক কৰক :

   

2. উৎস ষ্ট্ৰিংসমূহৰ সৈতে সকলো ঘৰ নিৰ্ব্বাচন কৰক।
3. এক্সট্ৰেক্ট সঁজুলিৰ পেনত, সংখ্যাসমূহ এক্সট্ৰেক্ট কৰক ৰেডিঅ' বুটাম নিৰ্ব্বাচন কৰক।
4. আপুনি ফলাফলসমূহ সূত্ৰ বা মান হ'ব বিচাৰে নে নাই তাৰ ওপৰত নিৰ্ভৰ কৰি, সূত্ৰ হিচাপে সন্নিবিষ্ট কৰক বাকচ নিৰ্ব্বাচন কৰক বা ইয়াক নিৰ্বাচিত নোহোৱাকৈ ৰাখক (অবিকল্পিত)।

   মোৰ পৰামৰ্শ হ'ল এই বাকচ নিৰ্ব্বাচন কৰক যদি আপুনি নিষ্কাষিত সংখ্যাসমূহ উৎস স্ট্ৰিংসমূহত কোনো পৰিবৰ্তন কৰাৰ লগে লগে স্বয়ংক্ৰিয়ভাৱে আপডেইট হোৱাটো বিচাৰে। যদি আপুনি ফলাফলসমূহ মূল স্ট্ৰিংসমূহত স্বাধীন হোৱাটো বিচাৰে (যেনে যদি আপুনি পিছৰ বিন্দুত উৎস তথ্য আঁতৰাবলৈ পৰিকল্পনা কৰিছে), তেন্তে এই বাকচ নিৰ্ব্বাচন নকৰিব।

5. ফল সন্নিবিষ্ট কৰক বুটাম ক্লিক কৰক। Done!

পূৰ্বৰ উদাহৰণৰ দৰে, ফলাফলৰ...এই উদাহৰণত, আমি ফলাফলসমূহ <9 হিচাপে সন্নিবিষ্ট কৰিবলৈ বাছি লৈছো>মানসমূহ , আৰু এড-ইনে বিচৰা ধৰণেই কৰিলে:

যদি সূত্ৰ হিচাপে সন্নিবিষ্ট কৰক চেকবাকচ নিৰ্বাচিত কৰা হৈছিল, আপুনি' d সূত্ৰ বাৰত এটা সূত্ৰ পৰ্যবেক্ষণ কৰক। কোনটো জানিবলৈ কৌতুহলী? মাত্ৰ Ultimate Suite ৰ ট্ৰাইল ডাউনলোড কৰক আৰু নিজেই চাওক :)

উপলব্ধ ডাউনলোডসমূহ

Excel Extract Number - নমুনা ৱৰ্কবুক (.xlsx ফাইল)

Ultimate Suite - trial version (.exe ফাইল)